maketime - 스크립트 및 차트 함수

개요

데이터 로드 편집기를 열고 새 섹션에 아래 로드 스크립트를 추가합니다.

로드 스크립트에는 다음이 포함됩니다.

• Transactions라는 테이블에 로드되는 트랜잭션 집합이 포함된 데이터 집합.

• 3개 필드에 걸쳐 제공되는 트랜잭션 시간: hours, minutes 및 seconds.

• TimeFormat 시스템 변수 서식으로 시간을 반환하는 transaction_time 필드 만들기.

로드 스크립트

SET TimeFormat='h:mm:ss TT';

Transactions:
    Load
        *,
        maketime(transaction_hour, transaction_minute, transaction_second) as transaction_time
        ; 
Load * Inline [
transaction_id, transaction_hour, transaction_minute, transaction_second, transaction_amount, transaction_quantity, customer_id
3750, 18, 43, 30, 12423.56, 23, 2038593
3751, 6, 32, 07, 5356.31, 6, 203521
3752, 12, 09, 16, 15.75, 1, 5646471
3753, 21, 43, 41, 7, 3036491
3754, 17, 55, 22, 21484.21, 1356, 049681
3756, 2, 52, 22, -59.18, 2, 2038593
3757, 9, 25, 23, 3177.4, 21, 203521
];

결과

데이터를 로드하고 시트를 엽니다. 새 테이블을 만들고 다음 필드를 차원으로 추가합니다.

• transaction_hour

• transaction_minute

• transaction_second

• transaction_time

transaction_time 필드는 maketime() 함수를 사용하고 시, 분 및 초 필드를 함수 인수로 전달하여 선행 LOAD 문에서 만들어집니다.

그런 다음 함수는 이러한 값을 결합하고 시간 필드로 변환하여 TimeFormat 시스템 변수의 시간 서식으로 결과를 반환합니다.

개요

데이터 로드 편집기를 열고 새 섹션에 아래 로드 스크립트를 추가합니다.

로드 스크립트에는 다음이 포함됩니다.

• 첫 번째 예와 동일한 데이터 집합 및 시나리오.

• TimeFormat 시스템 변수를 수정하지 않고 결과를 24시간 서식으로 표시하도록 하는 필드 transaction_time 만들기.

로드 스크립트

SET TimeFormat='h:mm:ss TT';

Transactions:
    Load
        *,
        time(maketime(transaction_hour, transaction_minute, transaction_second),'h:mm:ss') as transaction_time
        ; 
Load * Inline [
transaction_id, transaction_hour, transaction_minute, transaction_second, transaction_amount, transaction_quantity, customer_id
3750, 18, 43, 30, 12423.56, 23, 2038593
3751, 6, 32, 07, 5356.31, 6, 203521
3752, 12, 09, 16, 15.75, 1, 5646471
3753, 21, 43, 41, 7, 3036491
3754, 17, 55, 22, 21484.21, 1356, 049681
3756, 2, 52, 22, -59.18, 2, 2038593
3757, 9, 25, 23, 3177.4, 21, 203521
];

결과

데이터를 로드하고 시트를 엽니다. 새 테이블을 만들고 다음 필드를 차원으로 추가합니다.

• transaction_hour

• transaction_minute

• transaction_second

• transaction_time

이 경우 maketime() 함수는 time() 함수 내부에 중첩됩니다. time() 함수의 두 번째 인수는 maketime() 함수 결과의 서식을 필수 h:mm:ss로 설정합니다.

개요

데이터 로드 편집기를 열고 새 섹션에 아래 로드 스크립트를 추가합니다.

로드 스크립트에는 다음이 포함됩니다.

• Transactions라는 테이블에 로드되는 트랜잭션 집합이 포함된 데이터 집합.

• 두 필드에 걸쳐 제공되는 트랜잭션 시간: hours 및 minutes.

• TimeFormat 시스템 변수 서식으로 시간을 반환하는 필드 transaction_time 만들기.

h:mm:ss TT 서식으로 시간을 반환하는 차트 개체 측정값 transaction_time을 만듭니다.

로드 스크립트

SET TimeFormat='h:mm:ss TT';

Transactions:
Load * Inline [
transaction_id, transaction_hour, transaction_minute, transaction_amount, transaction_quantity, customer_id
3750, 18, 43, 12423.56, 23, 2038593
3751, 6, 32, 5356.31, 6, 203521
3752, 12, 09, 15.75, 1, 5646471
3753, 21, 43, 7, 3036491
3754, 17, 55, 21484.21, 1356, 049681
3756, 2, 52, -59.18, 2, 2038593
3757, 9, 25, 3177.4, 21, 203521
];

결과

데이터를 로드하고 시트를 엽니다. 새 테이블을 만들고 다음 필드를 차원으로 추가합니다.

• transaction_hour

• transaction_minute

transaction_time을 계산하려면 다음 측정값을 만듭니다.

=maketime(transaction_hour,transaction_minute)

transaction_time 측정값은 maketime() 함수를 사용하고 시간 및 분 필드를 함수 인수로 전달하여 차트 개체에서 만들어집니다.

그런 다음 이 함수는 이러한 값을 결합하고 초는 00으로 가정합니다. 이러한 값은 시간 필드로 변환되어 TimeFormat 시스템 변수 형식으로 결과를 반환합니다.

개요

2022년 1월의 캘린더 데이터 집합을 8시간 단위로 나누어 만듭니다.

로드 스크립트

SET TimestampFormat='M/D/YYYY h:mm:ss[.fff] TT';

tmpCalendar:
	load 
		*
    where year(date)=2022;
load
	date(recno()+makedate(2021,12,31)) as date
AutoGenerate 31;

Left join(tmpCalendar)
load
	maketime((recno()-1)*8,00,00) as time
autogenerate 3;

Calendar:
load
	timestamp(date + time) as timestamp
resident tmpCalendar;

drop table tmpCalendar;

결과

초기 autogenerate 함수는 tmpCalendar라는 테이블에 1월의 모든 날짜를 포함하는 캘린더를 만듭니다.

세 개의 레코드가 포함된 두 번째 테이블이 만들어집니다. 각 레코드에 대해 recno() – 1을 수행한 결과(값 0, 1, 2)에 8을 곱합니다. 결과적으로 값 0, 8 16이 생성됩니다. 이러한 값은 분 및 초 값이 0인 maketime() 함수에서 시간 매개 변수로 사용됩니다. 결과적으로 테이블에는 오전 12:00:00, 오전 8:00:00 및 오후 4:00:00의 세 가지 시간 필드가 포함됩니다.

이 테이블은 tmpCalendar 테이블에 조인됩니다. 이 조인의 경우 두 테이블 간에 일치하는 필드가 없으므로 시간 행이 각 날짜 행에 추가됩니다. 결과적으로 각 날짜 행은 이제 각 시간 값으로 세 번 반복됩니다.

마지막으로 tmpCalendar 테이블의 Resident LOAD에서 Calendar 테이블이 만들어집니다. 날짜 및 시간 필드는 연결되고 timestamp() 함수로 래핑되어 타임스탬프 필드를 만듭니다.

그런 다음 tmpCalendar 테이블이 삭제됩니다.