makedate - función de script y de gráfico

Vista general

Abra el editor de carga de datos y agregue el script de carga a continuación a una nueva pestaña.

El script de carga contiene:

• Un conjunto de datos que contiene un conjunto de transacciones de 2018, que se carga en una tabla llamada "Transactions".

• El campo de fecha proporcionado en el formato de la variable del sistema DateFormat: (MM/DD/AAAA).

• La creación de un campo, transaction_date, que devuelve una fecha en formato MM/DD/AAAA.

Script de carga

SET DateFormat='MM/DD/YYYY';

Transactions:
    Load
        *,
        makedate(transaction_year, transaction_month, transaction_day) as transaction_date
        ; 
Load * Inline [
transaction_id, transaction_year, transaction_month, transaction_day, transaction_amount, transaction_quantity, customer_id
3750, 2018, 08, 30, 12423.56, 23, 2038593
3751, 2018, 09, 07, 5356.31, 6, 203521
3752, 2018, 09, 16, 15.75, 1, 5646471
3753, 2018, 09, 22, 1251, 7, 3036491
3754, 2018, 09, 22, 21484.21, 1356, 049681
3756, 2018, 09, 22, -59.18, 2, 2038593
3757, 2018, 09, 23, 3177.4, 21, 203521
];

Resultados

Cargue los datos y abra una hoja. Cree una nueva tabla y agregue estos campos como dimensiones:

• transaction_year

• transaction_month

• transaction_day

• transaction_date

El campo transaction_date se crea en la instrucción load anterior utilizando la función makedate() e introduciendo los campos de año, mes y día como argumentos de la función.

Luego la función combina y convierte estos valores en un campo de fecha, devolviendo los resultados en el formato de la variable del sistema DateFormat.

Vista general

Abra el editor de carga de datos y agregue el script de carga a continuación a una nueva pestaña.

El script de carga contiene:

• Se utilizan el mismo conjunto de datos y escenario que en el primer ejemplo.

• La creación de un campo, transaction_date, en el formato DD/MM/AAAA, sin modificar la variable del sistema DateFormat.

Script de carga

SET DateFormat='MM/DD/YYYY';

Transactions:
    Load
        *,
        date(makedate(transaction_year, transaction_month, transaction_day), ‘DD/MM/YYYY’) as transaction_date
        ; 
Load * Inline [
transaction_id, transaction_year, transaction_month, transaction_day, transaction_amount, transaction_quantity, customer_id
3750, 2018, 08, 30, 12423.56, 23, 2038593
3751, 2018, 09, 07, 5356.31, 6, 203521
3752, 2018, 09, 16, 15.75, 1, 5646471
3753, 2018, 09, 22, 1251, 7, 3036491
3754, 2018, 09, 22, 21484.21, 1356, 049681
3756, 2018, 09, 22, -59.18, 2, 2038593
3757, 2018, 09, 23, 3177.4, 21, 203521
];

Resultados

Cargue los datos y abra una hoja. Cree una nueva tabla y agregue estos campos como dimensiones:

• transaction_year

• transaction_month

• transaction_day

• transaction_date

En este caso, la función makedate() está anidada dentro de la función date(). El segundo argumento de la función date() establece el formato de los resultados de la función makedate() como el DD/MM/AAAA requerido.

Vista general

Abra el editor de carga de datos y agregue el script de carga a continuación a una nueva pestaña.

El script de carga contiene:

• Un conjunto de datos que contiene un conjunto de transacciones de 2018, que se carga en una tabla llamada Transactions.

• Las fechas de transacción proporcionadas en dos campos: year y month.

Cree una medida de objeto gráfico, transaction_date, que devuelva una fecha en el formato MM/DD/AAAA.

Script de carga

SET DateFormat='MM/DD/YYYY';

Transactions:
Load * Inline [
transaction_id, transaction_year, transaction_month, transaction_amount, transaction_quantity, customer_id
3750, 2018, 08, 12423.56, 23, 2038593
3751, 2018, 09, 5356.31, 6, 203521
3752, 2018, 09, 15.75, 1, 5646471
3753, 2018, 09, 1251, 7, 3036491
3754, 2018, 09, 21484.21, 1356, 049681
3756, 2018, 09, -59.18, 2, 2038593
3757, 2018, 09, 3177.4, 21, 203521
];

Resultados

Cargue los datos y abra una hoja. Cree una nueva tabla y agregue estos campos como dimensiones:

• year

• month

Para averiguar la transaction_date, cree esta medida:

=makedate(transaction_year,transaction_month)

La medida transaction_date se crea en el objeto gráfico utilizando la función makedate() e indicando los campos de año y mes como argumentos de la función.

La función luego combina estos valores, así como el valor del día asumido de 01. Estos valores luego se convierten en un campo de fecha, devolviendo los resultados en el formato de la variable del sistema DateFormat.

Vista general

Cree un conjunto de datos de calendario para el año natural de 2022.

Script de carga

SET DateFormat='MM/DD/YYYY';

Calendar:
	load 
		*
    where year(date)=2022;
load
	date(recno()+makedate(2021,12,31)) as date
AutoGenerate 400;

Resultados

La función makedate() crea un valor de fecha para el 31 de diciembre de 2021. La función recno() proporciona el número de registro del registro actual que se está cargando en la tabla, comenzando desde 1. Por lo tanto, el primer registro tiene la fecha del 1 de enero de 2022. Cada fecha sucesiva recno() incrementará esta fecha en 1. Esta expresión va incluida en una función date() para convertir el valor en una fecha. La función autogenerate repite este proceso 400 veces. Por último, usando un load anterior, se puede aplicar una condición where para que cargue solo fechas del año 2022. Este script genera un calendario que contiene todas las fechas en 2022.