maketime - script- en diagramfunctie

Overzicht

Open de editor voor laden van gegevens en voeg het onderstaande load-script toe aan een nieuw tabblad.

Het load-script bevat:

• Een gegevensset met een set transacties die wordt geladen in de tabel Transactions.

• De transactietijden worden ingevoerd in drie velden: hours, minutes en seconds.

• Het veld transaction_time wordt gemaakt dat de tijd retourneert met de notatie van de TimeFormat-systeemvariabele.

Load-script

SET TimeFormat='h:mm:ss TT';

Transactions:
    Load
        *,
        maketime(transaction_hour, transaction_minute, transaction_second) as transaction_time
        ; 
Load * Inline [
transaction_id, transaction_hour, transaction_minute, transaction_second, transaction_amount, transaction_quantity, customer_id
3750, 18, 43, 30, 12423.56, 23, 2038593
3751, 6, 32, 07, 5356.31, 6, 203521
3752, 12, 09, 16, 15.75, 1, 5646471
3753, 21, 43, 41, 7, 3036491
3754, 17, 55, 22, 21484.21, 1356, 049681
3756, 2, 52, 22, -59.18, 2, 2038593
3757, 9, 25, 23, 3177.4, 21, 203521
];

Resultaten

Laad de gegevens en open een werkblad. Maak een nieuwe tabel en voeg deze velden toe als dimensies:

• transaction_hour

• transaction_minute

• transaction_second

• transaction_time

Het veld transaction_time wordt gemaakt in de voorafgaande load-instructie met behulp van de maketime()-functie en geeft de uur-, minuut- en secondevelden door als de argumenten van de functie.

De functie combineert en converteert deze waarden in een tijdveld en retourneert de resultaten met de tijdnotatie van de TimeFormat-systeemvariabele.

Overzicht

Open de editor voor laden van gegevens en voeg het onderstaande load-script toe aan een nieuw tabblad.

Het load-script bevat:

• Dezelfde gegevensset en het scenario uit het eerste voorbeeld.

• Het veld transaction_time wordt gemaakt waarmee we de resultaten kunnen bekijken in een 24-uurs tijdnotatie zonder de TimeFormat-systeemvariabele aan te passen.

Load-script

SET TimeFormat='h:mm:ss TT';

Transactions:
    Load
        *,
        time(maketime(transaction_hour, transaction_minute, transaction_second),'h:mm:ss') as transaction_time
        ; 
Load * Inline [
transaction_id, transaction_hour, transaction_minute, transaction_second, transaction_amount, transaction_quantity, customer_id
3750, 18, 43, 30, 12423.56, 23, 2038593
3751, 6, 32, 07, 5356.31, 6, 203521
3752, 12, 09, 16, 15.75, 1, 5646471
3753, 21, 43, 41, 7, 3036491
3754, 17, 55, 22, 21484.21, 1356, 049681
3756, 2, 52, 22, -59.18, 2, 2038593
3757, 9, 25, 23, 3177.4, 21, 203521
];

Resultaten

Laad de gegevens en open een werkblad. Maak een nieuwe tabel en voeg deze velden toe als dimensies:

• transaction_hour

• transaction_minute

• transaction_second

• transaction_time

In dit geval is de maketime()-functie in de time()-functie genest. Het tweede argument van de time()-functie stelt de notatie van de maketime()-functieresultaten in op de vereiste h:mm:ss.

Overzicht

Open de editor voor laden van gegevens en voeg het onderstaande load-script toe aan een nieuw tabblad.

Het load-script bevat:

• Een gegevensset met een set transacties die wordt geladen in de tabel Transactions.

• De transactietijden worden ingevoerd in twee velden: hours en minutes.

• Het veld transaction_time wordt gemaakt dat de tijd retourneert met de notatie van de TimeFormat-systeemvariabele.

Maak een diagramobjectmeting, transaction_time, die een tijd retourneert met de notatie h:mm:ss TT.

Load-script

SET TimeFormat='h:mm:ss TT';

Transactions:
Load * Inline [
transaction_id, transaction_hour, transaction_minute, transaction_amount, transaction_quantity, customer_id
3750, 18, 43, 12423.56, 23, 2038593
3751, 6, 32, 5356.31, 6, 203521
3752, 12, 09, 15.75, 1, 5646471
3753, 21, 43, 7, 3036491
3754, 17, 55, 21484.21, 1356, 049681
3756, 2, 52, -59.18, 2, 2038593
3757, 9, 25, 3177.4, 21, 203521
];

Resultaten

Laad de gegevens en open een werkblad. Maak een nieuwe tabel en voeg deze velden toe als dimensies:

• transaction_hour

• transaction_minute

Om de transaction_time te berekenen, maakt u deze meting:

=maketime(transaction_hour,transaction_minute)

De meting transaction_time wordt gemaakt in het diagramobject met behulp van de maketime()-functie en passeert de uur- en minuutvelden als functieargumenten.

De functie combineert deze waarden vervolgens en de secondeteller wordt op 00 gezet. Deze waarden worden geconverteerd in een tijdveld en retourneren de resultaten met de notatie van de TimeFormat-systeemvariabele.

Overzicht

Maak een kalendergegevensset voor januari 2022, opgesplitst in delen van acht uur.

Load-script

SET TimestampFormat='M/D/YYYY h:mm:ss[.fff] TT';

tmpCalendar:
	load 
		*
    where year(date)=2022;
load
	date(recno()+makedate(2021,12,31)) as date
AutoGenerate 31;

Left join(tmpCalendar)
load
	maketime((recno()-1)*8,00,00) as time
autogenerate 3;

Calendar:
load
	timestamp(date + time) as timestamp
resident tmpCalendar;

drop table tmpCalendar;

Resultaten

De aanvankelijke autogenerate-functie maakt een kalender met alle datums in januari in de tabel tmpCalendar.

Er wordt een tweede tabel gemaakt met drie records. Voor iedere record, wordt recno() – 1 afgetrokken (waarden 0, 1, 2) en het resultaat wordt vermenigvuldigd met 8. Het resultaat is dat dit de waarden 0, 8 16 genereert. Deze waarden worden gebruikt als de uurparameter in een maketime()-functie met minuut- en secondewaarden van 0. Het resultaat is dat de tabel drie tijdvelden bevat: 12:00:00 AM, 8:00:00 AM en 4:00:00 PM.

Deze tabel wordt samengevoegd met de tmpCalendar-tabel. Omdat de twee tabellen geen overeenkomende velden bevatten voor de samenvoeging, worden er aan iedere datumrij tijdrijen toegevoegd. Daardoor wordt iedere datumrij nu drie keer met iedere tijdwaarde herhaald.

Als laatste wordt de tabel Kalender gemaakt vanuit een resident-load van de tmpCalendar-tabel. De datum- en tijdvelden worden aaneengeschakeld en in de timestamp()-functie verpakt om het tijdstempelveld te maken.

De tmpCalendar-tabel wordt dan verwijderd.