maketime - 脚本和图表函数

概述

打开数据加载编辑器，并将下面的加载脚本添加到新选项卡。

加载脚本包含：

• 包含交易集的数据集，该数据集加载到名为 Transactions 的表中。

• 跨三个字段提供的交易时间：hours、minutes 和 seconds。

• 创建字段 transaction_time，以系统变量 TimeFormat 的格式返回时间。

加载脚本

SET TimeFormat='h:mm:ss TT';

Transactions:
    Load
        *,
        maketime(transaction_hour, transaction_minute, transaction_second) as transaction_time
        ; 
Load * Inline [
transaction_id, transaction_hour, transaction_minute, transaction_second, transaction_amount, transaction_quantity, customer_id
3750, 18, 43, 30, 12423.56, 23, 2038593
3751, 6, 32, 07, 5356.31, 6, 203521
3752, 12, 09, 16, 15.75, 1, 5646471
3753, 21, 43, 41, 7, 3036491
3754, 17, 55, 22, 21484.21, 1356, 049681
3756, 2, 52, 22, -59.18, 2, 2038593
3757, 9, 25, 23, 3177.4, 21, 203521
];

结果

加载数据并打开工作表。创建新表并将这些字段添加为维度：

• transaction_hour

• transaction_minute

• transaction_second

• transaction_time

transaction_time 字段是在前置 Load 语句中创建的，方法是使用 maketime() 函数并将小时、分钟和秒字段作为函数参数传递。

然后，该函数将这些值组合并转换为时间字段，以 TimeFormat 系统变量的时间格式返回结果。

概述

打开数据加载编辑器，并将下面的加载脚本添加到新选项卡。

加载脚本包含：

• 与第一个示例相同的数据集和场景。

• 创建一个字段 transaction_time，这将允许我们在不修改 TimeFormat 系统变量的情况下以 24 小时时间格式显示结果。

加载脚本

SET TimeFormat='h:mm:ss TT';

Transactions:
    Load
        *,
        time(maketime(transaction_hour, transaction_minute, transaction_second),'h:mm:ss') as transaction_time
        ; 
Load * Inline [
transaction_id, transaction_hour, transaction_minute, transaction_second, transaction_amount, transaction_quantity, customer_id
3750, 18, 43, 30, 12423.56, 23, 2038593
3751, 6, 32, 07, 5356.31, 6, 203521
3752, 12, 09, 16, 15.75, 1, 5646471
3753, 21, 43, 41, 7, 3036491
3754, 17, 55, 22, 21484.21, 1356, 049681
3756, 2, 52, 22, -59.18, 2, 2038593
3757, 9, 25, 23, 3177.4, 21, 203521
];

结果

加载数据并打开工作表。创建新表并将这些字段添加为维度：

• transaction_hour

• transaction_minute

• transaction_second

• transaction_time

在本例中，maketime() 函数嵌套在 time() 函数内部。time() 函数的第二个参数将 maketime() 函数结果的格式设置为所需的 h:mm:ss。

概述

打开数据加载编辑器，并将下面的加载脚本添加到新选项卡。

加载脚本包含：

• 包含交易集的数据集，该数据集加载到名为 Transactions 的表中。

• 跨两个字段提供的交易时间： hours 和 minutes。

• 创建字段 transaction_time，以系统变量 TimeFormat 的格式返回时间。

创建一个图表对象度量 transaction_time，返回格式为 h:mm:ss TT 的日期。

加载脚本

SET TimeFormat='h:mm:ss TT';

Transactions:
Load * Inline [
transaction_id, transaction_hour, transaction_minute, transaction_amount, transaction_quantity, customer_id
3750, 18, 43, 12423.56, 23, 2038593
3751, 6, 32, 5356.31, 6, 203521
3752, 12, 09, 15.75, 1, 5646471
3753, 21, 43, 7, 3036491
3754, 17, 55, 21484.21, 1356, 049681
3756, 2, 52, -59.18, 2, 2038593
3757, 9, 25, 3177.4, 21, 203521
];

结果

加载数据并打开工作表。创建新表并将这些字段添加为维度：

• transaction_hour

• transaction_minute

要计算 transaction_time，请创建此度量：

=maketime(transaction_hour,transaction_minute)

通过使用 maketime() 函数并将小时和分钟字段作为函数参数传递，在图表对象中创建 transaction_time 度量。

然后，函数将这些值组合起来，并假定秒为 00。然后将这些值转换为时间字段，以 TimeFormat 系统变量的格式返回结果。

概述

创建 2022 年 1 月的日历数据集，分为 8 小时增量。

加载脚本

SET TimestampFormat='M/D/YYYY h:mm:ss[.fff] TT';

tmpCalendar:
	load 
		*
    where year(date)=2022;
load
	date(recno()+makedate(2021,12,31)) as date
AutoGenerate 31;

Left join(tmpCalendar)
load
	maketime((recno()-1)*8,00,00) as time
autogenerate 3;

Calendar:
load
	timestamp(date + time) as timestamp
resident tmpCalendar;

drop table tmpCalendar;

结果

初始 autogenerate 函数在名为 tmpCalendar 的表中创建一个日历，其中包含 1 月份的所有日期。

创建了包含三条记录的第二个表。对于每个记录，recno() – 1 取（值0、1、2），并将结果乘以 8。因此，生成值 0、8 16。这些值用作 maketime() 函数中的小时参数，分钟和秒值为 0。因此，该表包含三个时间字段：12:00:00 AM、8:00:00 AM 和 4:00:00 PM。

这张表与 tmpCalendar 表相联接。因为联接的两个表之间没有匹配的字段，所以时间行被添加到每个日期行。因此，每个日期行现在用每个时间值重复三次。

最后，日历表是从 tmpCalendar 表的常驻负载创建的。日期和时间字段在 timestamp() 函数中连接和包装，以创建时间戳字段。

然后将 tmpCalendar 表放下。