Загрузка данных из встроенных таблиц

Обзор

Этот пример демонстрирует, как можно заключить встроенные данные в обратные кавычки. Данные в примере содержат квадратные скобки, и поэтому в эти символы нельзя заключить данные в операторе LOAD.

Скрипт загрузки

DataTable:

Load * inline 
`
custom_property, date, amount
[11402], 1/1/2024, 92.99
[11403], 1/2/2024, 102.34
[11404], 1/3/2024, 50.26
[11405], 1/4/2024, 153.69
[11406], 1/5/2024, 75.62
`;

Результаты

• custom_property

• date

• amount

Обзор

Замена разделителя полезна, когда данные в таблице содержат запятые, которые в противном случае указывают на переход к следующему столбцу в таблице.

Этот пример содержит четыре таблицы для загрузки, а именно:

• Четыре таблицы для загрузки. а именно:

  • Table1: разделитель ― вертикальная черта (|). Данные в столбце Phrase содержат запятые.

  • Table2: разделитель ― двоеточие.

  • Table3: разделитель ― обратная косая черта.

  • Table4: для разделения столбцов таблицы нажимается клавиша Tab. Этот вариант полезен, когда таблица копируется из текстового редактора и вставляется в скрипт.

  Table1 демонстрирует пример практического использования альтернативного разделителя. В других таблицах показаны другие варианты разделителей.

Скрипт загрузки

Table1:
LOAD * INLINE [
ID|Phrase
1 | 'The transaction was complete, but the order has not yet shipped.'
2 | 'We need to confirm the following details: sales rep number, order status, and shipping priority.'
] (Delimiter is '|');

Table2:
LOAD * INLINE [
Num1:Chr1
1:A
2:B ] (Delimiter is ':');

Table3:
LOAD * INLINE [
Num2\Chr2
1\A
2\B ] (Delimiter is \\);

Table4:
LOAD * INLINE [
Num3	Chr3
1	A
2	B ] (Delimiter is '\t');

Результаты

Обзор

Этот пример демонстрирует загрузку встроенной таблицы без определения имен столбцов.

Скрипт загрузки

Expenses:

Load * inline
[
1,Category1,40566.49
2,Category2,3504.54
3,Category3,593206.30
] (no labels);

Результаты

Обзор

Этот пример скрипта содержит следующее:

• Оператор встроенной загрузки, определяющий таблицу DataTable.
• Использование fix (в составе спецификации Table format) указывает, что данные загружаются в формате фиксированных записей.

Скрипт загрузки

DataTable:
LOAD
"@1:4",
"@5:8",
"@9:12",
"@13:16"
INLINE [
a   b   c   d
1   2   3   4
x   y   z   w
] (fix, utf8, embedded labels);

Результаты

Скрипт загрузки

ORDERS:

Load Original as Updated,
* Inline
[
Original
ProductA
ProductB
ProductC
];

Результаты

Обзор

Этот пример показывает, как можно определить вычисляемое поле, чтобы указать идентификатор каждой строки данных, не вводя значения всех идентификаторов вручную.

Скрипт загрузки

ORDERS:

Load RowNo() as ID,
* Inline
[
ProductName
A
B
C
D
E
];

Результаты

Обзор

Этот пример показывает несколько способов, применения простого преобразования к встроенным данным. Можно использовать один или несколько операторов LOAD, и по-разному настраивать синтаксис, чтобы определить, заменяет ли преобразование исходное поле или загружаются ли оба поля: исходное и новое.

В частности, обратите внимание на вариации, приведенные ниже, и как они влияют на результат:

• Количество операторов LOAD в таблице.

• Присутствие или отсутствие символа * (загружает все последующие поля).

• Наличие или отсутствие запятых (символ ,).

Этот пример скрипта содержит следующее:

• Четыре таблицы, каждая из которых ссылается на одни и те же данные. Имена полей не совпадают.

  • DerivedYears1: используются два оператора LOAD, чтобы загрузить встроенный столбец и столбец, содержащий преобразование встроенного столбца.

  • DerivedYears2: используются два оператора LOAD. Скрипт загружает встроенный столбец, затем загружает вычисляемое поле, созданное на основе преобразования исходного поля. Благодаря использованию второго оператора LOAD исходный столбец не загружается в таблицу, вследствие чего исходное поле заменяется новым.

  • DerivedYears3: используется один оператор LOAD для загрузки как исходного встроенного столбца, так и преобразованного столбца.

  • DerivedYears4: используется один оператор LOAD, чтобы определить встроенное поле и преобразование этого исходного поля. В таблицу загружается только преобразованное поле.

Скрипт загрузки

DerivedYears1:

Load *,
Year(initial_date1) as derived_year1
;
    
Load
* inline [
initial_date1
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears2:

Load
Year(initial_date2) as derived_year2
;
    
Load
* inline [
initial_date2
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears3:

Load Year(initial_date3) as derived_year3,
* inline [
initial_date3
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears4:

Load Year(initial_date4) as derived_year4
inline [
initial_date4
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

Результаты

Обзор

Предположим, что вставляется информация из большого текстового файла в редактор скриптов, но требуется выполнить дополнительную обработку записей в наборе данных. Например, требуется удалить определенные символы и префиксы, а также сделать первую букву каждого слова заглавной.

Этот пример скрипта содержит следующее:

• Встроенная таблица, Transformations, в которой определено преобразование для изменения текстового содержимого поля. После этого добавляется преобразуемый текст.

• Два оператора LOAD. При такой конфигурации, как в примере, в таблицу загружается только производное поле ProductName_Trimmed.

Скрипт загрузки

Transformations:

Load 
Capitalize(TextBetween(OrigColumn, '{','}')) as ProductName_Trimmed;

Load * inline [
OrigColumn
Product: {soft drinks and other beverages}
Product:  {snack food}
Product: {electronics and video games}
];

Результаты

Обзор

Этот пример скрипта содержит следующее:

• Простая встроенная загрузка для определения таблицы Purchases.

• Вставка вычисляемого поля OrderSize. Это поле является преобразованием поля amount из встроенного набора данных. Выполняется категоризация покупок как мелких или крупных в зависимости от того, превышает ли сумма $2000,00.

• Предложение where, которое запрещает загрузку записей, когда значение amount меньше $0,05.

Скрипт загрузки

Purchases:

Load
If(amount<2000,'Small Purchase','Large Purchase') as OrderSize,

* inline
[
ID, amount
1,2660.39
2,100.01
3,500.42
4,5023.99
5,0.04
6,2002.39
7,31034.53
8,1643.58
9,3993.65
10,614.34
11,675.93
]
WHERE
amount>1
;

Результаты

В приведенную выше таблицу не загружена транзакция с ID=5. Это объясняется тем, что значение amount меньше $0,05.

Обзор

Этот пример скрипта содержит следующее:

• Простая встроенная загрузка для определения таблицы T2.

• Переменная NullInterpret, определенная как две одиночные кавычки. Когда загружается скрипт, записи, содержащие это значение, обрабатываются как нули.

Скрипт загрузки

set nullinterpret = '';
T2:
Load * inline [
Test
''
x ];

Результаты

В приведенной выше таблице первая запись содержит нулевое значение. Поэтому она не включена в визуализацию. Нулевые значения, имеющиеся в таблице с дополнительными измерениями, будут обозначаться символом -.