maketime - skript- och diagramfunktion

Översikt

Öppn skriptredigeraren och lägg till laddningsskriptet nedan till en ny flik.

Laddningsskriptet innehåller:

• En datauppsättning som innehåller en uppsättning transaktioner som laddas i en tabell som heter Transactions.

• Tillhandahållna transaktionstider som tillhandahålls över tre fält: hours, minutes, och seconds.

• Ett fält transaction_time skapas som returnerar tiden i formatet för systemvariabeln TimeFormat.

Laddningsskript

SET TimeFormat='h:mm:ss TT';

Transactions:
    Load
        *,
        maketime(transaction_hour, transaction_minute, transaction_second) as transaction_time
        ; 
Load * Inline [
transaction_id, transaction_hour, transaction_minute, transaction_second, transaction_amount, transaction_quantity, customer_id
3750, 18, 43, 30, 12423.56, 23, 2038593
3751, 6, 32, 07, 5356.31, 6, 203521
3752, 12, 09, 16, 15.75, 1, 5646471
3753, 21, 43, 41, 7, 3036491
3754, 17, 55, 22, 21484.21, 1356, 049681
3756, 2, 52, 22, -59.18, 2, 2038593
3757, 9, 25, 23, 3177.4, 21, 203521
];

Resultat

Ladda data och öppna ett ark. Skapa en ny tabell och lägg till dessa fält som dimensioner:

• transaction_hour

• transaction_minute

• transaction_second

• transaction_time

transaction_time-fältet skapades i den föregående load-satsen genom att använda maketime()-funktionen och skicka tim-, minut- och sekundfälten som funktionens argument.

Funktionen kombinerar och konverterar sedan de här värdena till ett tidsfält och returnerar resultatet i tidsformatet för systemvariabeln TimeFormat.

Översikt

Öppn skriptredigeraren och lägg till laddningsskriptet nedan till en ny flik.

Laddningsskriptet innehåller:

• Samma datauppsättning och scenario som i det första exemplet.

• Ett fält transaction_time skapas som låter oss visa resultaten i 24-timmarsformat utan att ändra systemvariabeln TimeFormat.

Laddningsskript

SET TimeFormat='h:mm:ss TT';

Transactions:
    Load
        *,
        time(maketime(transaction_hour, transaction_minute, transaction_second),'h:mm:ss') as transaction_time
        ; 
Load * Inline [
transaction_id, transaction_hour, transaction_minute, transaction_second, transaction_amount, transaction_quantity, customer_id
3750, 18, 43, 30, 12423.56, 23, 2038593
3751, 6, 32, 07, 5356.31, 6, 203521
3752, 12, 09, 16, 15.75, 1, 5646471
3753, 21, 43, 41, 7, 3036491
3754, 17, 55, 22, 21484.21, 1356, 049681
3756, 2, 52, 22, -59.18, 2, 2038593
3757, 9, 25, 23, 3177.4, 21, 203521
];

Resultat

Ladda data och öppna ett ark. Skapa en ny tabell och lägg till dessa fält som dimensioner:

• transaction_hour

• transaction_minute

• transaction_second

• transaction_time

I det här fallet nästlas maketime()-funktion inuti time()-funktionen. Det andra argumentet i time()-funktionen ställer in formatet i maketime()-funktionens resultat till det erforderliga h:mm:ss.

Översikt

Öppn skriptredigeraren och lägg till laddningsskriptet nedan till en ny flik.

Laddningsskriptet innehåller:

• En datauppsättning som innehåller en uppsättning transaktioner som laddas i en tabell som heter Transactions.

• Tillhandahållna transaktionstider som tillhandahålls över två fält: hours och minutes.

• Ett fält transaction_time skapas, som returnerar tiden i formatet för systemvariabeln TimeFormat.

Skapa ett diagramobjektmått, transaction_time, som returnerar en tid i formatet h:mm:ss TT.

Laddningsskript

SET TimeFormat='h:mm:ss TT';

Transactions:
Load * Inline [
transaction_id, transaction_hour, transaction_minute, transaction_amount, transaction_quantity, customer_id
3750, 18, 43, 12423.56, 23, 2038593
3751, 6, 32, 5356.31, 6, 203521
3752, 12, 09, 15.75, 1, 5646471
3753, 21, 43, 7, 3036491
3754, 17, 55, 21484.21, 1356, 049681
3756, 2, 52, -59.18, 2, 2038593
3757, 9, 25, 3177.4, 21, 203521
];

Resultat

Ladda data och öppna ett ark. Skapa en ny tabell och lägg till dessa fält som dimensioner:

• transaction_hour

• transaction_minute

För att beräkna transaction_time skapar du det här måttet:

=maketime(transaction_hour,transaction_minute)

transaction_time-måttet skapades i den föregående load-satsen genom att använda maketime()-funktionen och skicka tim- och minutfälten som funktionens argument.

Funktionen kombinerar sedan dessa värden, och sekunderna antas vara 00. De här värdena konverteras sedan till ett tidsfält och returnerar resultatet i form av systemvariabeln TimeFormat.

Översikt

Skapa en kalenderdatauppsättning för januari månad 2022, uppbruten i åttatimmarssteg.

Laddningsskript

SET TimestampFormat='M/D/YYYY h:mm:ss[.fff] TT';

tmpCalendar:
	load 
		*
    where year(date)=2022;
load
	date(recno()+makedate(2021,12,31)) as date
AutoGenerate 31;

Left join(tmpCalendar)
load
	maketime((recno()-1)*8,00,00) as time
autogenerate 3;

Calendar:
load
	timestamp(date + time) as timestamp
resident tmpCalendar;

drop table tmpCalendar;

Resultat

Den initiala autogenerate-funktionen skapar en kalender som innehåller alla datum i januari i en tabell som heter tmpCalendar.

Ytterligare en tabell som innehåller tre poster skapas. För varje post tas recno() – 1 (värdena 0, 1, 2) och resultatet multipliceras med 8. Detta ger värdena 0, 8 16 som resultat. De här värdena används som timparameter i en maketime()-funktion, med minut- och sekundvärden som 0. Detta resulterar i att tabellen innehåller tre tidsfält: 12:00:00 AM, 8:00:00 AM, and 4:00:00 PM.

Den här tabellen länkas till tmpCalendar-tabellen. Eftersom det inte finns några matchande fält mellan de två tabellerna för länkningen läggs tidsraderna till i varje datarad. Detta resulterar i att varje datarad nu repeteras tre gånger för varje tidsvärde.

Slutligen skapas kalendertabellen från en resident load i tmpCalendar-tabellen. Datum- och tidsfälten konkateneras och omsluts i timestamp()-funktionen för att skapa en tidsmarkörsfältet.

tmpCalendar-tabellen släpps sedan här.