Satır içi tablolardan veri yükleme

Genel bakış

Bu örnek, satır içi verilerin başına ve sonuna nasıl kesme işareti ekleyebileceğinizi gösterir. Örnekteki veriler köşeli parantez karakterleri içerir, bu da köşeli parantezlerin LOAD deyimi için uygun olmamasına neden olur.

Kod dosyası

DataTable:

Load * inline 
`
custom_property, date, amount
[11402], 1/1/2024, 92.99
[11403], 1/2/2024, 102.34
[11404], 1/3/2024, 50.26
[11405], 1/4/2024, 153.69
[11406], 1/5/2024, 75.62
`;

Sonuçlar

• custom_property

• date

• amount

Genel bakış

Tablodaki veriler virgül içerdiğinde ayırıcıyı değiştirmek kullanışlıdır; aksi takdirde tabloda bir sonraki sütuna geçişe işaret ederler.

Bu örnek, yüklenecek dört tabloyu içerir. Bunlar aşağıda verilmiştir:

• Yüklenecek dört tablo. Bunlar aşağıda verilmiştir:

  • Table1: Sınırlayıcı, dikey sütundur (dikey çizgi). Phrase sütunundaki veriler virgül içerir.

  • Table2: Sınırlayıcı, iki nokta üst üstedir.

  • Table3: Sınırlayıcı, ters eğik çizgidir.

  • Table4: Tablo, klavyedeki Tab tuşuna basarak ayrılır. Bu seçenek, bir tabloyu kelime işlemciden kopyalayıp komut dosyasına yapıştırırken kullanışlıdır.

  Table1, alternatif bir ayırıcı kullanmaya yönelik pratik bir kullanım durumu gösterir. Diğer tablolarda daha fazla ayırıcı seçeneği gösterilir.

Kod dosyası

Table1:
LOAD * INLINE [
ID|Phrase
1 | 'The transaction was complete, but the order has not yet shipped.'
2 | 'We need to confirm the following details: sales rep number, order status, and shipping priority.'
] (Delimiter is '|');

Table2:
LOAD * INLINE [
Num1:Chr1
1:A
2:B ] (Delimiter is ':');

Table3:
LOAD * INLINE [
Num2\Chr2
1\A
2\B ] (Delimiter is \\);

Table4:
LOAD * INLINE [
Num3	Chr3
1	A
2	B ] (Delimiter is '\t');

Sonuçlar

Genel bakış

Bu örnekte, bir satır içi tabloyu sütun adlarını tanımlamadan nasıl yükleyebileceğiniz gösterilmiştir.

Kod dosyası

Expenses:

Load * inline
[
1,Category1,40566.49
2,Category2,3504.54
3,Category3,593206.30
] (no labels);

Sonuçlar

Genel bakış

Bu örnek komut dosyası şunları içerir:

• DataTable tablosunu tanımlayan bir satır içi yükleme deyimi.
• Yüklenecek verilerin sabit kayıt biçiminde olduğunu belirtmek için fix kullanma (Table format belirtiminin parçası olarak).

Kod dosyası

DataTable:
LOAD
"@1:4",
"@5:8",
"@9:12",
"@13:16"
INLINE [
a   b   c   d
1   2   3   4
x   y   z   w
] (fix, utf8, embedded labels);

Sonuçlar

Kod dosyası

ORDERS:

Load Original as Updated,
* Inline
[
Original
ProductA
ProductB
ProductC
];

Sonuçlar

Genel bakış

Bu örnekte, her bir kimlik değerini manuel olarak yazmadan her bir veri satırının kimliğini belirtmek için bir hesaplanan alanı nasıl tanımlayabileceğinizi gösterilmektedir.

Kod dosyası

ORDERS:

Load RowNo() as ID,
* Inline
[
ProductName
A
B
C
D
E
];

Sonuçlar

Genel bakış

Bu örnekte, basit bir dönüşümün satır içi verilere uygulanabileceği birkaç yol gösterilmektedir. Bir dönüşümün orijinal alanın yerini alıp almayacağını veya hem orijinal hem yeni alanların yüklenip yüklenmeyeceğini tanımlamak için bir ya da birden fazla LOAD deyimi kullanabilir ve söz dizimini farklı şekillerde yapılandırabilirsiniz.

Özellikle aşağıdaki varyasyonlara ve bunların çıktıyı nasıl etkilediğine dikkat edin:

• Tablodaki LOAD deyimi sayısı.

• * sembolünün varlığı veya yokluğu (tüm sonraki alanları yükler).

• Virgüllerin varlığı veya yokluğu (, sembolü).

Bu örnek komut dosyası şunları içerir:

• Tümü aynı verilere referans veren dört tablo. Alan adları farklıdır.

  • DerivedYears1: Bir satır içi sütunu ve satır içi sütunun dönüşümünü içeren bir sütunu yüklemek için iki LOAD deyimi kullanır.

  • DerivedYears2: İki LOAD deyimi kullanır. Komut dosyası bir satır içi sütun yükler, ardından orijinal sütundan dönüştürülen bir hesaplanan alanı yükler. İkinci LOAD deyimiyle orijinal sütun, tabloya yüklenmez ve bu sayede yeni alanın etkili bir şekilde orijinal alanın yerini almasını sağlar.

  • DerivedYears3: Hem orijinal satır içi sütunu hem dönüştürülen bir sütunu yüklemek için tek bir LOAD deyimi kullanır.

  • DerivedYears4: Bir satır içi alanını ve o orijinal alanın bir dönüşümünü tanımlamak için tek bir LOAD deyimi kullanır. Yalnızca dönüştürülen alan tabloya yüklenir.

Kod dosyası

DerivedYears1:

Load *,
Year(initial_date1) as derived_year1
;
    
Load
* inline [
initial_date1
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears2:

Load
Year(initial_date2) as derived_year2
;
    
Load
* inline [
initial_date2
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears3:

Load Year(initial_date3) as derived_year3,
* inline [
initial_date3
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

DerivedYears4:

Load Year(initial_date4) as derived_year4
inline [
initial_date4
'1/1/2022'
'1/1/2023'
'1/1/2024'
];

Sonuçlar

Genel bakış

Büyük bir metin dosyasından komut dosyası düzenleyiciye bilgi yapıştırdığınızı, ancak veri kümesindeki kayıtlar üzerinde ilave işleme gerçekleştirmek istediğinizi varsayalım. Örneğin, belirli karakterleri ve ön ekleri kaldırmak ve her bir sözcüğün baş harfini büyük yapmak istiyorsunuz.

Bu örnek komut dosyası şunları içerir:

• Bir alanın metin içeriğini değiştirmek üzere içinde bir dönüşüm tanımı olan bir satır içi tablo Transformations. Dönüştürülen metin bundan sonra eklenir.

• İki LOAD deyimi. Örnekteki yapılandırmayla yalnızca türetilen alan ProductName_Trimmed tabloya yüklenir.

Kod dosyası

Transformations:

Load 
Capitalize(TextBetween(OrigColumn, '{','}')) as ProductName_Trimmed;

Load * inline [
OrigColumn
Product: {soft drinks and other beverages}
Product:  {snack food}
Product: {electronics and video games}
];

Sonuçlar

Genel bakış

Bu örnek komut dosyası şunları içerir:

• Purchases tablosunu tanımlamak için basit bir satır içi yükleme.

• OrderSize olan bir hesaplanan alanın eklenmesi. Bu alan, satır içi veri kümesinden amount alanının bir dönüşümüdür. Alışverişleri, 2000,00 USD tutarını aşıp aşmadığına göre küçük veya büyük olarak kategorize eder.

• amount 0,05 USD tutarından az olduğunda kayıtların yüklenmesini engelleyen bir where cümlesi.

Kod dosyası

Purchases:

Load
If(amount<2000,'Small Purchase','Large Purchase') as OrderSize,

* inline
[
ID, amount
1,2660.39
2,100.01
3,500.42
4,5023.99
5,0.04
6,2002.39
7,31034.53
8,1643.58
9,3993.65
10,614.34
11,675.93
]
WHERE
amount>1
;

Sonuçlar

Yukarıdaki tabloda, 5 olan bir ID içeren işlem tabloya yüklenmedi. Bunun nedeni, amount değerinin 0,05 USD tutarından az olması.

Genel bakış

Bu örnek komut dosyası şunları içerir:

• T2 tablosunu tanımlamak için basit bir satır içi yükleme.

• İki tek tırnak işareti olarak tanımlanan NullInterpret değişkeni. Komut dosyası yüklendiğinde bu değeri içeren kayıtlar, null değerler olarak işlenir.

Kod dosyası

set nullinterpret = '';
T2:
Load * inline [
Test
''
x ];

Sonuçlar

Yukarıdaki tabloda birinci kayıt bir null değerdir. Bu nedenle görselleştirmeye dahil edilmez. Ek boyutlar içeren tablolardaki null değerler bir - sembolüyle belirtilecektir.