Laden von Daten aus Inline-Tabellen

Übersicht

Dieses Beispiel zeigt, wie Sie rückwärts geneigte Hochkommas zum Umschließen von Inline-Daten verwenden. Die Daten im Beispiel enthalten eckige Klammern, weshalb eckige Klammern als Umschließung für die LOAD-Anweisung inkompatibel sind.

Ladeskript

DataTable:

Load * inline 
`
custom_property, date, amount
[11402], 1/1/2024, 92.99
[11403], 1/2/2024, 102.34
[11404], 1/3/2024, 50.26
[11405], 1/4/2024, 153.69
[11406], 1/5/2024, 75.62
`;

Ergebnisse

• custom_property

• date

• amount

Übersicht

Das Ändern des Trennzeichens ist nützlich, wenn Daten in der Tabelle Kommas enthalten, was ansonsten den Wechsel zur nächsten Spalte in der Tabelle angäbe.

Dieses Beispiel enthält vier zu ladende Tabellen. Dies sind:

• Vier zu ladende Tabellen. Dies sind:

  • Table1: Das Trennzeichen ist ein senkrechter Strich. Die Daten in der Spalte Phrase enthalten Kommas.

  • Table2: Das Trennzeichen ist ein Punkt.

  • Table3: Das Trennzeichen ist ein umgekehrter Schrägstrich.

  • Table4: Das Trennzeichen in der Tabelle wird durch Drücken der Tabulatortaste auf der Tastatur gesetzt. Diese Option ist nützlich, wenn Sie eine Tabelle aus einem Textverarbeitungsprogramm kopieren und in das Skript einfügen.

  Table1 zeigt einen praktischen Anwendungsfall für die Verwendung eines alternativen Trennzeichens. Die anderen Tabellen zeigen weitere Trennzeichenoptionen.

Ladeskript

Table1:
LOAD * INLINE [
ID|Phrase
1 | 'The transaction was complete, but the order has not yet shipped.'
2 | 'We need to confirm the following details: sales rep number, order status, and shipping priority.'
] (Delimiter is '|');

Table2:
LOAD * INLINE [
Num1:Chr1
1:A
2:B ] (Delimiter is ':');

Table3:
LOAD * INLINE [
Num2\Chr2
1\A
2\B ] (Delimiter is \\);

Table4:
LOAD * INLINE [
Num3	Chr3
1	A
2	B ] (Delimiter is '\t');

Ergebnisse

Übersicht

Dieses Beispiel zeigt, wie Sie eine Inline-Tabelle ohne Definieren von Spaltennamen laden können.

Ladeskript

Expenses:

Load * inline
[
1,Category1,40566.49
2,Category2,3504.54
3,Category3,593206.30
] (no labels);

Ergebnisse

Übersicht

Dieses Beispielskript enthält Folgendes:

• Eine Inline-load-Anweisung, die die Tabelle DataTable definiert.
• Die Verwendung von fix (als Teil der Table format-Spezifikation), um anzugeben, dass die zu ladenden Daten ein festes Datensatzformat aufweisen.

Ladeskript

DataTable:
LOAD
"@1:4",
"@5:8",
"@9:12",
"@13:16"
INLINE [
a   b   c   d
1   2   3   4
x   y   z   w
] (fix, utf8, embedded labels);

Ergebnisse

Ladeskript

ORDERS:

Load Original as Updated,
* Inline
[
Original
ProductA
ProductB
ProductC
];

Ergebnisse

Übersicht

Dieses Beispiel zeigt, wie Sie ein berechnetes Feld definieren können, um die ID jeder Datenzeile anzugeben, ohne jeden ID-Wert manuell einzugeben.

Ladeskript

ORDERS:

Load RowNo() as ID,
* Inline
[
ProductName
A
B
C
D
E
];

Ergebnisse

Übersicht

Dieses Beispiel zeigt mehrere Weisen, auf die eine einfache Umwandlung auf Inline-Daten angewendet werden kann. Sie können eine oder mehrere LOAD-Anweisungen verwenden und die Syntax auf verschiedene Arten konfigurieren, um zu definieren, ob eine Umwandlung das ursprüngliche Feld ersetzt oder ob sowohl das ursprüngliche als auch neue Felder geladen werden.

Achten Sie besonders auf die Variationen im folgenden Beispiel und darauf, wie sie sich auf die Ausgabe auswirken:

• Anzahl der LOAD-Anweisungen innerhalb der Tabelle.

• Vorliegen oder Fehlen des *-Symbols (lädt alle nachfolgenden Felder)

• Vorliegen oder Fehlen von Kommas (,-Symbol).

Dieses Beispielskript enthält Folgendes:

• Vier Tabellen, die alle die gleichen Daten referenzieren. Die Feldnamen sind verschieden.

  • DerivedYears1: Verwendet zwei LOAD-Anweisungen, um eine Inline-Spalte und eine Spalte mit einer Umwandlung der Inline-Spalte zu laden.

  • DerivedYears2: Verwendet zwei LOAD-Anweisungen. Das Skript lädt eine Inline-Spalte und dann ein berechnetes Feld, das aus der ursprünglichen Spalte umgewandelt wurde. Mit der zweiten LOAD-Anweisung wird die ursprüngliche Spalte nicht in die Tabelle geladen, was effektiv bewirkt, dass das neue Feld das ursprüngliche Feld ersetzt.

  • DerivedYears3: Verwendet eine einzige LOAD-Anweisung, um sowohl die ursprüngliche Inline-Spalte als auch eine umgewandelte Spalte zu laden.

  • DerivedYears4: Verwendet eine einzelne LOAD-Anweisung, um ein Inline-Feld und eine Umwandlung dieses ursprünglichen Felds zu definieren. Nur das umgewandelte Feld wird in die Tabelle geladen.

Ladeskript

DerivedYears1:

Load *,
Year(initial_date1) as derived_year1
;
    
Load
* inline [
initial_date1
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears2:

Load
Year(initial_date2) as derived_year2
;
    
Load
* inline [
initial_date2
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears3:

Load Year(initial_date3) as derived_year3,
* inline [
initial_date3
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears4:

Load Year(initial_date4) as derived_year4
inline [
initial_date4
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

Ergebnisse

Übersicht

Angenommen, Sie fügen Informationen aus einer großen Textdatei in den Skript-Editor ein, möchten die Dateneinträge im Datensatz aber noch weiter verarbeiten. Sie möchten beispielsweise bestimmte Zeichen und Vorzeichen entfernen und alle Wörter mit einem Großbuchstaben beginnen lassen.

Dieses Beispielskript enthält Folgendes:

• Eine Inline-Tabelle, Transformations, in der eine Umwandlung definiert ist, um den Textinhalt eines Felds zu ändern. Der umzuwandelnde Text wird danach hinzugefügt.

• Zwei LOAD-Anweisungen. Mit der Konfiguration im Beispiel wird nur das abgeleitete Feld ProductName_Trimmed in die Tabelle geladen.

Ladeskript

Transformations:

Load 
Capitalize(TextBetween(OrigColumn, '{','}')) as ProductName_Trimmed;

Load * inline [
OrigColumn
Product: {soft drinks and other beverages}
Product:  {snack food}
Product: {electronics and video games}
];

Ergebnisse

Übersicht

Dieses Beispielskript enthält Folgendes:

• Einen einfachen Inline-Ladevorgang zum Definieren der Tabelle Purchases.

• Die Einfügung eines berechneten Felds, OrderSize. Dieses Feld ist eine Umwandlung des Felds amount aus dem Inline-Datensatz. Es ordnet Käufe in die Kategorien „klein“ oder „groß“ ein, je nachdem, ob der Betrag 2000,00 $ überschreitet oder nicht.

• Eine where-Bedingung, die verhindert, dass Datensätze geladen werden, wenn amount weniger als 0,05 $ beträgt.

Ladeskript

Purchases:

Load
If(amount<2000,'Small Purchase','Large Purchase') as OrderSize,

* inline
[
ID, amount
1,2660.39
2,100.01
3,500.42
4,5023.99
5,0.04
6,2002.39
7,31034.53
8,1643.58
9,3993.65
10,614.34
11,675.93
]
WHERE
amount>1
;

Ergebnisse

In der obigen Tabelle wurde die Transaktion mit einer ID von 5 nicht in die Tabelle geladen. Dies liegt daran, dass der Wert für amount weniger als 0,05 $ beträgt.

Übersicht

Dieses Beispielskript enthält Folgendes:

• Einen einfachen Inline-Ladevorgang zum Definieren der Tabelle T2.

• Die Variable NullInterpret, die als zwei einzelne Anführungszeichen definiert ist. Beim Laden des Skripts werden Datensätze, die diesen Wert enthalten, als Null-Werte verarbeitet.

Ladeskript

set nullinterpret = '';
T2:
Load * inline [
Test
''
x ];

Ergebnisse

In der obigen Tabelle ist der erste Datensatz ein Null-Wert. Daher wird er nicht in die Visualisierung eingeschlossen. Null-Werte in Tabellen mit zusätzlichen Dimensionen würden mit einem --Symbol bezeichnet.