Chargement de données depuis des tables inline

Vue d'ensemble

Cet exemple montre comment utiliser des backticks pour encadrer des données inline. Les données de l'exemple contiennent des caractères de crochet, ce qui rend les crochets incompatibles comme caractères d'encadrement pour l'instruction LOAD.

Script de chargement

DataTable:

Load * inline 
`
custom_property, date, amount
[11402], 1/1/2024, 92.99
[11403], 1/2/2024, 102.34
[11404], 1/3/2024, 50.26
[11405], 1/4/2024, 153.69
[11406], 1/5/2024, 75.62
`;

Résultats

• custom_property

• date

• amount

Vue d'ensemble

Le remplacement du délimiteur s'avère utile lorsque les données de la table contiennent des virgules, qui, si elles étaient utilisées comme délimiteur, entraîneraient le passage à la colonne suivante de la table.

Cet exemple contient quatre tables à charger. Il s'agit des suivantes :

• Quatre tables à charger. Il s'agit des suivantes :

  • Table1 : le délimiteur est une barre verticale (pipe). Les données de la colonne Phrase contiennent des virgules.

  • Table2 : le délimiteur est le caractère de deux-points.

  • Table3 : le délimiteur est une barre oblique inversée.

  • Table4 : la table est délimitée via une pression sur la touche Tab du clavier. Cette option s'avère utile lorsque vous copiez une table d'un traitement de texte et que vous la collez dans le script.

  Table1 montre un cas d'utilisation pratique d'un délimiteur alternatif. Les autres tables montrent d'autres options de délimiteur.

Script de chargement

Table1:
LOAD * INLINE [
ID|Phrase
1 | 'The transaction was complete, but the order has not yet shipped.'
2 | 'We need to confirm the following details: sales rep number, order status, and shipping priority.'
] (Delimiter is '|');

Table2:
LOAD * INLINE [
Num1:Chr1
1:A
2:B ] (Delimiter is ':');

Table3:
LOAD * INLINE [
Num2\Chr2
1\A
2\B ] (Delimiter is \\);

Table4:
LOAD * INLINE [
Num3	Chr3
1	A
2	B ] (Delimiter is '\t');

Résultats

Vue d'ensemble

Cet exemple montre comment charger une table inline sans définir de noms de colonne.

Script de chargement

Expenses:

Load * inline
[
1,Category1,40566.49
2,Category2,3504.54
3,Category3,593206.30
] (no labels);

Résultats

Vue d'ensemble

Cet exemple de script contient les éléments suivants :

• Une instruction inline load définissant la table DataTable.
• L'utilisation de fix (dans le cadre de la spécification de Table format) pour indiquer que les données à charger se présentent au format d'enregistrement fixe.

Script de chargement

DataTable:
LOAD
"@1:4",
"@5:8",
"@9:12",
"@13:16"
INLINE [
a   b   c   d
1   2   3   4
x   y   z   w
] (fix, utf8, embedded labels);

Résultats

Script de chargement

ORDERS:

Load Original as Updated,
* Inline
[
Original
ProductA
ProductB
ProductC
];

Résultats

Vue d'ensemble

Cet exemple montre comment définir un champ calculé de sorte à indiquer l'ID de chaque ligne de données, sans avoir à saisir manuellement chaque valeur d'ID.

Script de chargement

ORDERS:

Load RowNo() as ID,
* Inline
[
ProductName
A
B
C
D
E
];

Résultats

Vue d'ensemble

Cet exemple montre plusieurs manières d'appliquer une transformation simple à des données inline. Vous pouvez utiliser une ou plusieurs instructions LOAD et configurer la syntaxe de différentes manières afin de définir si une transformation remplace ou non le champ d'origine ou si les deux champs, celui d'origine et le nouveau, sont chargés.

En particulier, notez les variations dans ce qui suit et comment elles affectent la sortie :

• Nombre d'instructions LOAD dans la table.

• Présence ou absence de symbole * (charge tous les champs qui suivent).

• Présence ou absence de virgules (symbole ,).

Cet exemple de script contient les éléments suivants :

• Quatre tables, toutes référençant les mêmes données. Les noms de champ sont différents.

  • DerivedYears1 : utilise deux instructions LOAD pour charger une colonne inline et une colonne contenant une transformation de la colonne inline.

  • DerivedYears2 : utilise deux instructions LOAD. Le script charge une colonne inline, puis un champ calculé transformé à partir de la colonne d'origine. Avec la deuxième instruction LOAD, la colonne d'origine n'est pas chargée dans la table, remplaçant efficacement le champ d'origine par le nouveau champ.

  • DerivedYears3 : utilise une seule instruction LOAD pour charger la colonne inline d'origine et une colonne transformée.

  • DerivedYears4 : utilise une seule instruction LOAD pour définir un champ inline et une transformation de ce champ d'origine. Seul le champ transformé est chargé dans la table.

Script de chargement

DerivedYears1:

Load *,
Year(initial_date1) as derived_year1
;
    
Load
* inline [
initial_date1
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears2:

Load
Year(initial_date2) as derived_year2
;
    
Load
* inline [
initial_date2
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears3:

Load Year(initial_date3) as derived_year3,
* inline [
initial_date3
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears4:

Load Year(initial_date4) as derived_year4
inline [
initial_date4
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

Résultats

Vue d'ensemble

Supposons que vous colliez dans l'éditeur de script des informations provenant d'un fichier texte volumineux, mais que vous souhaitiez effectuer un traitement supplémentaire sur les enregistrements de l'ensemble de données. Par exemple, vous souhaitez supprimer certains caractères et préfixes et capitaliser chaque terme.

Cet exemple de script contient les éléments suivants :

• Une table inline, Transformations, dans laquelle une transformation est définie de sorte à modifier le contenu textuel d'un champ. Le texte transformé est ajouté après cela.

• Deux instructions LOAD. Avec la configuration de l'exemple, seul le champ dérivé ProductName_Trimmed est chargé dans la table.

Script de chargement

Transformations:

Load 
Capitalize(TextBetween(OrigColumn, '{','}')) as ProductName_Trimmed;

Load * inline [
OrigColumn
Product: {soft drinks and other beverages}
Product:  {snack food}
Product: {electronics and video games}
];

Résultats

Vue d'ensemble

Cet exemple de script contient les éléments suivants :

• Un chargement inline simple pour définir la table Purchases.

• L'insertion d'un champ calculé, OrderSize. Ce champ est une transformation du champ amount de l'ensemble de données inline. Il catégorise les achats comme importants ou peu importants suivant que le montant dépasse ou non $2000,00.

• Une clause where qui empêche le chargement des enregistrements lorsque la valeur de amount est inférieure à $0.05.

Script de chargement

Purchases:

Load
If(amount<2000,'Small Purchase','Large Purchase') as OrderSize,

* inline
[
ID, amount
1,2660.39
2,100.01
3,500.42
4,5023.99
5,0.04
6,2002.39
7,31034.53
8,1643.58
9,3993.65
10,614.34
11,675.93
]
WHERE
amount>1
;

Résultats

Dans le tableau ci-dessus, la transaction avec un ID égal à 5 n'a pas été chargée dans la table. Cela est dû au fait que la valeur de amount est inférieure à $0.05.

Vue d'ensemble

Cet exemple de script contient les éléments suivants :

• Un chargement inline simple pour définir la table T2.

• La variable NullInterpret définie sous la forme de deux guillemets simples. Lors du chargement du script, les enregistrements contenant cette valeur sont traités comme des valeurs nulles.

Script de chargement

set nullinterpret = '';
T2:
Load * inline [
Test
''
x ];

Résultats

Dans le tableau ci-dessus, le premier enregistrement est une valeur nulle. Par conséquent, il n'est pas inclus dans la visualisation. Les valeurs nulles existant dans les tables avec des dimensions supplémentaires seraient indiquées par un symbole -.