Ładowanie danych z tabel wbudowanych

Przegląd

Ten przykład pokazuje, jak można użyć grawisów do ujęcia danych wbudowanych. Dane w przykładzie zawierają nawiasy kwadratowe, co powoduje, że nawiasy kwadratowe nie są kompatybilne jako znaki do ujmowania danych w instrukcji LOAD .

Skrypt ładowania

DataTable:

Load * inline 
`
custom_property, date, amount
[11402], 1/1/2024, 92.99
[11403], 1/2/2024, 102.34
[11404], 1/3/2024, 50.26
[11405], 1/4/2024, 153.69
[11406], 1/5/2024, 75.62
`;

Wyniki

• custom_property

• date

• amount

Przegląd

Zamiana ogranicznika jest przydatna, gdy dane w tabeli zawierają przecinki, które w przeciwnym razie sygnalizowałyby przejście do następnej kolumny w tabeli.

Ten przykład zawiera cztery tabele do załadowania. Są to:

• Cztery tabele do załadowania. Są to:

  • Table1: ogranicznik to kreska pionowa. Dane w kolumnie Phrase zawierają przecinki.

  • Table2: ogranicznikiem jest dwukropek.

  • Table3: ogranicznikiem jest ukośnik odwrotny.

  • Table4: tabela jest rozdzielana przez naciśnięcie klawisza Tab na klawiaturze. Ta opcja jest przydatna podczas kopiowania tabeli z edytora tekstu i wklejania jej do skryptu.

  Table1 przedstawia praktyczne zastosowanie alternatywnego ogranicznika. Pozostałe tabele pokazują więcej opcji ograniczników.

Skrypt ładowania

Table1:
LOAD * INLINE [
ID|Phrase
1 | 'The transaction was complete, but the order has not yet shipped.'
2 | 'We need to confirm the following details: sales rep number, order status, and shipping priority.'
] (Delimiter is '|');

Table2:
LOAD * INLINE [
Num1:Chr1
1:A
2:B ] (Delimiter is ':');

Table3:
LOAD * INLINE [
Num2\Chr2
1\A
2\B ] (Delimiter is \\);

Table4:
LOAD * INLINE [
Num3	Chr3
1	A
2	B ] (Delimiter is '\t');

Wyniki

Przegląd

Ten przykład ilustruje sposób ładowania tabeli wbudowanej bez definiowania nazw kolumn.

Skrypt ładowania

Expenses:

Load * inline
[
1,Category1,40566.49
2,Category2,3504.54
3,Category3,593206.30
] (no labels);

Wyniki

Przegląd

Ten przykładowy skrypt zawiera następujące elementy:

• Instrukcja ładowania wbudowanego definiująca tabelę DataTable.
• Użycie fix (jako części specyfikacji Table format) do wskazania, że dane do załadowania mają ustalony format rekordu.

Skrypt ładowania

DataTable:
LOAD
"@1:4",
"@5:8",
"@9:12",
"@13:16"
INLINE [
a   b   c   d
1   2   3   4
x   y   z   w
] (fix, utf8, embedded labels);

Wyniki

Skrypt ładowania

ORDERS:

Load Original as Updated,
* Inline
[
Original
ProductA
ProductB
ProductC
];

Wyniki

Przegląd

Ten przykład pokazuje, jak można zdefiniować pole wyliczane wskazujące identyfikator każdego wiersza danych bez konieczności ręcznego wpisywania każdej wartości identyfikatora.

Skrypt ładowania

ORDERS:

Load RowNo() as ID,
* Inline
[
ProductName
A
B
C
D
E
];

Wyniki

Przegląd

Ten przykład pokazuje kilka sposobów zastosowania prostej transformacji do danych wbudowanych. Można użyć jednej lub wielu instrukcji LOAD oraz skonfigurować składnię na różne sposoby, aby określić, czy transformacja zastępuje oryginalne pole, nie zastępuje, czy też ładowane są zarówno oryginalne, jak i nowe pole.

W szczególności zwróć uwagę na następujące różnice i ich wpływ na wynik:

• Liczba instrukcji LOAD w tabeli.

• Obecność lub brak symbolu * (ładuje wszystkie kolejne pola).

• Obecność lub brak przecinków (symbol ,).

Ten przykładowy skrypt zawiera następujące elementy:

• Cztery tabele, z których wszystkie odwołują się do tych samych danych. Nazwy pól są różne.

  • DerivedYears1: używa dwóch instrukcji LOAD do załadowania kolumny wbudowanej i kolumny zawierającej transformację kolumny wbudowanej.

  • DerivedYears2: używa dwóch instrukcji LOAD. Skrypt ładuje kolumnę wbudowaną, a następnie ładuje pole wyliczane przekształcone z oryginalnej kolumny. W przypadku drugiej instrukcji LOAD pierwotna kolumna nie jest ładowana do tabeli, co w efekcie powoduje, że nowe pole zastępuje pole pierwotne.

  • DerivedYears3: używa pojedynczej instrukcji LOAD do załadowania zarówno pierwotnej kolumny wbudowanej, jak i kolumny przekształconej.

  • DerivedYears4: używa pojedynczej instrukcji LOAD do zdefiniowania pola wbudowanego i transformacji tego pierwotnego pola. Do tabeli ładowane jest tylko przekształcone pole.

Skrypt ładowania

DerivedYears1:

Load *,
Year(initial_date1) as derived_year1
;
    
Load
* inline [
initial_date1
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears2:

Load
Year(initial_date2) as derived_year2
;
    
Load
* inline [
initial_date2
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears3:

Load Year(initial_date3) as derived_year3,
* inline [
initial_date3
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears4:

Load Year(initial_date4) as derived_year4
inline [
initial_date4
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

Wyniki

Przegląd

Załóżmy, że wklejasz informacje z dużego pliku tekstowego do edytora skryptów, ale chcesz dodatkowo przetworzyć rekordy w zestawie danych. Na przykład chcesz usunąć określone znaki oraz prefiksy i zapisać każde słowo wielką literą.

Ten przykładowy skrypt zawiera następujące elementy:

• Tabela wbudowana Transformations, w której zdefiniowano transformację zmieniającą zawartość tekstową pola. Następnie dodawany jest przekształcany tekst.

• Dwie instrukcje LOAD. W przypadku konfiguracji z przykładu do tabeli ładowane jest tylko pochodne pole ProductName_Trimmed.

Skrypt ładowania

Transformations:

Load 
Capitalize(TextBetween(OrigColumn, '{','}')) as ProductName_Trimmed;

Load * inline [
OrigColumn
Product: {soft drinks and other beverages}
Product:  {snack food}
Product: {electronics and video games}
];

Wyniki

Przegląd

Ten przykładowy skrypt zawiera następujące elementy:

• Prosta wbudowana instrukcja load w celu zdefiniowania tabeli Purchases.

• Wstawienie pola wyliczanego, OrderSize. To pole jest transformacją pola amount z wbudowanego zestawu danych. Klasyfikuje zakupy jako małe i duże w zależności od tego, czy kwota przekracza 2000,00 USD.

• Klauzula where uniemożliwiająca ładowanie rekordów, gdy wartość amount jest mniejsza niż 0,05 USD.

Skrypt ładowania

Purchases:

Load
If(amount<2000,'Small Purchase','Large Purchase') as OrderSize,

* inline
[
ID, amount
1,2660.39
2,100.01
3,500.42
4,5023.99
5,0.04
6,2002.39
7,31034.53
8,1643.58
9,3993.65
10,614.34
11,675.93
]
WHERE
amount>1
;

Wyniki

W powyższej tabeli transakcja z ID 5 nie została załadowana do tabeli. Jest tak dlatego, że wartość amount wynosi mniej niż 0,05 USD.

Przegląd

Ten przykładowy skrypt zawiera następujące elementy:

• Prosta wbudowana instrukcja load w celu zdefiniowania tabeli T2.

• Zmienna NullInterpret zdefiniowana jako dwa pojedyncze cudzysłowy. Po załadowaniu skryptu rekordy zawierające tę wartość są przetwarzane jako wartości null.

Skrypt ładowania

set nullinterpret = '';
T2:
Load * inline [
Test
''
x ];

Wyniki

W powyższej tabeli pierwszy rekord ma wartość null. W związku z tym nie jest uwzględniony w wizualizacji. Wartości null występujące w tabelach z dodatkowymi wymiarami zostałyby oznaczone symbolem -.