Caricamento dei dati da tabelle inline

Panoramica

Questo esempio dimostra come sia possibile utilizzare gli apici rovesciati per racchiudere i dati inline. I dati dell'esempio contengono caratteri di parentesi quadra, il che rende le parentesi quadre incompatibili come contenitori per l'istruzione LOAD.

Script di caricamento

DataTable:

Load * inline 
`
custom_property, date, amount
[11402], 1/1/2024, 92.99
[11403], 1/2/2024, 102.34
[11404], 1/3/2024, 50.26
[11405], 1/4/2024, 153.69
[11406], 1/5/2024, 75.62
`;

Risultati

• custom_property

• date

• amount

Panoramica

Lo scambio del delimitatore è utile quando i dati della tabella contengono virgole, che altrimenti segnalerebbero il passaggio alla colonna successiva della tabella.

Questo esempio contiene quattro tabelle da caricare. Sono le seguenti:

• Quattro tabelle da caricare. Sono le seguenti:

  • Table1: Il delimitatore è una barra verticale (pipe). I dati nella colonna Phrase contengono virgole.

  • Table2: il delimitatore è un segno dei due punti.

  • Table3: il delimitatore è una barra rovesciata.

  • Table4: la tabella viene delimitata premendo il tasto Tab sulla tastiera. Questa opzione è utile quando si copia una tabella da un elaboratore di testi e la si incolla nello script.

  Table1 mostra un caso pratico di utilizzo di un delimitatore alternativo. Le altre tabelle mostrano altre opzioni di delimitatori.

Script di caricamento

Table1:
LOAD * INLINE [
ID|Phrase
1 | 'The transaction was complete, but the order has not yet shipped.'
2 | 'We need to confirm the following details: sales rep number, order status, and shipping priority.'
] (Delimiter is '|');

Table2:
LOAD * INLINE [
Num1:Chr1
1:A
2:B ] (Delimiter is ':');

Table3:
LOAD * INLINE [
Num2\Chr2
1\A
2\B ] (Delimiter is \\);

Table4:
LOAD * INLINE [
Num3	Chr3
1	A
2	B ] (Delimiter is '\t');

Risultati

Panoramica

Questo esempio dimostra come sia possibile caricare una tabella inline senza definire i nomi delle colonne.

Script di caricamento

Expenses:

Load * inline
[
1,Category1,40566.49
2,Category2,3504.54
3,Category3,593206.30
] (no labels);

Risultati

Panoramica

Questo esempio di script contiene quanto segue:

• Un'istruzione di caricamento in linea che definisce la tabella DataTable.
• L'uso di fix (all'interno della specifica Table format) per indicare che i dati da caricare sono in formato record fisso.

Script di caricamento

DataTable:
LOAD
"@1:4",
"@5:8",
"@9:12",
"@13:16"
INLINE [
a   b   c   d
1   2   3   4
x   y   z   w
] (fix, utf8, embedded labels);

Risultati

Script di caricamento

ORDERS:

Load Original as Updated,
* Inline
[
Original
ProductA
ProductB
ProductC
];

Risultati

Panoramica

Questo esempio mostra come sia possibile definire un campo calcolato per indicare l'ID di ogni riga di dati, senza dover digitare manualmente ogni valore ID.

Script di caricamento

ORDERS:

Load RowNo() as ID,
* Inline
[
ProductName
A
B
C
D
E
];

Risultati

Panoramica

Questo esempio mostra diversi modi in cui una semplice trasformazione può essere applicata ai dati inline. È possibile utilizzare una o più istruzioni LOAD e configurare la sintassi in modi diversi, per definire se una trasformazione sostituisce o meno il campo originale o se vengono caricati sia il campo originale che quello nuovo.

In particolare, si notino le variazioni di seguito elencate e il loro effetto sull'output:

• Numero di istruzioni LOAD all'interno della tabella.

• Presenza o assenza del simbolo * (carica tutti i campi successivi).

• Presenza o assenza delle virgole (simbolo ,).

Questo esempio di script contiene quanto segue:

• Quattro tabelle, che fanno tutte riferimento agli stessi dati. I nomi dei campi sono diversi.

  • DerivedYears1: usa due istruzioni LOAD per caricare una colonna inline e una colonna contenente una trasformazione della colonna inline.

  • DerivedYears2: usa due istruzioni LOAD. Lo script carica una colonna inline, quindi carica un campo calcolato trasformato dalla colonna originale. Con la seconda istruzione LOAD, la colonna originale non viene caricata nella tabella, rendendo di fatto il nuovo campo una sostituzione del campo originale.

  • DerivedYears3: usa una singola istruzione LOAD per caricare sia la colonna originale inline che una colonna trasformata.

  • DerivedYears4: usa una singola istruzione LOAD per definire un campo in linea e una trasformazione del campo originale. Nella tabella viene caricato solo il campo trasformato.

Script di caricamento

DerivedYears1:

Load *,
Year(initial_date1) as derived_year1
;
    
Load
* inline [
initial_date1
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears2:

Load
Year(initial_date2) as derived_year2
;
    
Load
* inline [
initial_date2
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears3:

Load Year(initial_date3) as derived_year3,
* inline [
initial_date3
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears4:

Load Year(initial_date4) as derived_year4
inline [
initial_date4
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

Risultati

Panoramica

Si supponga di incollare le informazioni da un file di testo di grandi dimensioni nell'editor script, ma di voler eseguire un'elaborazione aggiuntiva sui record del set di dati. Ad esempio, si desidera rimuovere alcuni caratteri e prefissi e scrivere in maiuscolo ogni parola.

Questo esempio di script contiene quanto segue:

• Una tabella inline, Transformations, in cui si definisce una trasformazione per cambiare il contenuto del testo di un campo. Il testo da trasformare viene aggiunto dopo.

• Due istruzioni LOAD. Con la configurazione dell'esempio, solo il campo derivato ProductName_Trimmed viene caricato nella tabella.

Script di caricamento

Transformations:

Load 
Capitalize(TextBetween(OrigColumn, '{','}')) as ProductName_Trimmed;

Load * inline [
OrigColumn
Product: {soft drinks and other beverages}
Product:  {snack food}
Product: {electronics and video games}
];

Risultati

Panoramica

Questo esempio di script contiene quanto segue:

• Un semplice caricamento inline per definire la tabella Purchases.

• L'inserimento di un campo calcolato, OrderSize. Questo campo è una trasformazione del campo amount dal set di dati inline. Il sistema classifica gli acquisti come piccoli o grandi, a seconda che l'importo superi o meno i 2.000 dollari.

• Una clausola where che impedisce di caricare i record quando amount è inferiore a 0,05 dollari.

Script di caricamento

Purchases:

Load
If(amount<2000,'Small Purchase','Large Purchase') as OrderSize,

* inline
[
ID, amount
1,2660.39
2,100.01
3,500.42
4,5023.99
5,0.04
6,2002.39
7,31034.53
8,1643.58
9,3993.65
10,614.34
11,675.93
]
WHERE
amount>1
;

Risultati

Nella tabella sopra, la transazione con un ID di 5 non è stata caricata nella tabella. Questo perché il valore amount è inferiore a 0,05 dollari.

Panoramica

Questo esempio di script contiene quanto segue:

• Un semplice caricamento inline per definire la tabella T2.

• La variabile NullInterpret definita come due virgolette singole. Quando lo script viene caricato, i record contenenti questo valore vengono elaborati come valori nulli.

Script di caricamento

set nullinterpret = '';
T2:
Load * inline [
Test
''
x ];

Risultati

Nella tabella precedente, il primo record è un valore nullo. Pertanto, non è incluso nella visualizzazione. I valori nulli presenti nelle tabelle con dimensioni aggiuntive saranno indicati con un simbolo -.