Ladda data från inline-tabeller

Översikt

Det här exemplet demonstrerar hur du kan använda backticks för att omsluta inline-data. Data i exemplet innehåller hakparentestecken som gör hakparenteser inkompatibla som omslutningstecken för LOAD-satsen.

Laddningsskript

DataTable:

Load * inline 
`
custom_property, date, amount
[11402], 1/1/2024, 92.99
[11403], 1/2/2024, 102.34
[11404], 1/3/2024, 50.26
[11405], 1/4/2024, 153.69
[11406], 1/5/2024, 75.62
`;

Resultat

• custom_property

• date

• amount

Översikt

Att byta ut avgränsaren är användbart när data i tabellen innehåller kommatecken, vilket annars skulle signalera att man byter till nästa kolumn i tabellen.

Detta exempel innehåller fyra tabeller som ska laddas. De är som följer:

• Fyra tabeller ska laddas. De är som följer:

  • Table1: avgränsaren är ett vertikalt streck (pipe). Data i Phrase-kolumnen innehåller komman.

  • Table2: avgränsaren är ett kolon.

  • Table3: avgränsaren är ett backstreck.

  • Table4: tabellen avgränsas genom att trycka på tabbtangenten på tangentbordet. Det här alternativet är användbart när du kopierar en tabell från en ordbehandlare och klistrar in den i skriptet.

  Table1 visar ett praktiskt användningsfall för att använda en alternativ avgränsare. I de andra tabellerna visas fler alternativ för avgränsare.

Laddningsskript

Table1:
LOAD * INLINE [
ID|Phrase
1 | 'The transaction was complete, but the order has not yet shipped.'
2 | 'We need to confirm the following details: sales rep number, order status, and shipping priority.'
] (Delimiter is '|');

Table2:
LOAD * INLINE [
Num1:Chr1
1:A
2:B ] (Delimiter is ':');

Table3:
LOAD * INLINE [
Num2\Chr2
1\A
2\B ] (Delimiter is \\);

Table4:
LOAD * INLINE [
Num3	Chr3
1	A
2	B ] (Delimiter is '\t');

Resultat

Översikt

Det här exemplet visar hur du kan ladda en inline-tabell utan att definiera kolumnnamn.

Laddningsskript

Expenses:

Load * inline
[
1,Category1,40566.49
2,Category2,3504.54
3,Category3,593206.30
] (no labels);

Resultat

Översikt

Det här exempelskriptet innehåller följande:

• En inline-load-sats som definierar tabellen DataTable.
• fix används (som en del av Table format-specifikationen) för att ange att data som ska laddas är i fast postformat.

Laddningsskript

DataTable:
LOAD
"@1:4",
"@5:8",
"@9:12",
"@13:16"
INLINE [
a   b   c   d
1   2   3   4
x   y   z   w
] (fix, utf8, embedded labels);

Resultat

Laddningsskript

ORDERS:

Load Original as Updated,
* Inline
[
Original
ProductA
ProductB
ProductC
];

Resultat

Översikt

I det här exemplet visas hur du kan definiera ett beräknat fält för att ange ID för varje datarad utan att manuellt skriva in varje ID-värde.

Laddningsskript

ORDERS:

Load RowNo() as ID,
* Inline
[
ProductName
A
B
C
D
E
];

Resultat

Översikt

Det här exemplet visar flera olika sätt att tillämpa en enkel omvandling på inline-data. Du kan använda en eller flera LOAD-satser och konfigurera syntaxen på olika sätt för att definiera om en transformation ersätter det ursprungliga fältet eller om både ursprungliga och nya fält laddas.

Lägg framför allt märke till variationerna i det följande och hur de påverkar utdata:

• Antalet LOAD-satser i tabellen.

• Om *-symbolen förekommer eller ej (laddar alla efterföljande fält).

• Om komman (,-symbolen) förekommer eller ej.

Det här exempelskriptet innehåller följande:

• Fyra tabeller som alla refererar till samma data. Fältnamnen skiljer sig åt.

  • DerivedYears1: använder två LOAD-satser för att ladda en inline-kolumn och en kolumn som innehåller en omvandling av inline-kolumnen.

  • DerivedYears2: använder två LOAD-satser. Skriptet laddar en inline-kolumn och laddar därefter ett beräknat fält som omvandlats från den ursprungliga kolumnen. Genom den andra LOAD-satsen laddas inte den ursprungliga kolumnen i tabellen, vilket gör att det nya fältet i praktiken ersätter det ursprungliga fältet.

  • DerivedYears3: använder en enda LOAD-sats för att ladda både den ursprungliga inline-kolumnen och en omvandlad kolumn.

  • DerivedYears4: använder en enda LOAD-sats för att definiera ett inline-fält och en omvandling av det ursprungliga fältet. Det är bara det omvandlade fältet som laddas i tabellen.

Laddningsskript

DerivedYears1:

Load *,
Year(initial_date1) as derived_year1
;
    
Load
* inline [
initial_date1
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears2:

Load
Year(initial_date2) as derived_year2
;
    
Load
* inline [
initial_date2
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears3:

Load Year(initial_date3) as derived_year3,
* inline [
initial_date3
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears4:

Load Year(initial_date4) as derived_year4
inline [
initial_date4
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

Resultat

Översikt

Anta att du klistrar in information från en stor textfil i skriptredigeraren, men vill utföra ytterligare bearbetning av posterna i datauppsättningen. Du vill exempelvis ta bort vissa tecken och prefix och skriva varje ord med stor bokstav.

Det här exempelskriptet innehåller följande:

• En inline-tabell, Transformations, i vilken en transformation definieras för att ändra textinnehållet i ett fält. Texten som omvandlas läggs till efter detta.

• Två LOAD-satser. Med konfigurationen i exemplet laddas bara det härledda fältet ProductName_Trimmed i tabellen.

Laddningsskript

Transformations:

Load 
Capitalize(TextBetween(OrigColumn, '{','}')) as ProductName_Trimmed;

Load * inline [
OrigColumn
Product: {soft drinks and other beverages}
Product:  {snack food}
Product: {electronics and video games}
];

Resultat

Översikt

Det här exempelskriptet innehåller följande:

• En enkel inline-laddning som definierar tabellen Purchases.

• Att infoga ett beräknat fält, OrderSize. Det här fältet är en omvandling av amount-fältet från inline-datauppsättningen. Den kategoriserar inköp som små eller stora, beroende på om beloppet överstiger 2000,00 USD eller inte.

• En where-sats som förhindrar poster från att laddas när amount är mindre än 0,05 USD.

Laddningsskript

Purchases:

Load
If(amount<2000,'Small Purchase','Large Purchase') as OrderSize,

* inline
[
ID, amount
1,2660.39
2,100.01
3,500.42
4,5023.99
5,0.04
6,2002.39
7,31034.53
8,1643.58
9,3993.65
10,614.34
11,675.93
]
WHERE
amount>1
;

Resultat

I tabellen ovan laddades inte transaktionen med en ID på 5 i tabellen. Det beror på att värdet för amount är mindre än 0,05 USD.

Översikt

Det här exempelskriptet innehåller följande:

• En enkel inline-laddning som definierar tabellen T2.

• NullInterpret-variabeln definierad som två enkla citattecken. När skriptet laddas bearbetas poster som innehåller detta värde som null-värden.

Laddningsskript

set nullinterpret = '';
T2:
Load * inline [
Test
''
x ];

Resultat

I tabellen ovan är den första posten ett null-värde. Därför inkluderas den inte i visualiseringen. Null-värden som finns i tabeller med ytterligare dimensioner anges med en --symbol.