Set-modifierare med dollarteckenexpansioner

Dollarteckenexpansioner är konstruktioner som beräknas innan uttrycket tolkats och utvärderats. Resultatet matas sedan in i uttrycket istället för $(…). Beräkningen av uttrycket görs sedan med hjälp av resultatet av dollarexpansionen.

Uttrycksredigeraren visar en förhandsgranskning av dollarexpansionen så att du kan bekräfta vad din dollarteckenexpansion utvärderas till.

Använd dollarteckensexpansioner när du vill använda en beräkning i din elementuppsättning.

Om du till exempel endast vill titta på det sista möjliga året kan du använda följande konstruktion:

<Year = {$(=Max(Year))}>

Max(Year) beräknas först och resultatet matas in i uttrycket istället för $(…).

Resultatet efter dollarexpansionen kommer att vara ett uttryck som detta:

<Year = {2021}>

Uttrycket i dollarteckenexpansionen beräknas baserat på det aktuella urvalet. Det betyder att om du har ett urval i ett annat fält kommer resultatet av uttrycket att påverkas.

Om du vill att beräkningen ska vara fristående från urvalet kan du använda set-analysen i dollarexpansionen. Exempel:

<Year = {$(=Max({1} Year))}>

Strängar

När du vill att dollarexpansionen ska resultera i en sträng gäller normala citatregler. Exempel:

<Country = {'$(=FirstSortedValue(Country,Date)'}>

Resultatet efter dollarexpansionen kommer att vara ett uttryck som detta:

<Country = {'New Zealand'}>

Du kommer att få ett syntaxfel om du inte använder citattecken.

Siffror

När du vill att dollarexpansionen ska resultera i en siffra ska du se till att expansionen får samma formatering som fältet. Det betyder att du ibland behöver radbryta uttrycket i en formateringsfunktion.

Exempel:

<Amount = {$(=Num(Max(Amount), '###0.00'))}>

Resultatet efter dollarexpansionen kommer att vara ett uttryck som detta:

<Amount = {12362.00}>

Använd en hash för att tvinga expansionen att alltid använda decimalkomma och ingen tusentalsavgränsare. Exempel:

<Amount = {$(#=Max(Amount))}>

Datum

Om du vill att dollarexpansionen ska resultera i ett datum ska du se till att expansionen har korrekt formatering. Det betyder att du ibland behöver radbryta uttrycket i en formateringsfunktion.

Exempel:

<Date = {'$(=Date(Max(Date)))'}>

Resultatet efter dollarexpansionen kommer att vara ett uttryck som detta:

<Date = {'12/31/2015'}>

Precis som för strängar behöver du använda korrekta citattecken.

Ett vanligt exempel kan vara när du vill att beräkningen ska vara begränsad till den senaste månaden (eller året). Då kan du använda en numerisk sökning i kombination med funktionen AddMonths().

Exempel:

<Date = {">=$(=AddMonths(Today(),-1))"}>

Resultatet efter dollarexpansionen kommer att vara ett uttryck som detta:

<Date = {">=9/31/2021"}>

Det kommer att välja ut alla händelser som inträffat under den senaste månaden.

Exempel: diagramuttryck för set-modifierare med dollarteckenexpansioner

Exempel – diagramuttryck

Laddningsskript

Ladda följande data som en inline-laddning i Skriptredigeraren för att skapa diagramuttrycksexemplen nedan.

Let vToday = Today();
MyTable:
Load 
Year(Date) as Year,
Date#(Date,'YYYY-MM-DD') as ISO_Date, 
Date(Date#(Date,'YYYY-MM-DD'),'M/D/YYYY') as US_Date, 
Country, Product, Amount 
Inline
[Date, Country, Product, Amount
2018-02-20, Canada, Washer, 6
2018-07-08, Germany, Anchor bolt, 10
2018-07-14, Germany, Anchor bolt, 3
2018-08-31, France, Nut, 2
2018-09-02, Czech Republic, Bolt, 1
2019-02-11, Czech Republic, Bolt, 3
2019-07-31, Czech Republic, Washer, 6
2020-03-13, France, Anchor bolt, 1
2020-07-12, Canada, Anchor bolt, 8
2021-10-15, France, Washer, 1];	

Mer information om hur du använder inline-laddningar finns i Använda inline-laddningar för att ladda data.

Diagramuttryck med dollarteckenexpansioner

Skapa en tabell i ett Qlik Sense-ark med följande diagramuttryck.

Tabell – set-modifierare med dollarteckenexpansioner

Land	Sum (Amount)	Sum({<US_Date={'$(vToday)'}>} Amount)	Sum({<ISO_Date={"$(=Date(Min(ISO_Date),'YYYY-MM-DD'))"}>} Amount)	Sum({<US_Date={">=$(=AddYears(Max(US_Date),-1))"}>} Amount)
Totalvärden	41	1	6	1
Kanada	14	0	6	0
Tjeckien	10	0	0	0
Frankrike	4	1	0	1
Tyskland	13	0	0	0

Förklaring

• Dimensioner:

  • Country

• Mått:

  • Sum(Amount)

    Summan Amount utan set-uttryck.

  • Sum({<US_Date={'$(vToday)'}>}Amount)

    Summan Amount för alla poster där US_Date är samma som i variabeln vToday.

  • Sum({<ISO_Date={"$(=Date(Min(ISO_Date),'YYYY-MM-DD'))"}>}Amount)

    Summan Amount för alla poster där ISO_Date är samma som den första (minsta) möjliga ISO_Date. Funktionen Date() behövs för att se till att formatet för datumet matchar fältets.

  • Sum({<US_Date={">=$(=AddYears(Max(US_Date),-1))"}>}Amount)

    Summan Amount för alla poster som har ett US_Date som är lika med eller kommer efter datumet ett år före det senaste (högsta) möjliga US_Date. Funktionen AddYears() kommer att returnera ett datum i formatet som anges av variabeln DateFormat och det behöver matcha formatet för fältet US_Date.

Mer information om uttryck finns i Använda uttryck i visualiseringar.