maketime - fonction de script et fonction de graphique

Vue d'ensemble

Ouvrez l'éditeur de chargement de données et ajoutez le script de chargement ci-dessous à un nouvel onglet.

Le script de chargement contient :

• Ensemble de données contenant un ensemble de transactions, chargé dans une table appelée Transactions.

• Heures de transaction fournies sur trois champs : hours, minutes et seconds.

• Création d'un champ, transaction_time, qui renvoie l'heure au format de la variable système TimeFormat.

Script de chargement

SET TimeFormat='h:mm:ss TT';

Transactions:
    Load
        *,
        maketime(transaction_hour, transaction_minute, transaction_second) as transaction_time
        ; 
Load * Inline [
transaction_id, transaction_hour, transaction_minute, transaction_second, transaction_amount, transaction_quantity, customer_id
3750, 18, 43, 30, 12423.56, 23, 2038593
3751, 6, 32, 07, 5356.31, 6, 203521
3752, 12, 09, 16, 15.75, 1, 5646471
3753, 21, 43, 41, 7, 3036491
3754, 17, 55, 22, 21484.21, 1356, 049681
3756, 2, 52, 22, -59.18, 2, 2038593
3757, 9, 25, 23, 3177.4, 21, 203521
];

Résultats

Chargez les données et ouvrez une feuille. Créez une table et ajoutez ces champs comme dimensions :

• transaction_hour

• transaction_minute

• transaction_second

• transaction_time

Le champ transaction_time est créé dans l'instruction preceding load via la fonction maketime() et en transmettant les champs hour, minute et second comme arguments de la fonction.

La fonction combine ensuite ces valeurs et les convertit en un champ time, renvoyant les résultats au format horaire de la variable système TimeFormat.

Vue d'ensemble

Ouvrez l'éditeur de chargement de données et ajoutez le script de chargement ci-dessous à un nouvel onglet.

Le script de chargement contient :

• Même ensemble de données et même scénario que ceux du premier exemple.

• Création d'un champ, transaction_time, qui vous permettra d'afficher les résultats au format horaire sur 24 heures sans modifier la variable système TimeFormat.

Script de chargement

SET TimeFormat='h:mm:ss TT';

Transactions:
    Load
        *,
        time(maketime(transaction_hour, transaction_minute, transaction_second),'h:mm:ss') as transaction_time
        ; 
Load * Inline [
transaction_id, transaction_hour, transaction_minute, transaction_second, transaction_amount, transaction_quantity, customer_id
3750, 18, 43, 30, 12423.56, 23, 2038593
3751, 6, 32, 07, 5356.31, 6, 203521
3752, 12, 09, 16, 15.75, 1, 5646471
3753, 21, 43, 41, 7, 3036491
3754, 17, 55, 22, 21484.21, 1356, 049681
3756, 2, 52, 22, -59.18, 2, 2038593
3757, 9, 25, 23, 3177.4, 21, 203521
];

Résultats

Chargez les données et ouvrez une feuille. Créez une table et ajoutez ces champs comme dimensions :

• transaction_hour

• transaction_minute

• transaction_second

• transaction_time

Dans cet exemple, la fonction maketime() est imbriquée dans la fonction time(). Le deuxième argument de la fonction time() définit le format des résultats de la fonction maketime() sur le format h:mm:ss requis.

Vue d'ensemble

Ouvrez l'éditeur de chargement de données et ajoutez le script de chargement ci-dessous à un nouvel onglet.

Le script de chargement contient :

• Ensemble de données contenant un ensemble de transactions, chargé dans une table appelée Transactions.

• Heures de transaction fournies sur deux champs : hours et minutes.

• Création d'un champ, transaction_time, qui renvoie l'heure au format de la variable système TimeFormat.

Créez une mesure d'objet graphique, transaction_time, qui renvoie une heure au format h:mm:ss TT.

Script de chargement

SET TimeFormat='h:mm:ss TT';

Transactions:
Load * Inline [
transaction_id, transaction_hour, transaction_minute, transaction_amount, transaction_quantity, customer_id
3750, 18, 43, 12423.56, 23, 2038593
3751, 6, 32, 5356.31, 6, 203521
3752, 12, 09, 15.75, 1, 5646471
3753, 21, 43, 7, 3036491
3754, 17, 55, 21484.21, 1356, 049681
3756, 2, 52, -59.18, 2, 2038593
3757, 9, 25, 3177.4, 21, 203521
];

Résultats

Chargez les données et ouvrez une feuille. Créez une table et ajoutez ces champs comme dimensions :

• transaction_hour

• transaction_minute

Pour calculer la valeur transaction_time, créez la mesure suivante :

=maketime(transaction_hour,transaction_minute)

La mesure transaction_time est créée dans l'objet graphique via la fonction maketime() et en transmettant les champs hour et minute comme arguments de la fonction.

La fonction combine ensuite ces valeurs et les secondes sont supposées être 00. Ces valeurs sont ensuite converties en un champ time, renvoyant les résultats au format de la variable système TimeFormat.

Vue d'ensemble

Créez un ensemble de données Calendar pour le mois de janvier 2022, divisé en incréments de huit heures.

Script de chargement

SET TimestampFormat='M/D/YYYY h:mm:ss[.fff] TT';

tmpCalendar:
	load 
		*
    where year(date)=2022;
load
	date(recno()+makedate(2021,12,31)) as date
AutoGenerate 31;

Left join(tmpCalendar)
load
	maketime((recno()-1)*8,00,00) as time
autogenerate 3;

Calendar:
load
	timestamp(date + time) as timestamp
resident tmpCalendar;

drop table tmpCalendar;

Résultats

La fonction autogenerate initiale crée un calendrier contenant l'ensemble des dates de janvier dans une table appelée tmpCalendar.

Une deuxième table, contenant trois enregistrements, est créée. Pour chaque enregistrement, l'argument recno() – 1 est pris (valeurs 0, 1 et 2) et le résultat est multiplié par 8. Cela génère les valeurs 0, 8 et 16. Ces valeurs sont utilisées comme paramètre horaire dans une fonction maketime(), avec les valeurs minute et second définies sur 0. En conséquence, la table contient trois champs horaires : 12:00:00 AM, 8:00:00 AM et 4:00:00 PM.

Cette table est jointe à la table tmpCalendar. Étant donné qu'il n'existe pas de champs correspondants entre les deux tables pour la jointure, les lignes des heures sont ajoutées à chaque ligne de date. C'est pourquoi chaque ligne de date est maintenant répétée trois fois avec chaque valeur horaire.

Pour finir, la table Calendar est créée à partir d'une instruction resident load appliquée à la table tmpCalendar. Les champs date et time sont concaténés et imbriqués dans la fonction timestamp() pour créer le champ timestamp (horodatage).

La table tmpCalendar est ensuite abandonnée.