Carregando dados de tabelas inline

Visão geral

Este exemplo demonstra como você pode usar crases para delimitar os dados inline. Os dados no exemplo contêm caracteres de colchetes, o que torna os colchetes incompatíveis como delimitadores da instrução de LOAD.

Script de carregamento

DataTable:

Load * inline 
`
custom_property, date, amount
[11402], 1/1/2024, 92.99
[11403], 1/2/2024, 102.34
[11404], 1/3/2024, 50.26
[11405], 1/4/2024, 153.69
[11406], 1/5/2024, 75.62
`;

Resultados

• custom_property

• date

• amount

Visão geral

A troca do delimitador é útil quando os dados da tabela contêm vírgulas, o que de outra forma sinalizaria a mudança para a próxima coluna da tabela.

Este exemplo contém quatro tabelas a serem carregadas. Eles são os seguintes:

• Quatro tabelas a serem carregadas. Eles são os seguintes:

  • Table1: o delimitador é uma barra vertical (barra). Os dados na coluna Phrase contêm vírgulas.

  • Table2: o delimitador é um sinal de dois pontos.

  • Table3: o delimitador é uma barra invertida.

  • Table4: a tabela é delimitada pressionando a tecla Tab do teclado. Esta opção é útil quando você copia uma tabela de um processador de texto e a cola no script.

  Table1 mostra um caso de uso prático para usar um delimitador alternativo. As outras tabelas mostram mais opções de delimitadores.

Script de carregamento

Table1:
LOAD * INLINE [
ID|Phrase
1 | 'The transaction was complete, but the order has not yet shipped.'
2 | 'We need to confirm the following details: sales rep number, order status, and shipping priority.'
] (Delimiter is '|');

Table2:
LOAD * INLINE [
Num1:Chr1
1:A
2:B ] (Delimiter is ':');

Table3:
LOAD * INLINE [
Num2\Chr2
1\A
2\B ] (Delimiter is \\);

Table4:
LOAD * INLINE [
Num3	Chr3
1	A
2	B ] (Delimiter is '\t');

Resultados

Visão geral

Este exemplo demonstra como você pode carregar uma tabela inline sem definir nomes de colunas.

Script de carregamento

Expenses:

Load * inline
[
1,Category1,40566.49
2,Category2,3504.54
3,Category3,593206.30
] (no labels);

Resultados

Visão geral

Este script de exemplo contém o seguinte:

• Uma instrução de LOAD inline que define a tabela DataTable.
• O uso de fix (como parte da especificação Table format) para indicar que os dados a serem carregados estão em formato de registro fixo.

Script de carregamento

DataTable:
LOAD
"@1:4",
"@5:8",
"@9:12",
"@13:16"
INLINE [
a   b   c   d
1   2   3   4
x   y   z   w
] (fix, utf8, embedded labels);

Resultados

Script de carregamento

ORDERS:

Load Original as Updated,
* Inline
[
Original
ProductA
ProductB
ProductC
];

Resultados

Visão geral

Este exemplo mostra como você pode definir um campo calculado para indicar o ID de cada linha de dados, sem digitar manualmente cada valor de ID.

Script de carregamento

ORDERS:

Load RowNo() as ID,
* Inline
[
ProductName
A
B
C
D
E
];

Resultados

Visão geral

Este exemplo mostra diversas maneiras pelas quais uma transformação simples pode ser aplicada a dados inline. Você pode usar uma ou várias instruções de LOAD e configurar a sintaxe de maneiras diferentes para definir se uma transformação substitui ou não o campo original ou se os campos original e novo serão carregados.

Em particular, observe as variações a seguir e como elas afetam a saída:

• Número de instruções de LOAD dentro da tabela.

• Presença ou ausência de símbolo * (carrega todos os campos subsequentes).

• Presença ou ausência de vírgulas (símbolo ,).

Este script de exemplo contém o seguinte:

• Quatro tabelas, todas referenciando os mesmos dados. Os nomes dos campos são diferentes.

  • DerivedYears1: usa duas instruções de LOAD para carregar uma coluna inline e uma coluna contendo uma transformação da coluna inline.

  • DerivedYears2: usa duas instruções de LOAD. O script carrega uma coluna inline e, em seguida, carrega um campo calculado transformado da coluna original. Com a segunda instrução de LOAD, a coluna original não é carregada na tabela, tornando efetivamente o novo campo uma substituição do campo original.

  • DerivedYears3: usa uma única instrução de LOAD para carregar a coluna inline original e uma coluna transformada.

  • DerivedYears4: usa uma única instrução de LOAD para definir um campo inline e uma transformação desse campo original. Somente o campo transformado é carregado na tabela.

Script de carregamento

DerivedYears1:

Load *,
Year(initial_date1) as derived_year1
;
    
Load
* inline [
initial_date1
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears2:

Load
Year(initial_date2) as derived_year2
;
    
Load
* inline [
initial_date2
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears3:

Load Year(initial_date3) as derived_year3,
* inline [
initial_date3
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears4:

Load Year(initial_date4) as derived_year4
inline [
initial_date4
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

Resultados

Visão geral

Suponha que você esteja colando informações de um arquivo de texto grande no editor de script, mas queira realizar processamento adicional nos registros do conjunto de dados. Por exemplo, você deseja remover certos caracteres e prefixos e colocar cada palavra em maiúscula.

Este script de exemplo contém o seguinte:

• Uma tabela inline, Transformations, na qual uma transformação é definida para alterar o conteúdo de texto de um campo. O texto que está sendo transformado é adicionado depois disso.

• Duas instruções de LOAD. Com a configuração do exemplo, apenas o campo derivado ProductName_Trimmed é carregado na tabela.

Script de carregamento

Transformations:

Load 
Capitalize(TextBetween(OrigColumn, '{','}')) as ProductName_Trimmed;

Load * inline [
OrigColumn
Product: {soft drinks and other beverages}
Product:  {snack food}
Product: {electronics and video games}
];

Resultados

Visão geral

Este script de exemplo contém o seguinte:

• Um carregamento embutido simples para definir a tabela Purchases.

• A inserção de um campo calculado, OrderSize. Este campo é uma transformação do campo amount do conjunto de dados inline. Ele categoriza as compras como pequenas ou grandes, dependendo se o valor ultrapassa ou não US$ 2.000,00.

• Uma cláusula where que impede que os registros sejam carregados quando amount for inferior a US$ 0,05.

Script de carregamento

Purchases:

Load
If(amount<2000,'Small Purchase','Large Purchase') as OrderSize,

* inline
[
ID, amount
1,2660.39
2,100.01
3,500.42
4,5023.99
5,0.04
6,2002.39
7,31034.53
8,1643.58
9,3993.65
10,614.34
11,675.93
]
WHERE
amount>1
;

Resultados

Na tabela acima, a transação com um ID de 5 não foi carregada na tabela. Isso ocorre porque o valor amount é inferior a US$ 0,05.

Visão geral

Este script de exemplo contém o seguinte:

• Um carregamento embutido simples para definir a tabela T2.

• A variável NullInterpret definida como duas aspas simples. Quando o script é carregado, os registros que contêm esse valor são processados como valores nulos.

Script de carregamento

set nullinterpret = '';
T2:
Load * inline [
Test
''
x ];

Resultados

Na tabela acima, o primeiro registro é um valor nulo. Portanto, não está incluído na visualização. Valores nulos existentes em tabelas com dimensões adicionais seriam indicados com um símbolo -.