インライン テーブルからデータを読み込む

概要

この例では、インライン データを囲むためにバック ティックを使用する方法を示します。例のデータには、角括弧文字が含まれていますが、そのため LOAD ステートメントの囲み文字として角括弧は使用できません。

ロード スクリプト

DataTable:

Load * inline 
`
custom_property, date, amount
[11402], 1/1/2024, 92.99
[11403], 1/2/2024, 102.34
[11404], 1/3/2024, 50.26
[11405], 1/4/2024, 153.69
[11406], 1/5/2024, 75.62
`;

結果

• custom_property

• date

• amount

概要

区切り文字は、テーブル内のデータにカンマが含まれている場合に交換できます。カンマが含まれていない場合、テーブル内の次の列に切り替える合図となります。

この例には、ロードするテーブルが 4 つ含まれています。次の通りです。

• ロードする 4 つのテーブル。次の通りです。

  • Table1: 区切り文字は縦棒 (パイプ)です。Phrase 列のデータにはカンマが含まれています。

  • Table2: 区切り文字はコロンです。

  • Table3: 区切り文字はバックスラッシュです。

  • Table4: テーブルは、キーボードで Tab キーを押すことで区切られます。このオプションは、ワード プロセッサーからテーブルをコピーして、スクリプトにペーストする際に有用です。

  Table1 は、代替区切り文字を使用する実際的なユース ケースを示しています。その他のテーブルには、別の区切り文字オプションが示されています。

ロード スクリプト

Table1:
LOAD * INLINE [
ID|Phrase
1 | 'The transaction was complete, but the order has not yet shipped.'
2 | 'We need to confirm the following details: sales rep number, order status, and shipping priority.'
] (Delimiter is '|');

Table2:
LOAD * INLINE [
Num1:Chr1
1:A
2:B ] (Delimiter is ':');

Table3:
LOAD * INLINE [
Num2\Chr2
1\A
2\B ] (Delimiter is \\);

Table4:
LOAD * INLINE [
Num3	Chr3
1	A
2	B ] (Delimiter is '\t');

結果

概要

この例は、列名を定義せずにインライン テーブルをロードできる方法を示しています。

ロード スクリプト

Expenses:

Load * inline
[
1,Category1,40566.49
2,Category2,3504.54
3,Category3,593206.30
] (no labels);

結果

概要

この例のスクリプトには、次の要素が含まれています。

• テーブル DataTable を定義するインライン ロード ステートメント。
• ロードするデータが固定レコード形式であることを示す fix (Table format 仕様の一部として) の使用。

ロード スクリプト

DataTable:
LOAD
"@1:4",
"@5:8",
"@9:12",
"@13:16"
INLINE [
a   b   c   d
1   2   3   4
x   y   z   w
] (fix, utf8, embedded labels);

結果

ロード スクリプト

ORDERS:

Load Original as Updated,
* Inline
[
Original
ProductA
ProductB
ProductC
];

結果

概要

この例は、計算された項目を定義して、各 ID 値を手入力しなくても各データ行の ID を示すことができる方法を示しています。

ロード スクリプト

ORDERS:

Load RowNo() as ID,
* Inline
[
ProductName
A
B
C
D
E
];

結果

概要

この例では、単純な変換をインライン データに適用する方法をいくつか示しています。1 つまたは複数の LOAD ステートメントを使用し、異なる方法で構文を構成することにより、変換により元の項目が置換されるか、それとも元の項目と新規の項目の両方がロードされるのかを定義できます。

特に、次のバリエーションと、出力にそれらがどう影響するかに注意してください。

• テーブル内の LOAD ステートメントの数。

• * 記号の有無 (後続の項目すべてをロードします)。

• カンマ (, 記号) の有無。

この例のスクリプトには、次の要素が含まれています。

• 4 つのテーブル。同じデータを参照します。項目名は異なります。

  • DerivedYears1: 2 つの LOAD ステートメントを使用して、インライン列と、インライン列の変換を含む列をロードします。

  • DerivedYears2: 2 つの LOAD ステートメントを使用します。スクリプトはインライン列をロードし、次に元の列から変換された計算された項目をロードします。2 番目の LOAD ステートメントでは、元の列がテーブルにロードされないため、元の項目を効果的に新しい項目が置換しています。

  • DerivedYears3: 単一の LOAD ステートメントを使用して、元のインライン列と変換された列の両方をロードします。

  • DerivedYears4: 単一の LOAD ステートメントを使用して、インライン項目と元の項目の変換を定義します。変換された項目のみがテーブルにロードされます。

ロード スクリプト

DerivedYears1:

Load *,
Year(initial_date1) as derived_year1
;
    
Load
* inline [
initial_date1
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears2:

Load
Year(initial_date2) as derived_year2
;
    
Load
* inline [
initial_date2
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears3:

Load Year(initial_date3) as derived_year3,
* inline [
initial_date3
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears4:

Load Year(initial_date4) as derived_year4
inline [
initial_date4
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

結果

概要

大きなテキスト ファイルからスクリプト エディタに情報をペーストしているが、データセットのレコードに追加処理を実行したいと考えています。例えば、特定の文字とプレフィックスを削除して、各単語を大文字にしたい場合などです。

この例のスクリプトには、次の要素が含まれています。

• インライン テーブル、Transformations。項目のテキスト コンテンツを変更するために、変換が定義されています。変換されるテキストは、この後に追加されます。

• 2 つの LOAD ステートメント。例の構成の場合、派生項目 ProductName_Trimmed のみがテーブルにロードされます。

ロード スクリプト

Transformations:

Load 
Capitalize(TextBetween(OrigColumn, '{','}')) as ProductName_Trimmed;

Load * inline [
OrigColumn
Product: {soft drinks and other beverages}
Product:  {snack food}
Product: {electronics and video games}
];

結果

概要

この例のスクリプトには、次の要素が含まれています。

• テーブル Purchases を定義する単純なインライン ロード。

• 計算された項目、OrderSize の挿入。この項目は、インライン データセットから amount 項目を変換したものです。購入額が 2000 ドルを超えるかどうかで、大か小に分類されます。

• amount が 0.05 ドル未満の場合にレコードがロードされないようにする where 節。

ロード スクリプト

Purchases:

Load
If(amount<2000,'Small Purchase','Large Purchase') as OrderSize,

* inline
[
ID, amount
1,2660.39
2,100.01
3,500.42
4,5023.99
5,0.04
6,2002.39
7,31034.53
8,1643.58
9,3993.65
10,614.34
11,675.93
]
WHERE
amount>1
;

結果

上のテーブルでは、5の ID のトランザクションがテーブルにロードされませんでした。これは、amount の値が 0.05 ドル未満だからです。

概要

この例のスクリプトには、次の要素が含まれています。

• テーブル T2 を定義する単純なインライン ロード。

• NullInterpret 変数は、2 つの一十引用符として定義されます。スクリプトがロードされると、この値を含むレコードが null 値として処理されます。

ロード スクリプト

set nullinterpret = '';
T2:
Load * inline [
Test
''
x ];

結果

上のテーブルでは、最初のレコードが null 値です。そのため、ビジュアライゼーションには含まれません。追加の軸を持ちこのテーブルに存在する null 値は、- 記号で示されます。