Count - チャート関数

Count() は、各チャート軸に含まれる値、テキスト、数値の数の集計に使われます。

構文:

Count({[SetExpression] [DISTINCT] [TOTAL [<fld {,fld}>]]} expr)

戻り値データ型：整数

引数
引数	説明
expr	メジャーの対象となるデータが含まれている数式または項目。
SetExpression	デフォルトでは、集計関数は選択されたレコードセットに対して集計を行います。Set 分析数式でレコードセットを定義することも可能です。
DISTINCT	関数の引数の前に DISTINCT という用語が付いている場合、関数の引数の評価から生じる重複は無視されます。
TOTAL	関数の引数の前に TOTAL の文字が配置されている場合、現在の軸の値に関連しているものだけでなく、現在の選択範囲内にあるすべての可能な値に対して計算が実行されます。つまりチャート軸は無視されます。 TOTAL [<fld {.fld}>] (ここで、TOTAL 修飾子の後には、1 つまたは複数の項目名のリストがチャート軸変数のサブセットとして続く) を使用して、合計絞込値のサブセットを作成できます。集計範囲の定義

例: チャートの数式
例	結果
Count(OrderNumber)	OrderNumber の値を持つ可能性がある行の数を返します。空のレコードも含め、すべてのレコードがカウントされます。情報メモ「0」は値と見なされ、空白のセルとはなりません。ただし、メジャーの軸に対する集計結果が 0 の場合、この軸はチャートには含まれません。
Count(Customer)	すべての行の発生回数を評価します。
Count(DISTINCT [Customer])	DISTINCT 修飾子は、Count が一意の発生のみを評価するように制限します。
Count(OrderNumber)/Count({1} TOTAL OrderNumber)	この数式は、選択した顧客からの注文数を、すべての顧客からの注文数に対する割合として返します。
Count(TOTAL <Product> OrderNumber)	選択した顧客のみの製品に対する注文数を返します。空のセルもカウントされます。

例 - Count の基本

概要

データロードエディターを開き、以下のロードスクリプトを新しいタブに追加します。

ロードスクリプトには次が含まれています。

「Example」というデータテーブルにロードされるデータセット。
データテーブル内の次の項目:
- Customer
- Product
- OrderNumber
- UnitSales
- UnitPrice

ロードスクリプト

Example:
LOAD * inline [
Customer|Product|OrderNumber|UnitSales|UnitPrice
Astrida|AA|1|4|16
Astrida|AA|7|10|15
Astrida|BB|4|9|9
Betacab|CC|6|5|10
Betacab|AA|5|2|20
Betacab|BB|1|25| 25
Canutility|AA|3|8|15
Canutility|CC|||19
Divadip|CC|2|4|16
Divadip|DD|3|1|25
](delimiter is '|');

結果

データをロードしてシートを開きます。新しいテーブルを作成し、この項目を軸として追加します:

Customer

次のメジャーを作成します:

=Count(OrderNumber)、注文の数を数えます。
=Count(Customer)、顧客レコードの数を計算します。
=Count(DISTINCT Customer)、個別の顧客の数をカウントします。
=Count(OrderNumber)/Count({1} TOTAL OrderNumber)、選択した顧客の注文の比率を、顧客注文の合計の比率としてカウントします。
=Count(TOTAL <Product> OrderNumber)、選択した顧客のみの製品の注文数をカウントします (空のセルもカウントされます)。

Results table
Customer	Count(OrderNumber)	Count(Customer)	Count(DISTINCT Customer)	Count(OrderNumber)/Count({1} TOTAL OrderNumber)	Count(TOTAL <Product> OrderNumber)
Totals	10	10	4	1	10
Astrida	3	3	1	0.3	10
Betacab	3	3	1	0.3	10
Canutility	2	2	1	0.2	10
Divadip	2	2	1	0.2	10

結果を見ると、次のことがわかります。

最初のメジャー: データセットには 10 件の注文レコードがあります。
2 番目のメジャー: データセットには 10 件の顧客レコードがあります。
3 番目のメジャー: データセットには 4 人の異なる (一意の) 顧客がいます。
4 番目のメジャー: 選択が適用されていないため、1 を返します。顧客 Canutility を選択した場合、データセットの合計 10 件のレコードのうち、この顧客の注文レコードが 2 件あるため、値は 0.2 に変わります。
5 番目のメジャー: 選択が適用されていないため、10 を返します。顧客 Astrida と Canutility を選択した場合、値は 5 に変わります。これは、これらの顧客の製品に対する注文数です (空のセルもカウントされます) 。

例 - Count を使用して製品ごとの販売数を調べる

概要

データセットには、店舗の売上データが含まれています。ここでは、製品ごとの販売数を知りたいと考えています。

データロードエディターを開き、以下のロードスクリプトを新しいタブに追加します。

ロードスクリプトには次が含まれています。

「Example」というデータテーブルにロードされるデータセット。
データテーブル内の次の項目:
- Product
- Sales
- Region
- Status

ロードスクリプト

Example:
Load * inline [
Product,Sales,Region,Status
Apple, 100, North, Completed
Banana, 80, South, Pending
Carrot, 50, East, Completed
Apple, 120, North, Completed
Banana, 90, South, Completed
Carrot, 60, West, Pending
Apple, 110, North, Completed
Banana, 85, South, Completed
Carrot, 55, East, Pending
];

結果

データをロードしてシートを開きます。新しいテーブルを作成し、この項目を軸として追加します:

Product

次のメジャーを作成します:

=Count(Sales)、製品ごとの販売数を計算します。
=Count({<Status={'Completed'}>} Sales)、完了した注文の販売数を計算します。
=Count({<Status={'Pending'}>} Sales)、注文が保留中の販売数を計算します。
=Count({<Region={'North'}>} Sales)、North 地域での注文数を計算します。

Results table
Product	Count(Sales)	Count({<Status={'Completed'}>} Sales)	Count({<Status={'Pending'}>} Sales)	Count({<Region={'North'}>} Sales)
Totals	9	6	3	3
Apple	3	3	0	3
Banana	3	2	1	0
Carrot	3	1	2	0

Count 関数の出力は、製品別の販売注文の合計数の内訳、完了した注文数、保留中の注文数を返します。最後のメジャーは、North 地域の販売記録の数を返します。

このページは役に立ちましたか?

このページまたはコンテンツに、タイポ、ステップの省略、技術的エラーなどの問題が見つかった場合は、お知らせください。改善に役立たせていただきます。

こちらにフィードバックをお寄せください