maketime – função de script e gráfico

Visão geral

Abra o editor da carga de dados e adicione o script de carregamento abaixo em uma nova guia.

O script de carregamento contém:

• Um conjunto de dados contendo um conjunto de transações que é carregado em uma tabela denominada Transactions

• Os tempos de transação são fornecidos em três campos: hours, minutes e seconds.

• A criação de um campo, transaction_time, que retorna a hora no formato da variável de sistema TimeFormat.

Script de carregamento

SET TimeFormat='h:mm:ss TT';

Transactions:
    Load
        *,
        maketime(transaction_hour, transaction_minute, transaction_second) as transaction_time
        ; 
Load * Inline [
transaction_id, transaction_hour, transaction_minute, transaction_second, transaction_amount, transaction_quantity, customer_id
3750, 18, 43, 30, 12423.56, 23, 2038593
3751, 6, 32, 07, 5356.31, 6, 203521
3752, 12, 09, 16, 15.75, 1, 5646471
3753, 21, 43, 41, 7, 3036491
3754, 17, 55, 22, 21484.21, 1356, 049681
3756, 2, 52, 22, -59.18, 2, 2038593
3757, 9, 25, 23, 3177.4, 21, 203521
];

Resultados

Carregue os dados e abra uma pasta. Crie uma nova tabela e adicione esses campos como dimensões:

• transaction_hour

• transaction_minute

• transaction_second

• transaction_time

O campo transaction_time é criado na instrução de carregamento anterior usando a função maketime() e informando os campos de hora, minuto e segundo como argumentos da função.

Em seguida, a função combina e converte esses valores em um campo de tempo, retornando os resultados no formato de tempo da variável de sistema TimeFormat.

Visão geral

Abra o editor da carga de dados e adicione o script de carregamento abaixo em uma nova guia.

O script de carregamento contém:

• O mesmo conjunto de dados e cenário do primeiro exemplo.

• A criação de um campo, transaction_time, que nos permitirá mostrar os resultados no formato de 24 horas sem modificar a variável de sistema TimeFormat.

Script de carregamento

SET TimeFormat='h:mm:ss TT';

Transactions:
    Load
        *,
        time(maketime(transaction_hour, transaction_minute, transaction_second),'h:mm:ss') as transaction_time
        ; 
Load * Inline [
transaction_id, transaction_hour, transaction_minute, transaction_second, transaction_amount, transaction_quantity, customer_id
3750, 18, 43, 30, 12423.56, 23, 2038593
3751, 6, 32, 07, 5356.31, 6, 203521
3752, 12, 09, 16, 15.75, 1, 5646471
3753, 21, 43, 41, 7, 3036491
3754, 17, 55, 22, 21484.21, 1356, 049681
3756, 2, 52, 22, -59.18, 2, 2038593
3757, 9, 25, 23, 3177.4, 21, 203521
];

Resultados

Carregue os dados e abra uma pasta. Crie uma nova tabela e adicione esses campos como dimensões:

• transaction_hour

• transaction_minute

• transaction_second

• transaction_time

Nesse caso, a função maketime() está aninhada dentro da função time(). O segundo argumento da função time() define o formato dos resultados da função maketime() como a h:mm:ss necessária.

Visão geral

Abra o editor da carga de dados e adicione o script de carregamento abaixo em uma nova guia.

O script de carregamento contém:

• Um conjunto de dados contendo um conjunto de transações que é carregado em uma tabela denominada Transactions.

• Os tempos de transação são fornecidos em dois campos: hours e minutes.

• A criação de um campo, transaction_time, que retorna a hora no formato da variável de sistema TimeFormat.

Crie uma medida de objeto de gráfico, transaction_time, que retorna uma hora no formato h:mm:ss TT.

Script de carregamento

SET TimeFormat='h:mm:ss TT';

Transactions:
Load * Inline [
transaction_id, transaction_hour, transaction_minute, transaction_amount, transaction_quantity, customer_id
3750, 18, 43, 12423.56, 23, 2038593
3751, 6, 32, 5356.31, 6, 203521
3752, 12, 09, 15.75, 1, 5646471
3753, 21, 43, 7, 3036491
3754, 17, 55, 21484.21, 1356, 049681
3756, 2, 52, -59.18, 2, 2038593
3757, 9, 25, 3177.4, 21, 203521
];

Resultados

Carregue os dados e abra uma pasta. Crie uma nova tabela e adicione esses campos como dimensões:

• transaction_hour

• transaction_minute

Para calcular a transaction_time, crie esta medida:

=maketime(transaction_hour,transaction_minute)

A medida transaction_time é criada no objeto de gráfico usando a função maketime() e informando os campos de hora e minuto como argumentos da função.

A função então combina esses valores, e os segundos são considerados 00. Esses valores são então convertidos em um campo de hora, retornando os resultados no formato da variável de sistema TimeFormat.

Visão geral

Crie um conjunto de dados do calendário para o mês de janeiro de 2022, dividido em incrementos de oito horas.

Script de carregamento

SET TimestampFormat='M/D/YYYY h:mm:ss[.fff] TT';

tmpCalendar:
	load 
		*
    where year(date)=2022;
load
	date(recno()+makedate(2021,12,31)) as date
AutoGenerate 31;

Left join(tmpCalendar)
load
	maketime((recno()-1)*8,00,00) as time
autogenerate 3;

Calendar:
load
	timestamp(date + time) as timestamp
resident tmpCalendar;

drop table tmpCalendar;

Resultados

A função autogenerate inicial cria um calendário contendo todas as datas de janeiro em uma tabela denominada tmpCalendar.

Uma segunda tabela, contendo três registros, é criada. Para cada registro, recno() – 1 é obtido (valores 0, 1, 2), e o resultado é multiplicado por 8. Como resultado, isso gera os valores 0, 8, 16. Esses valores são usados como o parâmetro de hora em uma função maketime(), com valores de minuto e segundo de 0. Como resultado, a tabela contém três campos de horário: 12:00:00 AM, 8:00:00 AM e 4:00:00 PM.

Essa tabela está unida à tabela tmpCalendar. Como não há campos correspondentes entre as duas tabelas para a união, as linhas de tempo são adicionadas a cada linha de data. Como resultado, cada linha de data agora é repetida três vezes com cada valor de tempo.

Finalmente, a tabela de calendário é criada a partir de um carregamento residente da tabela tmpCalendar. Os campos de data e hora são concatenados e agrupados na função timestamp() para criar o campo de carimbo de data/hora.

A tabela tmpCalendar é então descartada.