Num - Skript- und Diagrammfunktion

Num() formatiert eine Zahl, konvertiert also den Zahlenwert der Eingabe in den Eingabetext mit dem Format, das im zweiten Parameter angegeben ist. Wenn der zweite Parameter ausgelassen wird, werden die Dezimal- und Tausendertrennzeichen verwendet, die im Datenladeskript festgelegt sind. Angepasste Dezimal- und Tausendertrennzeichen sind optionale Parameter.

Syntax:

Num(number[, format[, dec_sep [, thou_sep]]])

Rückgabe Datentyp: dual

Die Funktion Num gibt einen dualen Wert mit dem String- und dem Zahlenwert zurück. Die Funktion nimmt den Zahlenwert der Eingabeformel und generiert einen String, der die Zahl repräsentiert.

Argumente
Argument	Beschreibung
number	Der zu evaluierende Textstring.
format	String zur Angabe der Formatierung des resultierenden Strings. Ist kein String angegeben, werden die Dezimal- und Tausendertrennzeichen verwendet, die im Datenladeskript festgelegt sind. Die Funktion Num unterstützt viele Formatoptionen für verschiedene numerische Strukturen, zum Beispiel: #,##0: Zeigt eine Zahl ohne Dezimalstellen an. #,##0.00: Zeigt eine Zahl mit zwei Dezimalstellen an. ##0.00%: Zeigt eine Zahl als Prozentsatz mit zwei Dezimalstellen an. #,##0;(#,##0): Formatiert negative Werte in Klammern. $#,##0.00: Formatiert Zahlen als Währung mit einem $-Symbol. 0.00E+0: Zeigt Zahlen in wissenschaftlicher Schreibweise an.
dec_sep	String zur Angabe des Dezimaltrennzeichens. Ist kein String angegeben, wird der vom Datenladeskript vorgegebene Wert der Variablen DecimalSep verwendet. Die Funktion Num unterstützt viele Formate für das Dezimaltrennzeichen, zum Beispiel: Komma „ , “: zum Beispiel $1,000,00 für eintausend Dollar. Zeitraum „ . “: zum Beispiel € 1,000.00. Bindestrich „ - “: Wenn er anstelle des traditionellen Punkts oder Kommas als Dezimaltrennzeichen verwendet wird, werden Werte wie ¥1,000-00 angezeigt. Weitere Informationen finden Sie unter DecimalSep.
thou_sep	String zur Angabe des Tausendertrennzeichens. Ist kein String angegeben, wird der vom Datenladeskript vorgegebene Wert der Variablen ThousandSep verwendet. Die Funktion Num unterstützt viele Optionen für das Tausendertrennzeichen: Punkt „ . “: Verwendet einen Punkt als Tausendertrennzeichen (in einigen europäischen Formaten üblich) und wird in Kombination mit einem Komma als Dezimaltrennzeichen als $1.000,00 angezeigt. Leerzeichen „ “: Verwendet ein Leerzeichen als Tausendertrennzeichen, was in einigen europäischen Ländern üblich ist. Wird als € 1 000.00 angezeigt. Unterstrich „_“:Verwendet einen Unterstrich als Tausendertrennzeichen, was manchmal in technischen oder spezifischen regionalen Formaten verwendet wird. Zeigt Werte wie $1_000.00 an. Weitere Informationen finden Sie unter ThousandSep.

Weitere Informationen zur Formatierung von Zahlen finden Sie unter Konventionen für Zahlen- und Uhrzeitformate.

Beispiel: Diagrammformeln
Beispiel	Ergebnisse (zurückgegebener String-Wert)
Num(35648.312)	Gibt 35648.312 zurück (abhängig von den Umgebungsvariablen im Skript)
Num(35648.312, '0.0', '.')	Gibt 35648.3 zurück
Num(35648.312, '0,00', ',')	Gibt 3,56,48 zurück
Num(35648.312, '#,##0.0', '.', ',')	Gibt 35,648.3 zurück
Num(35648.312, '# ##0', ',', ' ')	Gibt 35 648 zurück

Beispiel – Grundlegendes zu „Num“

Übersicht

Öffnen Sie den Dateneditor und fügen Sie das Ladeskript unten in einen neuen Abschnitt ein.

Das Ladeskript umfasst:

Datensatz, der in eine Datentabelle namens Example geladen wird
Die folgenden Felder in einer Datentabelle:
- InputValue

Ladeskript

Example:
Load * inline [
InputValue
35648
3564800
356.48
];

Ergebnisse

Laden Sie die Daten und öffnen Sie ein Arbeitsblatt. Erstellen Sie eine neue Tabelle und fügen Sie dieses Feld als Dimension hinzu:

InputValue

Erstellen Sie die folgenden Kennzahlen:

=Num(InputDate), um den Wert als Zahl anzuzeigen, die entsprechend der Systemeinstellung formatiert ist.
=Num(InputValue, '0.0', '.'), um den Wert als Zahl anzuzeigen, die mit dem in der Funktion angegebenen Format formatiert ist.
=Num(InputValue, '0,00', ','), um den Wert als Zahl anzuzeigen, die mit dem in der Funktion angegebenen Format formatiert ist.
=Num(InputValue, '#,##0.0', '.', ','), um den Wert als Zahl anzuzeigen, die mit dem in der Funktion angegebenen Format formatiert ist.
=Num(InputValue, '# ##0', ',', ' '), um den Wert als Zahl anzuzeigen, die mit dem in der Funktion angegebenen Format formatiert ist.

Results table
InputValue	Num(InputDate)	Num(InputValue, '0.0', '.')	Num(InputValue, '0,00', ',')	Num(InputValue, '#,##0.0', '.', ',')	Num(InputValue, '# ##0', ',', ' ')
356.48	356.48	356.5	3,56	356.5	356
35648	35648	35648.0	3,56,48	35,648.0	35 648
3564800	3564800	3564800.0	3,56,48,00	3,564,800.0	3 564 800

Die Ergebnisse zeigen, wie die Funktion Num die Werte für das Feld InputValue basierend auf dem in der Funktionsformel angegebenen Format anzeigen kann.

Die Funktion Num kann im Ladeskript zum Formatieren einer Zahl verwendet werden, selbst wenn die Tausender- und Dezimaltrennzeichen bereits im Skript festgelegt sind. Das folgende Ladeskript enthält spezifische Tausender- und Dezimaltrennzeichen, verwendet dann aber Num zum Formatieren von Daten auf unterschiedliche Arten.

Ladeskript

Erstellen Sie im Dateneditor einen neuen Abschnitt, fügen Sie dann das Beispielskript hinzu und führen Sie es aus. Fügen Sie einem Arbeitsblatt in Ihrer App dann mindestens diejenigen Felder hinzu, die in der Ergebnistabelle aufgeführt sind, um das Ergebnis anzuzeigen.

SET ThousandSep=',';
SET DecimalSep='.';
Transactions:
Load
*,
Num(transaction_amount) as [No formatting],
Num(transaction_amount,'0') as [0],
Num(transaction_amount,'#,##0') as [#,##0],
Num(transaction_amount,'# ###,00') as [# ###,00],
Num(transaction_amount,'# ###,00',',',' ') as [# ###,00 , ',' , ' '],
Num(transaction_amount,'#,###.00','.',',') as [#,###.00 , '.' , ','],
Num(transaction_amount,'$#,###.00') as [$#,###.00],
;
Load * Inline [
transaction_id, transaction_date, transaction_amount, transaction_quantity, discount, customer_id, size, color_code
3750, 20180830, 12423.56, 23, 0,2038593, L, Red
3751, 20180907, 5356.31, 6, 0.1, 203521, m, orange
3752, 20180916, 15.75, 1, 0.22, 5646471, S, blue
3753, 20180922, 1251, 7, 0, 3036491, l, Black
3754, 20180922, 21484.21, 1356, 75, 049681, xs, Red
3756, 20180922, -59.18, 2, 0.333333333333333, 2038593, M, Blue
3757, 20180923, 3177.4, 21, .14, 203521, XL, Black
];

Ergebnisse

Qlik Sense Tabelle mit den Ergebnissen verschiedener Verwendungsweisen der Num-Funktion im Ladeskript. Die vierte Spalte der Tabelle enthält zu Beispielzwecken eine falsche Formatierung.
No formatting	0	#,##0	# ###,00	# ###,00 , ',' , ' '	#,###.00 , '.' , ','	$#,###.00
-59.18	-59	-59	-59###,00	-59,18	-59.18	$-59,18
15.75	16	16	16###,00	15,75	15.75	$15,75
1251	1251	1,251	1251###,00	1 251,00	1,251.00	$1,251.00
3177.4	3177	3,177	3177###,00	3 177,40	3,177.40	$3,177.40
5356.31	5356	5,356	5356###,00	5 356,31	5,356.31	$5,356.31
12423.56	12424	12,424	12424###,00	12 423,56	12,423.56	$12,423.56
21484.21	21484	21,484	21484###,00	21 484,21	21,484.21	$21,484.21

Beispiel – Szenario für „Num“

Übersicht

Ein Datensatz enthält Umsatzdaten, die Sie in einem einfacheren numerischen Format darstellen möchten.

Öffnen Sie den Dateneditor und fügen Sie das Ladeskript unten in einen neuen Abschnitt ein.

Das Ladeskript umfasst:

Datensatz, der in eine Datentabelle namens Example geladen wird
Die folgenden Felder in der Datentabelle:
- Customer
- Sales

Ladeskript

Example:
Load * inline [
Customer, Sales
Customer A, 2550000
Customer B, 12500
Customer C, 15000
Customer D, 250
];

Ergebnisse

Laden Sie die Daten und öffnen Sie ein Arbeitsblatt. Erstellen Sie eine neue Tabelle und fügen Sie dieses Feld als Dimension hinzu:

Customer

Erstellen Sie die folgende Kennzahl:

=If(Sales > 1000000, Num(Sales/1000000, '#,##0.00M'), If(Sales > 1000, Num(Sales/1000, '#,##0.00K'), Num(Sales, '#,##0.00'))), um die numerische Darstellung der Werte festzulegen.

Results table
Customer	If(Sales > 1000000, Num(Sales/1000000, '#,##0.00M'), If(Sales > 1000, Num(Sales/1000, '#,##0.00K'), Num(Sales, '#,##0.00')))
Customer A	2.55M
Customer B	12.50K
Customer C	15.00K
Customer D	250.00

Die Kennzahlenformel in Spalte 2 verwendet die Funktion Num, um die Daten in einem vereinfachten numerischen Format darzustellen.

Die Funktion Num kann in einem Ladeskript zum Formatieren einer Zahl als Prozentsatz verwendet werden.

Ladeskript

Erstellen Sie im Dateneditor einen neuen Abschnitt, fügen Sie dann das Beispielskript hinzu und führen Sie es aus. Fügen Sie einem Arbeitsblatt in Ihrer App dann die Felder hinzu, die in der Ergebnisspalte aufgeführt sind, um das Ergebnis anzuzeigen.

SET ThousandSep=','; SET DecimalSep='.'; Transactions: Load *, Num(discount,'#,##0%') as [Discount #,##0%] ; Load * Inline [ transaction_id, transaction_date, transaction_amount, transaction_quantity, discount, customer_id, size, color_code 3750, 20180830, 12423.56, 23, 0,2038593, L, Red 3751, 20180907, 5356.31, 6, 0.1, 203521, m, orange 3752, 20180916, 15.75, 1, 0.22, 5646471, S, blue 3753, 20180922, 1251, 7, 0, 3036491, l, Black 3754, 20180922, 21484.21, 1356, 75, 049681, xs, Red 3756, 20180922, -59.18, 2, 0.333333333333333, 2038593, M, Blue 3757, 20180923, 3177.4, 21, .14, 203521, XL, Black ];

Qlik Sense Tabelle mit den Ergebnissen der Num-Funktion, die im Ladeskript zum Formatieren von Prozentsätzen verwendet wird.
Discount	Discount #,##0%
0	0%
0.1	10%
0.22	22%
0	0%
75	7,500%
0.333333333333333	33%
.14	14%

Hat diese Seite Ihnen geholfen?

Wenn Sie Probleme mit dieser Seite oder ihren Inhalten feststellen – einen Tippfehler, einen fehlenden Schritt oder einen technischen Fehler –, teilen Sie uns bitte mit, wie wir uns verbessern können!

Geben Sie hier Ihr Feedback ab