Count - 차트 함수

Count() 는 각 차트 차원의 값, 텍스트 및 숫자의 수를 집계하는 데 사용됩니다.

구문:

Count({[SetExpression] [DISTINCT] [TOTAL [<fld {,fld}>]]} expr)

반환 데이터 유형: 정수

인수
인수	설명
expr	측정할 데이터가 포함된 표현식 또는 필드입니다.
SetExpression	기본적으로 집계 함수는 선택에 의해 정의된 사용 가능한 레코드의 집합을 집계합니다. 집합 분석 표현식으로 대체 레코드 집합을 정의할 수 있습니다.
DISTINCT	함수 인수 앞에 DISTINCT라는 단어가 있을 경우 해당 함수 인수의 평가 결과로 생성된 중복이 무시됩니다.
TOTAL	TOTAL이 함수 인수 앞에 오는 경우, 현재 선택을 고려하되 현재 차원 값에 관련되지 않은 가능한 모든 값에 대한 계산이 실행됩니다. 즉, 차트 차원은 무시됩니다. TOTAL [<fld {.fld}>](여기서 TOTAL 한정자 뒤에는 하나 이상의 필드 이름 목록이 차트 차원 변수의 하위 집합으로 옴)을 사용하여 가능한 전체 값의 하위 집합을 만듭니다. 집계 범위 정의

예: 차트 표현식
예	결과
Count(OrderNumber)	OrderNumber에 대한 값을 가질 수 있는 행의 수를 반환합니다. 비어있는 레코드를 포함한 모든 레코드가 계산됩니다. 정보 메모"0"은 빈 셀이 아니라 하나의 값으로 계산됩니다. 그러나 측정값이 차원에 대해 0으로 집계되는 경우 해당 차원은 차트에 포함되지 않습니다.
Count(Customer)	모든 행에서 발생하는 횟수를 평가합니다.
Count(DISTINCT [Customer])	DISTINCT 한정자는 Count가 고유한 발생만 평가하도록 제한합니다.
Count(OrderNumber)/Count({1} TOTAL OrderNumber)	이 표현식은 모든 고객의 주문 중 선택한 고객의 주문 수를 백분율로 반환합니다.
Count(TOTAL <Product> OrderNumber)	선택한 고객의 제품에 대한 주문 수만 반환합니다. 비어 있는 셀도 계산됩니다.

예 - Count 기본 사항

개요

데이터 로드 편집기를 열고 아래의 로드 스크립트를 새 탭에 추가합니다.

로드 스크립트에는 다음이 포함됩니다.

Example이라는 데이터 테이블에 로드되는 데이터 집합입니다.
데이터 테이블의 필드는 다음과 같습니다.
- Customer
- Product
- OrderNumber
- UnitSales
- UnitPrice

로드 스크립트

Example:
LOAD * inline [
Customer|Product|OrderNumber|UnitSales|UnitPrice
Astrida|AA|1|4|16
Astrida|AA|7|10|15
Astrida|BB|4|9|9
Betacab|CC|6|5|10
Betacab|AA|5|2|20
Betacab|BB|1|25| 25
Canutility|AA|3|8|15
Canutility|CC|||19
Divadip|CC|2|4|16
Divadip|DD|3|1|25
](delimiter is '|');

결과

데이터를 로드하고 시트를 엽니다. 새 테이블을 만들고 이 필드를 차원으로 추가합니다.

Customer

다음 측정값을 만듭니다.

=Count(OrderNumber): 주문 수를 계산합니다.
=Count(Customer): 고객 레코드 수를 계산합니다.
=Count(DISTINCT Customer): 고유 고객 수를 계산합니다.
=Count(OrderNumber)/Count({1} TOTAL OrderNumber): 선택된 고객 주문의 비율을 전체 고객 주문의 비율로 계산합니다.
=Count(TOTAL <Product> OrderNumber): 선택된 고객의 제품에 대한 주문 수만 계산합니다(빈 셀도 계산됨).

Results table
Customer	Count(OrderNumber)	Count(Customer)	Count(DISTINCT Customer)	Count(OrderNumber)/Count({1} TOTAL OrderNumber)	Count(TOTAL <Product> OrderNumber)
Totals	10	10	4	1	10
Astrida	3	3	1	0.3	10
Betacab	3	3	1	0.3	10
Canutility	2	2	1	0.2	10
Divadip	2	2	1	0.2	10

결과를 살펴보면 다음을 확인할 수 있습니다.

첫 번째 측정값: 데이터 집합에 10개의 주문 레코드가 있습니다.
두 번째 측정값: 데이터 집합에 10개의 고객 레코드가 있습니다.
세 번째 측정값: 데이터 집합에 4개의 고유한 고객이 있습니다.
네 번째 측정값: 선택 항목이 적용되지 않았으므로 1을 반환합니다. 고객 Canutility를 선택하면 데이터 집합에 있는 총 10개 레코드 중 이 고객에 대한 주문 레코드가 2개이므로 값이 0.2로 변경됩니다.
다섯 번째 측정값: 선택 항목이 적용되지 않았으므로 10을 반환합니다. Astrida 및 Canutility 고객을 선택하면 해당 고객의 제품에 대한 주문 수가 5로 변경됩니다(빈 셀도 계산됨).

예 - Count를 사용하여 제품당 판매 수 찾기

개요

데이터 집합에는 매장 판매량에 대한 데이터가 포함되어 있습니다. 제품당 판매 수를 알아보려고 합니다.

데이터 로드 편집기를 열고 아래의 로드 스크립트를 새 탭에 추가합니다.

로드 스크립트에는 다음이 포함됩니다.

Example이라는 데이터 테이블에 로드되는 데이터 집합입니다.
데이터 테이블의 필드는 다음과 같습니다.
- Product
- Sales
- Region
- Status

로드 스크립트

Example:
Load * inline [
Product,Sales,Region,Status
Apple, 100, North, Completed
Banana, 80, South, Pending
Carrot, 50, East, Completed
Apple, 120, North, Completed
Banana, 90, South, Completed
Carrot, 60, West, Pending
Apple, 110, North, Completed
Banana, 85, South, Completed
Carrot, 55, East, Pending
];

결과

데이터를 로드하고 시트를 엽니다. 새 테이블을 만들고 이 필드를 차원으로 추가합니다.

Product

다음 측정값을 만듭니다.

=Count(Sales): 제품당 판매 수를 계산합니다.
=Count({<Status={'Completed'}>} Sales): 완료된 주문이 있는 판매 수를 계산합니다.
=Count({<Status={'Pending'}>} Sales): 주문이 보류 중인 판매 수를 계산합니다.
=Count({<Region={'North'}>} Sales): North 지역의 주문 수를 계산합니다.

Results table
Product	Count(Sales)	Count({<Status={'Completed'}>} Sales)	Count({<Status={'Pending'}>} Sales)	Count({<Region={'North'}>} Sales)
Totals	9	6	3	3
Apple	3	3	0	3
Banana	3	2	1	0
Carrot	3	1	2	0

Count 함수의 출력은 제품별 총 판매 주문 수, 완료된 주문 수, 보류 중인 주문 수에 대한 분할을 반환합니다. 마지막 측정값은 North 지역의 판매 레코드 수를 반환합니다.

이 페이지가 도움이 되었습니까?

이 페이지 또는 해당 콘텐츠에서 오타, 누락된 단계 또는 기술적 오류와 같은 문제를 발견하면 개선 방법을 알려 주십시오!

여기에 피드백을 남겨주십시오.