Modifikatoren mit Dollarzeichen

Dollarzeichen-Erweiterungen sind Konstrukte, die berechnet werden, bevor die Formel analysiert und ausgewertet wird. Das Ergebnis wird dann anstelle von $(…) in die Formel eingefügt. Die Berechnung der Formel erfolgt dann mit dem Ergebnis der Dollarzeichen-Erweiterung.

Der Formel-Editor zeigt eine Variablenvorschau mit Dollarzeichen-Erweiterung, damit Sie prüfen können, welches Ergebnis Ihre Dollarzeichen-Erweiterung zurückgibt.

Verwenden Sie Dollarzeichen-Erweiterungen, wenn Sie eine Berechnung innerhalb Ihres Elementsatzes verwenden möchten.

Wenn Sie beispielsweise nur das letzte mögliche Jahr betrachten möchten, können Sie folgende Konstruktion verwenden:

<Year = {$(=Max(Year))}>

Max(Year) wird zuerst berechnet, und das Ergebnis wird anstelle von $(…) in die Formel eingefügt.

Das Ergebnis nach der Dollarzeichenerweiterung ist eine Formel wie die folgende:

<Year = {2021}>

Die Formel innerhalb der Dollarzeichen-Erweiterung wird basierend auf der aktuellen Auswahl berechnet. Das bedeutet, dass sich eine Auswahl in einem anderen Feld auf das Ergebnis der Formel auswirkt.

Wenn die Berechnung unabhängig von der Auswahl sein soll, verwenden Sie eine Aggregierung mit Auswahlformeln innerhalb der Dollarzeichen-Erweiterung. Hier ein Beispiel:

<Year = {$(=Max({1} Year))}>

Zeichenfolgen

Wenn das Ergebnis der Dollarzeichen-Erweiterung eine Zeichenfolge sein soll, gelten normale Regeln für Anführungszeichen. Hier ein Beispiel:

<Country = {'$(=FirstSortedValue(Country,Date)'}>

Das Ergebnis nach der Dollarzeichenerweiterung ist eine Formel wie die folgende:

<Country = {'New Zealand'}>

Sie erhalten einen Syntaxfehler, wenn Sie die Anführungszeichen nicht verwenden.

Zahlen

Wenn das Ergebnis der Dollarzeichen-Erweiterung eine Zahl sein soll, vergewissern Sie sich, dass die Erweiterung die gleiche Formatierung wie das Feld enthält. Das bedeutet, dass die Formel manchmal von einer Formatierungsfunktion umschlossen sein muss.

Hier ein Beispiel:

<Amount = {$(=Num(Max(Amount), '###0.00'))}>

Das Ergebnis nach der Dollarzeichenerweiterung ist eine Formel wie die folgende:

<Amount = {12362.00}>

Verwenden Sie ein Hash, um zu erzwingen, dass immer der Dezimalpunkt und kein Tausendertrennzeichen verwendet wird. Hier ein Beispiel:

<Amount = {$(#=Max(Amount))}>

Datumsangaben

Wenn das Ergebnis der Dollarzeichen-Erweiterung ein Datum sein soll, vergewissern Sie sich, dass die Erweiterung die korrekte Formatierung aufweist. Das bedeutet, dass die Formel manchmal von einer Formatierungsfunktion umschlossen sein muss.

Hier ein Beispiel:

<Date = {'$(=Date(Max(Date)))'}>

Das Ergebnis nach der Dollarzeichenerweiterung ist eine Formel wie die folgende:

<Date = {'12/31/2015'}>

Wie bei Zeichenfolgen müssen Sie die richtigen Anführungszeichen verwenden.

Ein häufiger Anwendungsfall ist, dass die Berechnung auf den letzten Monat oder das letzte Jahr beschränkt sein soll. Dann können Sie eine numerische Suche in Kombination mit der Funktion AddMonths() verwenden.

Hier ein Beispiel:

<Date = {">=$(=AddMonths(Today(),-1))"}>

Das Ergebnis nach der Dollarzeichenerweiterung ist eine Formel wie die folgende:

<Date = {">=9/31/2021"}>

Damit werden alle Ereignisse herausgesucht, die im letzten Monat eingetreten sind.

Beispiel: Diagrammformeln für Modifikatoren für Auswahlformeln mit Dollarzeichen-Erweiterungen

Beispiel – Diagrammformeln

Ladeskript

Laden Sie die folgenden Daten als Inline-Ladevorgang in den Dateneditor, um die folgenden Diagrammformelbeispiele zu erstellen.

Let vToday = Today();
MyTable:
Load 
Year(Date) as Year,
Date#(Date,'YYYY-MM-DD') as ISO_Date, 
Date(Date#(Date,'YYYY-MM-DD'),'M/D/YYYY') as US_Date, 
Country, Product, Amount 
Inline
[Date, Country, Product, Amount
2018-02-20, Canada, Washer, 6
2018-07-08, Germany, Anchor bolt, 10
2018-07-14, Germany, Anchor bolt, 3
2018-08-31, France, Nut, 2
2018-09-02, Czech Republic, Bolt, 1
2019-02-11, Czech Republic, Bolt, 3
2019-07-31, Czech Republic, Washer, 6
2020-03-13, France, Anchor bolt, 1
2020-07-12, Canada, Anchor bolt, 8
2021-10-15, France, Washer, 1];	

Weitere Informationen über Inline-Ladevorgänge finden Sie unter Verwenden von Inline-Ladevorgängen zum Laden von Daten.

Diagrammformeln mit Dollarzeichen-Erweiterungen

Erstellen Sie eine Tabelle in einem Qlik Sense Arbeitsblatt mit den folgenden Diagrammformeln.

Tabelle – Modifikatoren für Auswahlformeln zum Aufrufen von Variablen (Dollarzeichen-Erweiterungen)

Land	Sum (Amount)	Sum({<US_Date={'$(vToday)'}>} Amount)	Sum({<ISO_Date={"$(=Date(Min(ISO_Date),'YYYY-MM-DD'))"}>} Amount)	Sum({<US_Date={">=$(=AddYears(Max(US_Date),-1))"}>} Amount)
Summen	41	1	6	1
Kanada	14	0	6	0
Tschechische Republik	10	0	0	0
Frankreich	4	1	0	1
Deutschland	13	0	0	0

Erläuterung

• Dimension:

  • Country

• Kennzahl:

  • Sum(Amount)

    Amount ohne Auswahlformel summieren.

  • Sum({<US_Date={'$(vToday)'}>}Amount)

    Amount für alle Datensätze summieren, bei denen das US_Date dasselbe ist wie in der Variablen vToday.

  • Sum({<ISO_Date={"$(=Date(Min(ISO_Date),'YYYY-MM-DD'))"}>}Amount)

    Amount für alle Datensätze summieren, bei denen das ISO_Date dasselbe wie das erste (früheste) mögliche ISO_Date ist. Die Funktion Date() wird benötigt, um sicherzustellen, dass das Format des Datums mit dem des Felds übereinstimmt.

  • Sum({<US_Date={">=$(=AddYears(Max(US_Date),-1))"}>}Amount)

    Amount für alle Datensätze summieren, die einen US_Date nach dem oder am Datum ein Jahr vor dem letzten (spätesten) möglichen US_Date haben. Die Funktion AddYears() gibt ein Datum in dem Format zurück, das von der Variablen DateFormat angegeben wird, und dieses muss dem Format des Felds US_Date entsprechen.

Weitere Informationen zu Formeln finden Sie unter Arbeiten mit Formeln in Visualisierungen.