달러 기호 확장은 표현식이 구문 분석 및 평가되기 전에 계산되는 구문입니다. 그런 다음 결과가 $(…) 대신 표현식에 주입됩니다. 그런 다음 달러 기호 확장의 결과를 사용하여 표현식을 계산합니다.
식 편집기는 달러 기호 확장 미리보기를 표시하므로 달러 기호 확장이 무엇을 평가하는지 확인할 수 있습니다.
식 편집기의 달러 기호 확장 미리보기
요소 집합 내에서 계산을 사용하려면 달러 기호 확장을 사용합니다.
예를 들어, 가능한 마지막 연도만 보고 싶다면 다음 구성을 사용할 수 있습니다.
<Year = {$(=Max(Year))}>
Max(Year)가 먼저 계산되고 결과가 $(…) 대신 표현식에 주입됩니다.
달러 확장 후의 결과는 다음과 같은 표현식이 됩니다.
<Year = {2021}>
달러 기호 확장 안의 표현식은 현재 선택을 기반으로 계산됩니다. 즉, 다른 필드에 선택 내용이 있는 경우 표현식의 결과가 영향을 받습니다.
계산이 선택과 무관하게 하려면 달러 기호 확장 내에서 집합 분석을 사용합니다. 예:
<Year = {$(=Max({1} Year))}>
문자열
달러 기호 확장으로 인해 문자열이 생성되도록 하려면 일반적인 인용 규칙이 적용됩니다. 예:
<Country = {'$(=FirstSortedValue(Country,Date)'}>
달러 확장 후의 결과는 다음과 같은 표현식이 됩니다.
<Country = {'New Zealand'}>
인용 부호를 사용하지 않으면 구문 오류가 발생합니다.
숫자
달러 기호 확장으로 인해 숫자가 표시되도록 하려면 확장이 필드와 동일한 형식을 가져야 합니다. 즉, 서식 지정 함수에서 표현식을 래핑해야 하는 경우가 있습니다.
예:
<Amount = {$(=Num(Max(Amount), '###0.00'))}>
달러 확장 후의 결과는 다음과 같은 표현식이 됩니다.
<Amount = {12362.00}>
해시를 사용하여 확장이 항상 소수점을 사용하고 천 단위 구분 기호를 사용하지 않도록 합니다. 예:
<Amount = {$(#=Max(Amount))}>
날짜
달러 기호 확장으로 인해 날짜가 표시되도록 하려면 확장이 올바른 형식이어야 합니다. 즉, 서식 지정 함수에서 표현식을 래핑해야 하는 경우가 있습니다.
예:
<Date = {'$(=Date(Max(Date)))'}>
달러 확장 후의 결과는 다음과 같은 표현식이 됩니다.
<Date = {'12/31/2015'}>
문자열과 마찬가지로 올바른 따옴표를 사용해야 합니다.
일반적인 사용 사례는 계산을 지난 달(또는 연도)로 제한하려는 것입니다. 그런 다음 AddMonths() 함수와 함께 숫자 검색을 사용할 수 있습니다.
예:
<Date = {">=$(=AddMonths(Today(),-1))"}>
달러 확장 후의 결과는 다음과 같은 표현식이 됩니다.
<Date = {">=9/31/2021"}>
이 함수는 지난 달에 발생한 모든 이벤트를 선택합니다.
예: 달러 기호 확장이 포함된 집합 수정자의 차트 표현식
로드 스크립트
데이터 로드 편집기에서 다음 데이터를 인라인 로드로 로드하여 아래 차트 표현식 예를 만듭니다.
Let vToday = Today();
MyTable:
Load
Year(Date) as Year,
Date#(Date,'YYYY-MM-DD') as ISO_Date,
Date(Date#(Date,'YYYY-MM-DD'),'M/D/YYYY') as US_Date,
Country, Product, Amount
Inline
[Date, Country, Product, Amount
2018-02-20, Canada, Washer, 6
2018-07-08, Germany, Anchor bolt, 10
2018-07-14, Germany, Anchor bolt, 3
2018-08-31, France, Nut, 2
2018-09-02, Czech Republic, Bolt, 1
2019-02-11, Czech Republic, Bolt, 3
2019-07-31, Czech Republic, Washer, 6
2020-03-13, France, Anchor bolt, 1
2020-07-12, Canada, Anchor bolt, 8
2021-10-15, France, Washer, 1]; 인라인 로드 사용에 대한 자세한 내용은 인라인 로드를 사용하여 데이터 로드를 참조하십시오.
달러 기호 확장을 사용하는 차트 표현식
다음 차트 표현식을 사용하여 Qlik Sense 시트에 테이블을 만듭니다.
| 국가 | Sum(Amount) | Sum({<US_Date={'$(vToday)'}>} Amount) | Sum({<ISO_Date={"$(=Date(Min(ISO_Date),'YYYY-MM-DD'))"}>} Amount) | Sum({<US_Date={">=$(=AddYears(Max(US_Date),-1))"}>} Amount) |
|---|---|---|---|---|
| 합계 | 41 | 1 | 6 | 1 |
| 캐나다 | 14 | 0 | 6 | 0 |
| 체코 공화국 | 10 | 0 | 0 | 0 |
| 프랑스 | 4 | 1 | 0 | 1 |
| 독일 | 13 | 0 | 0 | 0 |
설명
-
차원:
-
Country
-
-
측정값:
-
Sum(Amount)
집합 표현식 없는 합계 Amount입니다.
-
Sum({<US_Date={'$(vToday)'}>}Amount)
Amount가 US_Date 변수vToday와 동일한 모든 레코드의 합계입니다.
-
Sum({<ISO_Date={"$(=Date(Min(ISO_Date),'YYYY-MM-DD'))"}>}Amount)
ISO_Date가 첫 번째(가장 작은) 가능한 ISO_Date와 동일한 모든 레코드의 합계 Amount입니다. 날짜 형식이 필드 형식과 일치하도록 하려면 Date() 함수가 필요합니다.
-
Sum({<US_Date={">=$(=AddYears(Max(US_Date),-1))"}>}Amount)
마지막(가장 큰) 가능한 US_Date의 1년 전 날짜 또는 그 이후에 US_Date가 있는 모든 레코드의 합계 Amount입니다. AddYears() 함수는 변수 DateFormat에 지정된 형식으로 날짜를 반환하며 이는 필드 US_Date 형식과 일치해야 합니다.
-
달러 기호 확장을 사용하는 집합 수정자
집합 표현식에 대한 자세한 내용은 시각화에서 표현식 사용을 참조하십시오.
| 예 | 결과 |
|---|---|
| sum( {$<Year = {$(#vLastYear)}>} Sales ) |
현재 선택을 기준으로 이전 연도의 판매량을 반환합니다. 여기에서 관련 연도를 포함하는 vLastYear 변수는 달러 기호 확장에 사용됩니다. |
| sum( {$<Year = {$(#=Only(Year)-1)}>} Sales ) |
현재 선택을 기준으로 이전 연도의 판매량을 반환합니다. 여기에서 달러 기호 확장은 이전 연도를 계산하는 데 사용합니다. |