makedate - script- en diagramfunctie

Overzicht

Open de editor voor laden van gegevens en voeg het onderstaande load-script toe aan een nieuw tabblad.

Het load-script bevat:

• Een gegevensverzameling met een set transacties voor 2018 die wordt geladen in een tabel met de naam Transactions.

• Het datumveld opgegeven in de DateFormat-systeemvariabele (MM/DD/YYYY) indeling.

• Het veld transaction_date wordt gemaakt dat een datum retourneert met de notatie mm/dd/jjjj.

Load-script

SET DateFormat='MM/DD/YYYY';

Transactions:
    Load
        *,
        makedate(transaction_year, transaction_month, transaction_day) as transaction_date
        ; 
Load * Inline [
transaction_id, transaction_year, transaction_month, transaction_day, transaction_amount, transaction_quantity, customer_id
3750, 2018, 08, 30, 12423.56, 23, 2038593
3751, 2018, 09, 07, 5356.31, 6, 203521
3752, 2018, 09, 16, 15.75, 1, 5646471
3753, 2018, 09, 22, 1251, 7, 3036491
3754, 2018, 09, 22, 21484.21, 1356, 049681
3756, 2018, 09, 22, -59.18, 2, 2038593
3757, 2018, 09, 23, 3177.4, 21, 203521
];

Resultaten

Laad de gegevens en open een werkblad. Maak een nieuwe tabel en voeg deze velden toe als dimensies:

• transaction_year

• transaction_month

• transaction_day

• transaction_date

Het veld transaction_date wordt gemaakt in de voorafgaande load-instructie met behulp van de makedate()-functie en geeft de jaar-, maand- en dagvelden door als de argumenten van de functie.

De functie combineert en converteert deze waarden in een datumveld en retourneert de resultaten met de notatie van de DateFormat-systeemvariabele.

Overzicht

Open de editor voor laden van gegevens en voeg het onderstaande load-script toe aan een nieuw tabblad.

Het load-script bevat:

• Dezelfde gegevensset en het scenario uit het eerste voorbeeld.

• Het veld transaction_date wordt gemaakt met de notatie dd/mm/jjjj zonder de DateFormat-systeemvariabele aan te passen.

Load-script

SET DateFormat='MM/DD/YYYY';

Transactions:
    Load
        *,
        date(makedate(transaction_year, transaction_month, transaction_day), ‘DD/MM/YYYY’) as transaction_date
        ; 
Load * Inline [
transaction_id, transaction_year, transaction_month, transaction_day, transaction_amount, transaction_quantity, customer_id
3750, 2018, 08, 30, 12423.56, 23, 2038593
3751, 2018, 09, 07, 5356.31, 6, 203521
3752, 2018, 09, 16, 15.75, 1, 5646471
3753, 2018, 09, 22, 1251, 7, 3036491
3754, 2018, 09, 22, 21484.21, 1356, 049681
3756, 2018, 09, 22, -59.18, 2, 2038593
3757, 2018, 09, 23, 3177.4, 21, 203521
];

Resultaten

Laad de gegevens en open een werkblad. Maak een nieuwe tabel en voeg deze velden toe als dimensies:

• transaction_year

• transaction_month

• transaction_day

• transaction_date

In dit geval is de makedate()-functie in de date()-functie genest. Het tweede argument van de date()-functie stelt de datumnotatie van de makedate()-functieresultaten in op de vereiste dd/mm/jjjj.

Overzicht

Open de editor voor laden van gegevens en voeg het onderstaande load-script toe aan een nieuw tabblad.

Het load-script bevat:

• Een gegevensset met een set transacties voor 2018 die wordt geladen in een tabel met de naam Transactions.

• De transactiedatums worden ingevoerd in twee velden: year en month.

Maak een diagramobjectmeting, transaction_date, die een datum retourneert met de notatie mm/dd/jjjj.

Load-script

SET DateFormat='MM/DD/YYYY';

Transactions:
Load * Inline [
transaction_id, transaction_year, transaction_month, transaction_amount, transaction_quantity, customer_id
3750, 2018, 08, 12423.56, 23, 2038593
3751, 2018, 09, 5356.31, 6, 203521
3752, 2018, 09, 15.75, 1, 5646471
3753, 2018, 09, 1251, 7, 3036491
3754, 2018, 09, 21484.21, 1356, 049681
3756, 2018, 09, -59.18, 2, 2038593
3757, 2018, 09, 3177.4, 21, 203521
];

Resultaten

Laad de gegevens en open een werkblad. Maak een nieuwe tabel en voeg deze velden toe als dimensies:

• year

• month

Om de transaction_date vast te stellen, maakt u deze meting:

=makedate(transaction_year,transaction_month)

De meting transaction_date wordt gemaakt in het diagramobject met behulp van de makedate()-functie en passeert de jaar- en maandvelden als functieargumenten.

De functie combineert deze waarden vervolgens, evenals de aangenomen dagwaarde van 01. Deze waarden worden geconverteerd in een datumveld en retourneren de resultaten met de indeling van de DateFormat-systeemvariabele.

Overzicht

Maak een kalendergegevensset voor het kalenderjaar 2022.

Load-script

SET DateFormat='MM/DD/YYYY';

Calendar:
	load 
		*
    where year(date)=2022;
load
	date(recno()+makedate(2021,12,31)) as date
AutoGenerate 400;

Resultaten

De makedate()-functie maakt een datumwaarde voor 31 december 2021. De recno()-functie levert het recordnummer van de huidige record die in de tabel wordt geladen, beginnend bij 1. Daarom heeft de eerste record de datum 1 januari 2022. Iedere achtereenvolgende recno() verhoogt deze datum met 1. Deze uitdrukking is verpakt in een date()-functie om de waarde om te zetten in een datum. Dit proces wordt 400 keer herhaald door de autogenerate-functie. Als laatste kan een where-voorwaarde worden gebruikt om alleen datums uit het jaar 2022. Dit kan door het gebruik van een voorafgaande lading. Dit script genereert een kalender met iedere datum in 2022.