Set değiştiriciler içeren aramalar

Yükleme kodu

Aşağıdaki grafik ifadesi örneklerini oluşturmak için aşağıdaki verileri veri yükleme düzenleyicisinde satır içi yükleme olarak yükleyin.

MyTable:
Load 
Year(Date) as Year,
Date#(Date,'YYYY-MM-DD') as ISO_Date, 
Date(Date#(Date,'YYYY-MM-DD'),'M/D/YYYY') as US_Date, 
Country, Product, Amount 
Inline
[Date, Country, Product, Amount
2018-02-20, Canada, Washer, 6
2018-07-08, Germany, Anchor bolt, 10
2018-07-14, Germany, Anchor bolt, 3
2018-08-31, France, Nut, 2
2018-09-02, Czech Republic, Bolt, 1
2019-02-11, Czech Republic, Bolt, 3
2019-07-31, Czech Republic, Washer, 6
2020-03-13, France, Anchor bolt, 1
2020-07-12, Canada, Anchor bolt, 8
2020-09-16, France, Washer, 1];	

Satır içi yüklemeleri kullanma hakkında daha fazla bilgi için bk. Veri yüklemek için satır içi yüklemeler kullanma.

1. Örnek: Metin aramaları içeren grafik ifadeleri

Aşağıdaki grafik ifadeleriyle Qlik Sense sayfasında bir tablo oluşturun.

Açıklama

• Boyutlar:

  • Country

• Hesaplamalar:

  • Sum(Amount)

    Set ifadesi olmadan Amount toplamını al.

  • Sum({<Country={"C*"}>}Amount)

    Canada ve Czech Republic gibi C ile başlayan tüm ülkeler için Amount toplamını al.

  • Sum({<Country={"*^R*"}>}Amount)

    Czech Republic gibi R ile başlayan tüm ülkeler için Amount değerini topla.

  • Sum({<Product={"*bolt*"}>}Amount)

    Bolt ve Anchor bolt gibi bolt dizesini içeren tüm ürünler için Amount değerini topla.

İfadeler hakkında daha fazla bilgi için bkz. Görselleştirmelerde ifadeleri kullanma.

2. Örnek: Sayısal aramalar içeren grafik ifadeleri

Aşağıdaki grafik ifadeleriyle Qlik Sense sayfasında bir tablo oluşturun.

Açıklama

• Boyutlar:

  • Country

• Hesaplamalar:

  • Sum(Amount)

    Set ifadesi olmadan Amount toplamını al.

  • Sum({<Year={">2019"}>}Amount)

    2019 sonrası tüm yıllar için Amount değerini topla.

  • Sum({<ISO_Date={">=2019-07-01"}>}Amount)

    2019-07-01 veya sonraki tarihler için Amount değerlerini topla. Aramadaki tarihin biçimi, alanın biçimiyle eşleşmelidir.

  • Sum({<US_Date={">=4/1/2018<=12/31/2018"}>}Amount)

    Başlangıç ve bitiş tarihleri dahil 4/1/2018 ile 12/31/2018 arasındaki tüm tarihler için Amount değerlerini topla. Aramadaki tarihlerin biçimi, alanın biçimiyle eşleşmelidir.

3. Örnek: İfade aramaları içeren grafik ifadeleri

Aşağıdaki grafik ifadeleriyle Qlik Sense sayfasında bir tablo oluşturun.

Açıklama

• Boyutlar:

  • Country

• Hesaplamalar:

  • Sum(Amount)

    Set ifadesi olmadan Amount toplamını al.

  • Sum({<Country={"=Sum(Amount)>10"}>}Amount)

    Birleştirilmiş Amount toplam değeri 10 üzerinde olan tüm ülkeler için Amount değerini topla.

  • Sum({<Country={"=Count(distinct Product)=1"}>}Amount)

    Tam olarak tek bir ürünle ilişkili tüm ülkeler için Amount değerini topla.

  • Sum({<Product={"=Count(Amount)>3"}>}Amount)

    Verilerinde üçten fazla işlem olan tüm ülkeler için Amount değerini topla.