含搜尋的集合修飾詞

載入指令碼

在資料載入編輯器中載入下列資料作為內嵌載入，以建立以下的圖表運算式範例。

MyTable:
Load 
Year(Date) as Year,
Date#(Date,'YYYY-MM-DD') as ISO_Date, 
Date(Date#(Date,'YYYY-MM-DD'),'M/D/YYYY') as US_Date, 
Country, Product, Amount 
Inline
[Date, Country, Product, Amount
2018-02-20, Canada, Washer, 6
2018-07-08, Germany, Anchor bolt, 10
2018-07-14, Germany, Anchor bolt, 3
2018-08-31, France, Nut, 2
2018-09-02, Czech Republic, Bolt, 1
2019-02-11, Czech Republic, Bolt, 3
2019-07-31, Czech Republic, Washer, 6
2020-03-13, France, Anchor bolt, 1
2020-07-12, Canada, Anchor bolt, 8
2020-09-16, France, Washer, 1];	

如需更多關於使用內嵌載入的資訊，請參閱 使用內嵌載入以載入資料。

範例 1：含文字搜尋的圖表運算式

透過下列圖表運算式在 Qlik Sense 工作表中建立表格。

解釋

• 維度：

  • Country

• 量值：

  • Sum(Amount)

    不含集合運算式的 Amount 總和。

  • Sum({<Country={"C*"}>}Amount)

    以 C 開頭的所有國家的總和 Amount，例如 Canada 和 Czech Republic。

  • Sum({<Country={"*^R*"}>}Amount)

    有個字以 R 開頭的所有國家的總和 Amount，例如 Czech Republic。

  • Sum({<Product={"*bolt*"}>}Amount)

    包含字串 bolt 的所有產品的總和 Amount，例如 Bolt 和 Anchor bolt。

如需關於運算式的詳細資訊，請參閱在視覺化中使用運算式。

範例 2：含數值搜尋的圖表運算式

透過下列圖表運算式在 Qlik Sense 工作表中建立表格。

解釋

• 維度：

  • Country

• 量值：

  • Sum(Amount)

    不含集合運算式的 Amount 總和。

  • Sum({<Year={">2019"}>}Amount)

    2019 之後所有年份的總和 Amount。

  • Sum({<ISO_Date={">=2019-07-01"}>}Amount)

    2019-07-01 當日或之後所有日期的總和 Amount。搜尋中的日期格式必須符合欄位格式。

  • Sum({<US_Date={">=4/1/2018<=12/31/2018"}>}Amount)

    從 4/1/2018 至 12/31/2018 所有日期的總和 Amount，包括開始和結束日期。搜尋中的日期格式必須符合欄位格式。

範例 3：含運算式搜尋的圖表運算式

透過下列圖表運算式在 Qlik Sense 工作表中建立表格。

解釋

• 維度：

  • Country

• 量值：

  • Sum(Amount)

    不含集合運算式的 Amount 總和。

  • Sum({<Country={"=Sum(Amount)>10"}>}Amount)

    Amount 彙總總和大於 10 的所有國家的總和 Amount。

  • Sum({<Country={"=Count(distinct Product)=1"}>}Amount)

    與確切一個相異產品相關的所有國家的總和 Amount。

  • Sum({<Product={"=Count(Amount)>3"}>}Amount)

    在資料中有超過三筆交易的所有國家的總和 Amount。