從內嵌表格載入資料

概述

此範例呈現您可以如何使用反引號括起內嵌資料。範例中的資料包含方括弧字元，這讓方括弧與 LOAD 陳述式的圍繞符號相容。

載入指令嗎

DataTable:

Load * inline 
`
custom_property, date, amount
[11402], 1/1/2024, 92.99
[11403], 1/2/2024, 102.34
[11404], 1/3/2024, 50.26
[11405], 1/4/2024, 153.69
[11406], 1/5/2024, 75.62
`;

結果

• custom_property

• date

• amount

概述

若表格中的資料包含逗號，則交換分隔符號很實用，這會以其他方式告知切換至表格中的下一欄。

此範例包含要載入的四個表格。如下所示：

• 要載入的四個表格。如下所示：

  • Table1：分隔符號是垂直線 (|)。Phrase 欄中的資料包含逗號。

  • Table2：分隔符號是冒號。

  • Table3：分隔符號是反斜線。

  • Table4：表格的分隔方式是按下鍵盤上的 Tab 鍵。若您從文書處理器複製表格並在指令碼中貼上，則此選項很實用。

  Table1 顯示使用替代分隔符號的實際使用案例。其他表格顯示更多分隔符號選項。

載入指令嗎

Table1:
LOAD * INLINE [
ID|Phrase
1 | 'The transaction was complete, but the order has not yet shipped.'
2 | 'We need to confirm the following details: sales rep number, order status, and shipping priority.'
] (Delimiter is '|');

Table2:
LOAD * INLINE [
Num1:Chr1
1:A
2:B ] (Delimiter is ':');

Table3:
LOAD * INLINE [
Num2\Chr2
1\A
2\B ] (Delimiter is \\);

Table4:
LOAD * INLINE [
Num3	Chr3
1	A
2	B ] (Delimiter is '\t');

結果

概述

範例呈現您可以如何載入內嵌表格，而沒有定義欄名稱。

載入指令嗎

Expenses:

Load * inline
[
1,Category1,40566.49
2,Category2,3504.54
3,Category3,593206.30
] (no labels);

結果

概述

此範例指令碼包含下列內容：

• 定義表格 DataTable 的內嵌 LOAD 陳述式。
• 使用 fix (作為部分 Table format 規格) 指示要載入的資料採用固定記錄格式。

載入指令嗎

DataTable:
LOAD
"@1:4",
"@5:8",
"@9:12",
"@13:16"
INLINE [
a   b   c   d
1   2   3   4
x   y   z   w
] (fix, utf8, embedded labels);

結果

載入指令嗎

ORDERS:

Load Original as Updated,
* Inline
[
Original
ProductA
ProductB
ProductC
];

結果

概述

此範例顯示您可以如何定義計算欄位，以指示每個資料列的 ID，而不必手動輸入每個 ID 值。

載入指令嗎

ORDERS:

Load RowNo() as ID,
* Inline
[
ProductName
A
B
C
D
E
];

結果

概述

此範例顯示幾種將簡單轉換套用至內嵌資料的方式。您可以使用一個或多個 LOAD 陳述式，並以不同方式設定語法，以定義轉換是否取代原始欄位，或是原始和新欄位都會載入。

尤其是，請注意下列變化以及如何影響輸出：

• 表格內 LOAD 陳述式的數量。

• 存在或不存在 * 符號 (載入所有後續欄位)。

• 存在或不存在逗號 (, 符號)。

此範例指令碼包含下列內容：

• 四個表格，全部都參考相同資料。欄位名稱不同。

  • DerivedYears1：使用兩個 LOAD 陳述式載入內嵌欄和包含內嵌欄轉換的欄。

  • DerivedYears2：使用兩個 LOAD 陳述式。指令碼載入內嵌欄，然後載入從原始欄轉換的計算欄位。透過第二個 LOAD 陳述式，原始欄不會載入到表格中，有效讓新欄位取代原始欄位。

  • DerivedYears3：使用單一 LOAD 陳述式載入原始內嵌欄和轉換的欄。

  • DerivedYears4：使用單一 LOAD 陳述式定義內嵌欄位和該原始欄位的轉換。只有轉換的欄位會載入到表格中。

載入指令嗎

DerivedYears1:

Load *,
Year(initial_date1) as derived_year1
;
    
Load
* inline [
initial_date1
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears2:

Load
Year(initial_date2) as derived_year2
;
    
Load
* inline [
initial_date2
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears3:

Load Year(initial_date3) as derived_year3,
* inline [
initial_date3
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears4:

Load Year(initial_date4) as derived_year4
inline [
initial_date4
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

結果

概述

假設您將資訊從大型文字檔案貼到指令碼編輯器中，但想要對資料集中的記錄執行其他處理。例如，您想要移除特定字元和前置詞，並將每個字設為大寫。

此範例指令碼包含下列內容：

• 內嵌表格 Transformations，其中定義了轉換，以變更欄位的文字內容。轉換的文字在此後新增。

• 兩個 LOAD 陳述式。藉由範例中的設定，只有衍生的欄位 ProductName_Trimmed 會載入到表格中。

載入指令嗎

Transformations:

Load 
Capitalize(TextBetween(OrigColumn, '{','}')) as ProductName_Trimmed;

Load * inline [
OrigColumn
Product: {soft drinks and other beverages}
Product:  {snack food}
Product: {electronics and video games}
];

結果

概述

此範例指令碼包含下列內容：

• 用來定義表格 Purchases 的簡單內嵌載入。

• 插入計算欄位 OrderSize。此欄位是來自內嵌資料集的 amount 欄位的轉換。這將購買分類為小或大，取決於金額是否超過 $2000.00。

• where 子句防止在 amount 小於 $0.05 時載入記錄。

載入指令嗎

Purchases:

Load
If(amount<2000,'Small Purchase','Large Purchase') as OrderSize,

* inline
[
ID, amount
1,2660.39
2,100.01
3,500.42
4,5023.99
5,0.04
6,2002.39
7,31034.53
8,1643.58
9,3993.65
10,614.34
11,675.93
]
WHERE
amount>1
;

結果

在上表中，ID 為 5 的交易未載入到表格中。這是因為 amount 值小於 $0.05。

概述

此範例指令碼包含下列內容：

• 用來定義表格 T2 的簡單內嵌載入。

• NullInterpret 變數定義為兩個單引號。載入指令碼時，包含此值的記錄會作為 Null 值來處理。

載入指令嗎

set nullinterpret = '';
T2:
Load * inline [
Test
''
x ];

結果

在上表中，第一個記錄是 Null 值。因此，未包括在視覺化中。存在於具有其他維度之表格中的 Null 值會以 - 符號表示。