从内联表加载数据

概述

此示例演示了如何使用反勾号将内联数据包封起来。示例中的数据包含方括号字符，这使得方括号与 LOAD 语句的包封符不兼容。

加载脚本

DataTable:

Load * inline 
`
custom_property, date, amount
[11402], 1/1/2024, 92.99
[11403], 1/2/2024, 102.34
[11404], 1/3/2024, 50.26
[11405], 1/4/2024, 153.69
[11406], 1/5/2024, 75.62
`;

结果

• custom_property

• date

• amount

概述

当表中的数据包含逗号时，交换分隔符非常有用，否则会发出切换到表中下一列的信号。

此示例包含四个要加载的表。它们如下所示：

• 要加载四个表。它们如下所示：

  • Table1：分隔符是垂直条（管道）。Phrase 列中的数据包含逗号。

  • Table2：分隔符是冒号。

  • Table3：分隔符是反斜杠。

  • Table4：通过按键盘上的 Tab 键来分隔表格。当您从文字处理程序复制表并将其粘贴到脚本中时，此选项非常有用。

  Table1 显示了使用替代分隔符的实际用例。其他表格显示了更多分隔符选项。

加载脚本

Table1:
LOAD * INLINE [
ID|Phrase
1 | 'The transaction was complete, but the order has not yet shipped.'
2 | 'We need to confirm the following details: sales rep number, order status, and shipping priority.'
] (Delimiter is '|');

Table2:
LOAD * INLINE [
Num1:Chr1
1:A
2:B ] (Delimiter is ':');

Table3:
LOAD * INLINE [
Num2\Chr2
1\A
2\B ] (Delimiter is \\);

Table4:
LOAD * INLINE [
Num3	Chr3
1	A
2	B ] (Delimiter is '\t');

结果

概述

此示例演示了如何在不定义列名的情况下加载内联表。

加载脚本

Expenses:

Load * inline
[
1,Category1,40566.49
2,Category2,3504.54
3,Category3,593206.30
] (no labels);

结果

概述

此示例脚本包含以下内容：

• 定义表 DataTable 的内联 LOAD 语句。
• 使用 fix（作为 Table format 规范的一部分）来指示要加载的数据是固定记录格式。

加载脚本

DataTable:
LOAD
"@1:4",
"@5:8",
"@9:12",
"@13:16"
INLINE [
a   b   c   d
1   2   3   4
x   y   z   w
] (fix, utf8, embedded labels);

结果

加载脚本

ORDERS:

Load Original as Updated,
* Inline
[
Original
ProductA
ProductB
ProductC
];

结果

概述

此示例显示如何定义计算字段以指示每个数据行的 ID，而无需手动键入每个 ID 值。

加载脚本

ORDERS:

Load RowNo() as ID,
* Inline
[
ProductName
A
B
C
D
E
];

结果

概述

此示例显示了将简单转换应用于内联数据的几种方法。您可以使用一个或多个 LOAD 语句，并以不同的方式配置语法，以定义转换是否替换原始字段，或者是否同时加载原始字段和新字段。

特别要注意以下内容的变化及其对输出的影响：

• 表中的 LOAD 语句数。

• 是否存在 * 符号（加载所有后续字段）。

• 是否存在逗号（, 符号）。

此示例脚本包含以下内容：

• 四个表，所有这些表都引用了相同的数据。字段名称不同。

  • DerivedYears1：使用两个 LOAD 语句加载内联列和包含内联列转换的列。

  • DerivedYears2：使用两个 LOAD 语句。脚本加载一个内联列，然后加载从原始列转换而来的已计算字段。对于第二个 LOAD 语句，原始列不会加载到表中，从而有效地使新字段替换了原始字段。

  • DerivedYears3：使用单个 LOAD 语句同时加载原始内联列和转换后的列。

  • DerivedYears4：使用单个 LOAD 语句定义内联字段和原始字段的转换。只有转换后的字段才会加载到表中。

加载脚本

DerivedYears1:

Load *,
Year(initial_date1) as derived_year1
;
    
Load
* inline [
initial_date1
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears2:

Load
Year(initial_date2) as derived_year2
;
    
Load
* inline [
initial_date2
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears3:

Load Year(initial_date3) as derived_year3,
* inline [
initial_date3
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears4:

Load Year(initial_date4) as derived_year4
inline [
initial_date4
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

结果

概述

假设您将信息从一个大型文本文件粘贴到脚本编辑器中，但希望对数据集中的记录执行额外处理。例如，您希望删除某些字符和前缀，并将每个单词大写。

此示例脚本包含以下内容：

• 内联表，Transformations，其中定义了一个转换来更改字段的文本内容。正在转换的文本将添加在此之后。

• 两个 LOAD 语句。对于示例中的配置，只有派生字段 ProductName_Trimmed 被加载到表中。

加载脚本

Transformations:

Load 
Capitalize(TextBetween(OrigColumn, '{','}')) as ProductName_Trimmed;

Load * inline [
OrigColumn
Product: {soft drinks and other beverages}
Product:  {snack food}
Product: {electronics and video games}
];

结果

概述

此示例脚本包含以下内容：

• 定义表 Purchases 的简单内联加载。

• 插入计算字段 OrderSize。此字段是内联数据集中 amount 字段的转换。根据金额是否超过 2000.00 美元，它将购买分为小额或大额。

• 当 amount 小于 $0.05 时，阻止加载记录的 where 子句。

加载脚本

Purchases:

Load
If(amount<2000,'Small Purchase','Large Purchase') as OrderSize,

* inline
[
ID, amount
1,2660.39
2,100.01
3,500.42
4,5023.99
5,0.04
6,2002.39
7,31034.53
8,1643.58
9,3993.65
10,614.34
11,675.93
]
WHERE
amount>1
;

结果

在上表中，5 为 ID 的事务未加载到表中。这是因为 amount 值低于 0.05 美元。

概述

此示例脚本包含以下内容：

• 定义表 T2 的简单内联加载。

• 定义为两个单引号的 NullInterpret 变量。加载脚本时，包含此值的记录将作为空值进行处理。

加载脚本

set nullinterpret = '';
T2:
Load * inline [
Test
''
x ];

结果

在上表中，第一条记录为空值。因此，它不会包括在可视化中。具有附加维度的表中存在的空值将用 - 符号表示。