makedate - funzione dello script e del grafico

Panoramica

Aprire l'editor caricamento dati e aggiungere lo script di caricamento sotto in una nuova scheda.

Lo script di caricamento contiene:

• Un set di dati contenente un insieme di transazioni per il 2018, caricato in una tabella denominata Transactions.

• Il campo della data fornito nel formato della variabile di sistema DateFormat (MM/GG/AAAA).

• La creazione di un campo, transaction_date, che restituisce una data nel formato MM/GG/AAAA.

Script di caricamento

SET DateFormat='MM/DD/YYYY';

Transactions:
    Load
        *,
        makedate(transaction_year, transaction_month, transaction_day) as transaction_date
        ; 
Load * Inline [
transaction_id, transaction_year, transaction_month, transaction_day, transaction_amount, transaction_quantity, customer_id
3750, 2018, 08, 30, 12423.56, 23, 2038593
3751, 2018, 09, 07, 5356.31, 6, 203521
3752, 2018, 09, 16, 15.75, 1, 5646471
3753, 2018, 09, 22, 1251, 7, 3036491
3754, 2018, 09, 22, 21484.21, 1356, 049681
3756, 2018, 09, 22, -59.18, 2, 2038593
3757, 2018, 09, 23, 3177.4, 21, 203521
];

Risultati

Caricare i dati e aprire un foglio. Creare una nuova tabella e aggiungere tali campi come dimensioni:

• transaction_year

• transaction_month

• transaction_day

• transaction_date

Il campo transaction_date viene creato nell'istruzione di caricamento precedente utilizzando la funzione makedate() e passando i campi anno, mese e giorno come argomenti della funzione.

La funzione combina e converte questi valori in un campo data, restituendo i risultati nel formato della variabile di sistema DateFormat.

Panoramica

Aprire l'editor caricamento dati e aggiungere lo script di caricamento sotto in una nuova scheda.

Lo script di caricamento contiene:

• Vengono utilizzati lo stesso set di dati e lo stesso scenario del primo esempio.

• La creazione di un campo, transaction_date, nel formato GG/MM/AAAA senza modificare la variabile di sistema DateFormat.

Script di caricamento

SET DateFormat='MM/DD/YYYY';

Transactions:
    Load
        *,
        date(makedate(transaction_year, transaction_month, transaction_day), ‘DD/MM/YYYY’) as transaction_date
        ; 
Load * Inline [
transaction_id, transaction_year, transaction_month, transaction_day, transaction_amount, transaction_quantity, customer_id
3750, 2018, 08, 30, 12423.56, 23, 2038593
3751, 2018, 09, 07, 5356.31, 6, 203521
3752, 2018, 09, 16, 15.75, 1, 5646471
3753, 2018, 09, 22, 1251, 7, 3036491
3754, 2018, 09, 22, 21484.21, 1356, 049681
3756, 2018, 09, 22, -59.18, 2, 2038593
3757, 2018, 09, 23, 3177.4, 21, 203521
];

Risultati

Caricare i dati e aprire un foglio. Creare una nuova tabella e aggiungere tali campi come dimensioni:

• transaction_year

• transaction_month

• transaction_day

• transaction_date

In questo caso, la funzione makedate() è nidificata all'interno della funzione date(). Il secondo argomento della funzione date() imposta il formato dei risultati della funzione makedate() come GG/MM/AAAA.

Panoramica

Aprire l'editor caricamento dati e aggiungere lo script di caricamento sotto in una nuova scheda.

Lo script di caricamento contiene:

• Un set di dati contenente un insieme di transazioni per il 2018, caricato in una tabella denominata Transactions.

• Le date delle transazioni sono fornite in due campi: year e month.

Creare una misura dell'oggetto grafico, transaction_date, che restituisca una data nel formato MM/GG/AAAA.

Script di caricamento

SET DateFormat='MM/DD/YYYY';

Transactions:
Load * Inline [
transaction_id, transaction_year, transaction_month, transaction_amount, transaction_quantity, customer_id
3750, 2018, 08, 12423.56, 23, 2038593
3751, 2018, 09, 5356.31, 6, 203521
3752, 2018, 09, 15.75, 1, 5646471
3753, 2018, 09, 1251, 7, 3036491
3754, 2018, 09, 21484.21, 1356, 049681
3756, 2018, 09, -59.18, 2, 2038593
3757, 2018, 09, 3177.4, 21, 203521
];

Risultati

Caricare i dati e aprire un foglio. Creare una nuova tabella e aggiungere tali campi come dimensioni:

• year

• month

Per determinare il valore transaction_date, creare questa misura:

=makedate(transaction_year,transaction_month)

La misura transaction_date viene creata nell'oggetto grafico utilizzando la funzione makedate() e passando i campi anno e mese come argomenti della funzione.

La funzione combina quindi questi valori e il valore presunto del giorno, pari a 01. Questi valori vengono poi convertiti in un campo data, restituendo i risultati nel formato della variabile di sistema DateFormat.

Panoramica

Creare un set di dati di calendario per l'anno solare 2022.

Script di caricamento

SET DateFormat='MM/DD/YYYY';

Calendar:
	load 
		*
    where year(date)=2022;
load
	date(recno()+makedate(2021,12,31)) as date
AutoGenerate 400;

Risultati

La funzione makedate() crea un valore di data per il 31 dicembre 2021. La funzione recno() fornisce il numero di record del record correntemente caricato nella tabella, a partire da 1. Pertanto, il primo record ha la data del 1° gennaio 2022. A ogni valore recno() successivo, la data viene incrementata di 1. Questa espressione è racchiusa in una funzione date() che converte il valore in una data. Questo processo viene ripetuto 400 volte dalla funzione autogenerate. Infine, sfruttando un caricamento precedente, è possibile utilizzare una condizione where per caricare solo le date a partire dall'anno 2022. Questo script genera un calendario contenente tutte le date del 2022.