Gegevens laden vanuit inline-tabellen

Overzicht

In dit voorbeeld wordt getoond hoe u backticks kunt gebruiken om de inline-gegevens in te sluiten. De gegevens in het voorbeeld bevatten vierkante haakjes, waardoor de vierkante haakjes niet gebruikt kunnen worden om de LOAD-instructie in te sluiten.

Load-script

DataTable:

Load * inline 
`
custom_property, date, amount
[11402], 1/1/2024, 92.99
[11403], 1/2/2024, 102.34
[11404], 1/3/2024, 50.26
[11405], 1/4/2024, 153.69
[11406], 1/5/2024, 75.62
`;

Resultaten

• custom_property

• date

• amount

Overzicht

Het wijzigen van het scheidingsteken is handig als gegevens in de tabel komma's bevatten, wat anders aangeeft dat er naar de volgende kolom in de tabel overgeschakeld moet worden.

Dit voorbeeld bevat vier tabellen die geladen moeten worden. Ze zijn als volgt:

• Vier tabellen moeten geladen worden. Ze zijn als volgt:

  • Table1: scheidingsteken is een verticale staaf (pijp). De gegevens in de kolom Phrase bevatten komma's.

  • Table2: scheidingsteken is een dubbele punt.

  • Table3 is een backslash.

  • Table4: de tabel wordt gescheiden door op de Tab-toets op het toetsenbord te drukken. Deze optie is handig als u een tabel van een tekstverwerker kopieert en plakt in het script.

  Table1 toont een praktische usecase voor het gebruik van een alternatief scheidingsteken. De andere tabellen tonen meer scheidingstekens.

Load-script

Table1:
LOAD * INLINE [
ID|Phrase
1 | 'The transaction was complete, but the order has not yet shipped.'
2 | 'We need to confirm the following details: sales rep number, order status, and shipping priority.'
] (Delimiter is '|');

Table2:
LOAD * INLINE [
Num1:Chr1
1:A
2:B ] (Delimiter is ':');

Table3:
LOAD * INLINE [
Num2\Chr2
1\A
2\B ] (Delimiter is \\);

Table4:
LOAD * INLINE [
Num3	Chr3
1	A
2	B ] (Delimiter is '\t');

Resultaten

Overzicht

In dit voorbeeld wordt getoond hoe u een inline-tabel kunt laden zonder kolomnamen te definiëren.

Load-script

Expenses:

Load * inline
[
1,Category1,40566.49
2,Category2,3504.54
3,Category3,593206.30
] (no labels);

Resultaten

Overzicht

In dit voorbeeldscript wordt het volgende getoond:

• Een inline-load-instructie die de tabel DataTable definieert.
• Het gebruik van fix (als onderdeel van de specificatie Table format) om aan te geven dat de gegevens in een opmaak met vaste recordlengte worden geladen.

Load-script

DataTable:
LOAD
"@1:4",
"@5:8",
"@9:12",
"@13:16"
INLINE [
a   b   c   d
1   2   3   4
x   y   z   w
] (fix, utf8, embedded labels);

Resultaten

Load-script

ORDERS:

Load Original as Updated,
* Inline
[
Original
ProductA
ProductB
ProductC
];

Resultaten

Overzicht

In dit voorbeeld wordt getoond hoe u een berekend veld kunt definiëren om de ID van elke gegevensrij aan te geven, zonder elke ID-waarde handmatig te hoeven typen.

Load-script

ORDERS:

Load RowNo() as ID,
* Inline
[
ProductName
A
B
C
D
E
];

Resultaten

Overzicht

Dit voorbeeld toont verschillende manieren waarop een eenvoudige transformatie op inline-gegevens kan worden toegepast. U kunt één of meerdere LOAD-instructies gebruiken en de syntaxis op verschillende manieren configureren om te definiëren of een transformatie het originele veld vervangt of dat zowel het origineel en nieuwe velden worden geladen.

Let met name op de variaties in het volgende voorbeeld en hoe ze de uitvoer beïnvloeden:

• Aantal LOAD-instructies in de tabel.

• Aanwezigheid of afwezigheid van het symbool * (laadt alle voorgaande velden).

• Aanwezigheid of afwezigheid van komma's (symbool ,).

In dit voorbeeldscript wordt het volgende getoond:

• Vier tabellen die allemaal naar dezelfde gegevens verwijzen. De veldnamen zijn verschillend.

  • DerivedYears1: gebruikt twee LOAD-instructies om een inline-kolom te laden en een kolom die de transformatie van de inline-kolom bevat.

  • DerivedYears2: gebruikt twee LOAD-instructies. Het script laadt een inline-kolom en laadt vervolgens een berekend veld dat is getransformeerd op basis van de originele kolom. Bij de tweede LOAD-instructie wordt de originele kolom niet geladen in de tabel, waardoor het nieuwe veld in feite een vervanging is van het originele veld.

  • DerivedYears3: gebruikt een afzonderlijke LOAD-instructie om zowel de originele inline-kolom als de getransformeerde kolom te laden.

  • DerivedYears4: gebruikt een afzonderlijke LOAD-instructie om een inline-veld en een transformatie van dat originele veld te definiëren. Alleen het getransformeerde veld wordt geladen in de tabel.

Load-script

DerivedYears1:

Load *,
Year(initial_date1) as derived_year1
;
    
Load
* inline [
initial_date1
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears2:

Load
Year(initial_date2) as derived_year2
;
    
Load
* inline [
initial_date2
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears3:

Load Year(initial_date3) as derived_year3,
* inline [
initial_date3
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears4:

Load Year(initial_date4) as derived_year4
inline [
initial_date4
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

Resultaten

Overzicht

Stel dat u gegevens van een groot tekstbestand in de scripteditor plakt, maar u wilt een aanvullende verwerking van de records in de gegevensverzameling uitvoeren. U wilt bijvoorbeeld bepaalde tekens en prefixen verwijderen en elk woord beginnen met een hoofdletter.

In dit voorbeeldscript wordt het volgende getoond:

• Een inline-tabel, Transformations, waarin een transformatie is gedefinieerd om tekstinhoud van een veld te wijzigen. De tekst die wordt getransformeerd wordt hierna toegevoegd.

• Twee LOAD-instructies. Bij de configuratie in het voorbeeld, wordt alleen het afgeleide veld ProductName_Trimmed geladen in de tabel.

Load-script

Transformations:

Load 
Capitalize(TextBetween(OrigColumn, '{','}')) as ProductName_Trimmed;

Load * inline [
OrigColumn
Product: {soft drinks and other beverages}
Product:  {snack food}
Product: {electronics and video games}
];

Resultaten

Overzicht

In dit voorbeeldscript wordt het volgende getoond:

• Een simpele inline-lading om de tabel Purchases te definiëren.

• Het invoegen van een berekend veld, OrderSize. Dit veld is een transformatie van het veld amount van de inline-gegevensverzameling. Hierin worden aankopen gecategoriseerd als klein of groot, afhankelijk van het feit of het bedrag $2000.00 overschrijdt.

• Een where-clausule die voorkomt dat records worden geladen als het amount lager is dan $0.05.

Load-script

Purchases:

Load
If(amount<2000,'Small Purchase','Large Purchase') as OrderSize,

* inline
[
ID, amount
1,2660.39
2,100.01
3,500.42
4,5023.99
5,0.04
6,2002.39
7,31034.53
8,1643.58
9,3993.65
10,614.34
11,675.93
]
WHERE
amount>1
;

Resultaten

In de bovenstaande tabel is een transactie met een ID van 5 niet geladen in de tabel. Dit komt doordat de waarde amount lager is dan $0.05.

Overzicht

In dit voorbeeldscript wordt het volgende getoond:

• Een simpele inline-lading om de tabel T2 te definiëren.

• De variabele NullInterpret is gedefinieerd als twee enkele aanhalingstekens. Als het script is geladen, worden records die deze waarde bevatten verwerkt als null-waarden.

Load-script

set nullinterpret = '';
T2:
Load * inline [
Test
''
x ];

Resultaten

In de bovenstaande tabel is het eerste record een null-waarde. Daardoor wordt deze niet opgenomen in de visualisatie. Null-waarden die aanwezig zijn in tabellen met aanvullende dimensies worden aangegeven met het symbool -.