Modificadores de conjunto com pesquisas

Script de carregamento

Carregue os seguintes dados como um carregamento inline no editor de carregamento de dados para criar os exemplos de expressão de gráfico abaixo.

MyTable:
Load 
Year(Date) as Year,
Date#(Date,'YYYY-MM-DD') as ISO_Date, 
Date(Date#(Date,'YYYY-MM-DD'),'M/D/YYYY') as US_Date, 
Country, Product, Amount 
Inline
[Date, Country, Product, Amount
2018-02-20, Canada, Washer, 6
2018-07-08, Germany, Anchor bolt, 10
2018-07-14, Germany, Anchor bolt, 3
2018-08-31, France, Nut, 2
2018-09-02, Czech Republic, Bolt, 1
2019-02-11, Czech Republic, Bolt, 3
2019-07-31, Czech Republic, Washer, 6
2020-03-13, France, Anchor bolt, 1
2020-07-12, Canada, Anchor bolt, 8
2020-09-16, France, Washer, 1];	

Para obter mais informações sobre como usar carregamentos inline, consulte Usando carregamentos inline para carregar dados.

Exemplo 1: expressões de gráfico com pesquisas de texto

Crie uma tabela em uma pasta do Qlik Sense com as seguintes expressões de gráfico.

Explicação

• Dimensões:

  • Country

• Medidas:

  • Sum(Amount)

    Soma Amount, sem expressão de conjunto.

  • Sum({<Country={"C*"}>}Amount)

    Soma Amount para todos os países que começam com C, como Canada e Czech Republic.

  • Sum({<Country={"*^R*"}>}Amount)

    Soma Amount para todos os países que têm uma palavra que começa com R, como Czech Republic.

  • Sum({<Product={"*bolt*"}>}Amount)

    Soma Amount para todos os produtos que contêm a sequência de caracteres bolt, como Bolt e Anchor bolt.

Para obter mais informações sobre expressões, consulte Usando expressões em visualizações.

Exemplo 2: expressões de gráfico com pesquisas numéricas.

Crie uma tabela em uma pasta do Qlik Sense com as seguintes expressões de gráfico.

Explicação

• Dimensões:

  • Country

• Medidas:

  • Sum(Amount)

    Soma Amount, sem expressão de conjunto.

  • Sum({<Year={">2019"}>}Amount)

    Soma Amount por todos os anos após 2019.

  • Sum({<ISO_Date={">=2019-07-01"}>}Amount)

    Soma Amount para todas as datas em ou depois de 2019-07-01. O formato da data na pesquisa deve corresponder ao formato do campo.

  • Sum({<US_Date={">=4/1/2018<=12/31/2018"}>}Amount)

    Soma Amount para todas as datas de 4/1/2018 a 12/31/2018, incluindo as datas de início e de término. O formato das datas na pesquisa deve corresponder ao formato do campo.

Exemplo 3: expressões de gráfico com pesquisas de expressão

Crie uma tabela em uma pasta do Qlik Sense com as seguintes expressões de gráfico.

Explicação

• Dimensões:

  • Country

• Medidas:

  • Sum(Amount)

    Soma Amount, sem expressão de conjunto.

  • Sum({<Country={"=Sum(Amount)>10"}>}Amount)

    Soma Amount para todos os países que têm uma soma agregada de Amount maior que 10.

  • Sum({<Country={"=Count(distinct Product)=1"}>}Amount)

    Soma Amount para todos os países associados a exatamente um produto distinto.

  • Sum({<Product={"=Count(Amount)>3"}>}Amount)

    Soma Amount para todos os países que têm mais de três transações nos dados.