Parfois, vous devez définir un ensemble de valeurs de champ à l'aide d'une définition d'ensemble imbriquée. Par exemple, vous pouvez souhaiter sélectionner tous les clients qui ont acheté un produit spécifique sans sélectionner le produit.
Dans de tels cas, utilisez les fonctions d'ensemble d'éléments P() et E(). Elles renvoient les ensembles d'éléments de valeurs possibles et les valeurs exclues d'un champ, respectivement. À l'intérieur des parenthèses, vous pouvez spécifier le champ en question et une expression d'ensemble qui définit l'étendue. Par exemple :
P({1<Year = {2021}>} Customer)
Cela renverra l'ensemble des clients qui ont effectué des translations en 2021. Vous pouvez alors utiliser ce résultat dans un modificateur d'ensemble. Par exemple :
Sum({<Customer = P({1<Year = {2021}>} Customer)>} Amount)
Cette expression d'ensemble sélectionnera ces clients, mais ne limitera pas la sélection à 2021.
Il est impossible d'employer ces fonctions dans d'autres expressions.
De plus, seuls les ensembles naturels peuvent être utilisés à l'intérieur des fonctions d'ensemble d'éléments. Un ensemble naturel est un ensemble d'enregistrements qu'il est possible de définir par une sélection simple.
Par exemple, l'ensemble fourni par {1-$} ne peut pas toujours être défini par le biais d'une sélection et, de ce fait, il ne s'agit pas d'un ensemble naturel. L'application de ces fonctions à des ensembles non naturels renverra des résultats inattendus.
Exemples : Expressions de graphique pour modificateurs d'ensemble avec des fonctions d'ensemble
Script de chargement
Chargez les données suivantes sous forme de chargement inline dans l'éditeur de chargement de données pour créer les exemples d'expression de graphique ci-dessous.
MyTable:
Load
Year(Date) as Year,
Date#(Date,'YYYY-MM-DD') as ISO_Date,
Date(Date#(Date,'YYYY-MM-DD'),'M/D/YYYY') as US_Date,
Country, Product, Amount
Inline
[Date, Country, Product, Amount
2018-02-20, Canada, Washer, 6
2018-07-08, Germany, Anchor bolt, 10
2018-07-14, Germany, Anchor bolt, 3
2018-08-31, France, Nut, 2
2018-09-02, Czech Republic, Bolt, 1
2019-02-11, Czech Republic, Bolt, 3
2019-07-31, Czech Republic, Washer, 6
2020-03-13, France, Anchor bolt, 1
2020-07-12, Canada, Anchor bolt, 8
2020-09-16, France, Washer, 1]; Pour plus d'informations sur l'utilisation des chargements inline, voir Utilisation de chargements inline pour charger des données.
Expressions de graphique
Créez une table dans une feuille Qlik Sense avec les expressions de graphique suivantes.
| Country | Sum(Amount) | Sum({<Country=P({<Year={2019}>}Country)>} Amount) | Sum({<Product=P({<Year={2019}>}Product)>} Amount) | Sum({<Country=E({<Product={Washer}>}Country)>} Amount) |
|---|---|---|---|---|
| Totaux | 41 | 10 | 17 | 13 |
| Canada | 14 | 0 | 6 | 0 |
| République tchèque | 10 | 10 | 10 | 0 |
| FRANCE | 4 | 0 | 1 | 0 |
| Allemagne | 13 | 0 | 0 | 13 |
Explication
-
Dimensions :
-
Country
-
-
Mesures :
-
Sum(Amount)
somme Amount sans expression d'ensemble.
-
Sum({<Country=P({<Year={2019}>} Country)>} Amount)
Somme Amount des pays associés à l'année 2019. Cependant, cela ne limitera le calcul à l'année 2019.
-
Sum({<Product=P({<Year={2019}>} Product)>} Amount)
Somme Amount des produits associés à l'année 2019. Cependant, cela ne limitera le calcul à l'année 2019.
-
Sum({<Country=E({<Product={Washer}>} Country)>} Amount)
Somme Amount des pays non associés au produit Washer.
-
Modificateurs d'ensemble utilisant des fonctions d'ensemble
Pour plus d'informations sur les expressions, voir Utilisation d'expressions dans les visualisations.
| Exemples | Résultats |
|---|---|
| sum( {$<Customer = P({1<Product={'Shoe'}>} Customer)>} Sales ) |
Renvoie les ventes pour la sélection active, mais seuls les clients ayant un jour acheté le produit « Shoe » sont retenus. La fonction d'élément P( ) renvoie alors une liste de clients possibles, ceux qui sont concernés par la sélection « Shoe » dans le champ Product. |
| sum( {$<Customer = P({1<Product={'Shoe'}>})>} Sales ) |
Comme précédemment. Si le champ est omis dans la fonction d'élément, la fonction renvoie les valeurs possibles pour le champ spécifié dans l'affectation extérieure. |
| sum( {$<Customer = P({1<Product={'Shoe'}>} Supplier)>} Sales ) |
Renvoie les ventes pour la sélection active, mais seulement les clients ayant un jour fourni le produit 'Shoe', à savoir, les clients également fournisseurs. La fonction d'élément P( ) renvoie alors une liste de fournisseurs possibles, ceux qui sont concernés par la sélection « Shoe » dans le champ Product. La liste des fournisseurs est alors utilisée comme sélection dans le champ Customer. |
| sum( {$<Customer = E({1<Product={'Shoe'}>})>} Sales ) |
Renvoie les ventes pour la sélection active, mais seuls les clients n'ayant jamais acheté le produit « Shoe » sont retenus. La fonction d'élément E( ) renvoie alors la liste des clients exclus, ceux qui ne font pas partie de la sélection « Shoe » dans le champ Product. |