検索を使った set 修飾子

ロード スクリプト

以下のデータをインライン データとしてデータロードエディタにロードして、以下のチャートの数式の例を作成します。

MyTable:
Load 
Year(Date) as Year,
Date#(Date,'YYYY-MM-DD') as ISO_Date, 
Date(Date#(Date,'YYYY-MM-DD'),'M/D/YYYY') as US_Date, 
Country, Product, Amount 
Inline
[Date, Country, Product, Amount
2018-02-20, Canada, Washer, 6
2018-07-08, Germany, Anchor bolt, 10
2018-07-14, Germany, Anchor bolt, 3
2018-08-31, France, Nut, 2
2018-09-02, Czech Republic, Bolt, 1
2019-02-11, Czech Republic, Bolt, 3
2019-07-31, Czech Republic, Washer, 6
2020-03-13, France, Anchor bolt, 1
2020-07-12, Canada, Anchor bolt, 8
2020-09-16, France, Washer, 1];	

インライン ロードの使用の詳細については、インライン ロードを使用したデータのロード を参照してください。

例 1: テキスト検索を使用したチャートの数式。

次のチャートの数を使用して、Qlik Sense シートにテーブルを作成します。

説明

• 軸：

  • Country

• 数式：

  • Sum(Amount)

    set 数式なしで Amount を合計します。

  • Sum({<Country={"C*"}>}Amount)

    Canada や Czech Republic など、C で始まるすべての国について Amount を合計します。

  • Sum({<Country={"*^R*"}>}Amount)

    Czech Republic など、R で始まる単語があるすべての国について Amount を合計します。

  • Sum({<Product={"*bolt*"}>}Amount)

    Bolt や Anchor bolt など、文字列 bolt を含むすべての製品について Amount を合計します。

数式の詳細については、「ビジュアライゼーションにおける数式の使用」を参照してください。

例 2: 数値の検索を使用したチャートの数式。

次のチャートの数を使用して、Qlik Sense シートにテーブルを作成します。

説明

• 軸：

  • Country

• 数式：

  • Sum(Amount)

    set 数式なしで Amount を合計します。

  • Sum({<Year={">2019"}>}Amount)

    2019 以降のすべての年の場合は Sum Amount です。

  • Sum({<ISO_Date={">=2019-07-01"}>}Amount)

    2019-07-01 以降のすべての日付の場合は Sum Amount です。検索での日付の形式は、項目の形式と一致する必要があります。

  • Sum({<US_Date={">=4/1/2018<=12/31/2018"}>}Amount)

    開始日と終了日を含む、4/1/2018 から 12/31/2018 までのすべての日付の場合は Sum Amount です。検索での日付の形式は、項目の形式と一致する必要があります。

例 3: 数式の検索を使用したチャートの数式

次のチャートの数を使用して、Qlik Sense シートにテーブルを作成します。

説明

• 軸：

  • Country

• 数式：

  • Sum(Amount)

    set 数式なしで Amount を合計します。

  • Sum({<Country={"=Sum(Amount)>10"}>}Amount)

    Amount の合計が 10 より大きいすべての国の場合は Sum Amount です。

  • Sum({<Country={"=Count(distinct Product)=1"}>}Amount)

    正確に 1 つの異なる製品に関連付けられているすべての国の場合は Sum Amount です。

  • Sum({<Product={"=Count(Amount)>3"}>}Amount)

    データに 3 つ以上のトランザクションがあるすべての国の場合は Sum Amount です。