Cargar datos de tablas inline

General

Este ejemplo muestra cómo puede utilizar tildes invertidas para incluir los datos inline. Los datos del ejemplo contienen caracteres entre corchetes, lo que hace que los corchetes sean incompatibles como caracteres de inclusión para la sentencia LOAD.

Script de carga

DataTable:

Load * inline 
`
custom_property, date, amount
[11402], 1/1/2024, 92.99
[11403], 1/2/2024, 102.34
[11404], 1/3/2024, 50.26
[11405], 1/4/2024, 153.69
[11406], 1/5/2024, 75.62
`;

Resultados

• custom_property

• date

• amount

General

Intercambiar el delimitador es útil cuando los datos de la tabla contienen comas, lo que de otro modo indicaría el cambio a la siguiente columna de la tabla.

Este ejemplo contiene cuatro tablas para cargar. Son las siguientes:

• Cuatro tablas que cargar. Son las siguientes:

  • Table1: el delimitador es una barra vertical (canalización). Los datos de la columna Phrase contienen comas.

  • Table2: el delimitador son dos puntos.

  • Table3: el delimitador es una barra invertida.

  • Table4: la tabla se delimita pulsando la tecla Tab del teclado. Esta opción es útil cuando copia una tabla de un procesador de textos y la pega en el script.

  Table1 muestra un caso de uso práctico para utilizar un delimitador alternativo. Las otras tablas muestran más opciones de delimitadores.

Script de carga

Table1:
LOAD * INLINE [
ID|Phrase
1 | 'The transaction was complete, but the order has not yet shipped.'
2 | 'We need to confirm the following details: sales rep number, order status, and shipping priority.'
] (Delimiter is '|');

Table2:
LOAD * INLINE [
Num1:Chr1
1:A
2:B ] (Delimiter is ':');

Table3:
LOAD * INLINE [
Num2\Chr2
1\A
2\B ] (Delimiter is \\);

Table4:
LOAD * INLINE [
Num3	Chr3
1	A
2	B ] (Delimiter is '\t');

Resultados

General

Este ejemplo muestra cómo se puede cargar una tabla inline sin definir nombres de columnas.

Script de carga

Expenses:

Load * inline
[
1,Category1,40566.49
2,Category2,3504.54
3,Category3,593206.30
] (no labels);

Resultados

General

Este script de ejemplo contiene lo siguiente:

• Una sentencia de carga inline que define la tabla DataTable.
• El uso de fix(como parte de la especificación de Table format) para indicar que los datos a cargar están en formato de registro fijo.

Script de carga

DataTable:
LOAD
"@1:4",
"@5:8",
"@9:12",
"@13:16"
INLINE [
a   b   c   d
1   2   3   4
x   y   z   w
] (fix, utf8, embedded labels);

Resultados

Script de carga

ORDERS:

Load Original as Updated,
* Inline
[
Original
ProductA
ProductB
ProductC
];

Resultados

General

Este ejemplo muestra cómo puede definir un campo calculado para indicar el ID de cada fila de datos, sin escribir manualmente cada valor de ID.

Script de carga

ORDERS:

Load RowNo() as ID,
* Inline
[
ProductName
A
B
C
D
E
];

Resultados

General

Este ejemplo muestra varias formas en las que se puede aplicar una transformación simple a datos inline. Puede utilizar una o varias sentencias LOAD y configurar la sintaxis de diferentes maneras, para definir si una transformación reemplaza o no al campo original o si se cargan tanto el campo original como el nuevo.

En particular, tenga en cuenta las variaciones en lo siguiente y cómo afectan al resultado:

• Número de sentencias LOAD en la tabla.

• Presencia o ausencia del símbolo * (carga todos los campos posteriores).

• Presencia o ausencia de comas (símbolo ,).

Este script a modo de ejemplo contiene lo siguiente:

• Cuatro tablas, todas las cuales hacen referencia a los mismos datos. Los nombres de los campos son diferentes.

  • DerivedYears1: utiliza dos sentencias LOAD para cargar una columna inline y una columna que contiene una transformación de la columna inline.

  • DerivedYears2: utiliza dos sentencias LOAD. El script carga una columna inline y luego carga un campo calculado transformado a partir de la columna original. Con la segunda sentencia LOAD, la columna original no se carga en la tabla, lo que efectivamente hace que el nuevo campo reemplace al campo original.

  • DerivedYears3: utiliza una sencilla sentencia LOAD para cargar tanto la columna inline original como una columna transformada.

  • DerivedYears4: utiliza una sencilla sentencia LOAD para definir un campo en línea y una transformación de ese campo original. Sólo el campo transformado se carga en la tabla.

Script de carga

DerivedYears1:

Load *,
Year(initial_date1) as derived_year1
;
    
Load
* inline [
initial_date1
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears2:

Load
Year(initial_date2) as derived_year2
;
    
Load
* inline [
initial_date2
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears3:

Load Year(initial_date3) as derived_year3,
* inline [
initial_date3
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears4:

Load Year(initial_date4) as derived_year4
inline [
initial_date4
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

Resultados

General

Supongamos que está pegando información de un archivo de texto grande en el editor de script, pero desea realizar un procesamiento adicional en los registros del conjunto de datos. Por ejemplo, desea eliminar ciertos caracteres y prefijos y poner en mayúscula cada palabra.

Este script a modo de ejemplo contiene lo siguiente:

• Una tabla inline, Transformations, en la que se define una transformación para cambiar el contenido del texto de un campo. El texto que se está transformando se agrega después de esto.

• Dos sentencias LOAD. Con la configuración del ejemplo, solo se carga en la tabla el campo derivado ProductName_Trimmed.

Script de carga

Transformations:

Load 
Capitalize(TextBetween(OrigColumn, '{','}')) as ProductName_Trimmed;

Load * inline [
OrigColumn
Product: {soft drinks and other beverages}
Product:  {snack food}
Product: {electronics and video games}
];

Resultados

General

Este script a modo de ejemplo contiene lo siguiente:

• Una carga inline simple para definir la tabla Purchases.

• La inserción de un campo calculado, OrderSize. Este campo es una transformación del campo amount del conjunto de datos inline. Clasifica las compras en pequeñas o grandes, dependiendo de si la cantidad supera o no los 2.000,00 $.

• Una cláusula where que impide que se carguen registros cuando el valor amount es inferior a 0,05 $.

Script de carga

Purchases:

Load
If(amount<2000,'Small Purchase','Large Purchase') as OrderSize,

* inline
[
ID, amount
1,2660.39
2,100.01
3,500.42
4,5023.99
5,0.04
6,2002.39
7,31034.53
8,1643.58
9,3993.65
10,614.34
11,675.93
]
WHERE
amount>1
;

Resultados

En la tabla anterior, la transacción con un ID de 5 no se cargó en la tabla. Esto se debe a que el valor amount es inferior a 0,05 $.

General

Este script de ejemplo contiene lo siguiente:

• Una carga inline simple para definir la tabla T2.

• La variable NullInterpret definida como dos comillas simples. Cuando se carga el script, los registros que contienen este valor se procesan como valores nulos.

Script de carga

set nullinterpret = '';
T2:
Load * inline [
Test
''
x ];

Resultados

En la tabla anterior, el primer registro es un valor nulo. Por tanto, no se incluye en la visualización. Los valores nulos existentes en tablas con dimensiones adicionales se indicarán con un símbolo -.