Modificadores de conjunto con expansiones de signo dólar

Las expansiones de signo dólar son construcciones que se calculan antes de analizar y evaluar la expresión. A continuación, el resultado se inserta en la expresión, en lugar de la $(…). El cálculo de la expresión se realiza posteriormente utilizando el resultado de la expansión de dólar.

El editor de expresiones muestra una vista previa de la expansión de dólar para que pueda verificar qué devuelve su expansión de signo dólar.

Utilice expansiones de signo dólar cuando desee usar un cálculo dentro de su conjunto de elementos.

Por ejemplo, si desea ver únicamente el último año posible, puede usar la siguiente construcción:

<Year = {$(=Max(Year))}>

Max(Year) se calcula primero y el resultado se insertaría en la expresión en lugar de la $(…).

El resultado tras la expansión del dólar será una expresión como la siguiente:

<Year = {2021}>

La expresión dentro de la expansión del dólar se calcula en función de la selección actual. Esto significa que si tiene una selección en otro campo, el resultado de la expresión se verá afectado.

Si desea que el cálculo sea independiente de la selección, utilice el análisis de conjuntos dentro de la expansión del dólar. Por ejemplo:

<Year = {$(=Max({1} Year))}>

Cadenas de texto

Cuando desee que la expansión de dólar dé como resultado una cadena de texto, se aplican las reglas de entrecomillado normales. Por ejemplo:

<Country = {'$(=FirstSortedValue(Country,Date)'}>

El resultado tras la expansión del dólar será una expresión como la siguiente:

<Country = {'New Zealand'}>

Obtendrá un error de sintaxis si no usa las comillas.

Números

Cuando desee que la expansión de dólar dé como resultado un número, asegúrese de que la expansión tenga el mismo formato que el campo. Esto significa que a veces es necesario ajustar la expresión en una función de formato.

Por ejemplo:

<Amount = {$(=Num(Max(Amount), '###0.00'))}>

El resultado tras la expansión del dólar será una expresión como la siguiente:

<Amount = {12362.00}>

Utilice un hash para obligar a la expansión a que use siempre un punto decimal y no un separador de miles. Por ejemplo:

<Amount = {$(#=Max(Amount))}>

Fechas

Cuando desee que la expansión de dólar dé como resultado una fecha, asegúrese de que la expansión tenga el formato correcto. Esto significa que a veces es necesario ajustar la expresión en una función de formato.

Por ejemplo:

<Date = {'$(=Date(Max(Date)))'}>

El resultado tras la expansión del dólar será una expresión como la siguiente:

<Date = {'12/31/2015'}>

Al igual que con las cadenas de texto, debe utilizar las comillas correctas.

Un caso de uso muy habitual es desear que el cálculo se limite al último mes (o año). En ese caso puede usar una búsqueda numérica en combinación con la función AddMonths().

Por ejemplo:

<Date = {">=$(=AddMonths(Today(),-1))"}>

El resultado tras la expansión del dólar será una expresión como la siguiente:

<Date = {">=9/31/2021"}>

Esto seleccionará todos los eventos que ocurrieron el último mes.

Ejemplo: expresiones de gráfico para modificadores de conjunto con expansiones de signo dólar

Ejemplo: expresiones de gráfico

Script de carga

Cargue los datos siguientes como una carga inline en el editor de carga de datos para crear los ejemplos de expresión del gráfico a continuación.

Let vToday = Today();
MyTable:
Load 
Year(Date) as Year,
Date#(Date,'YYYY-MM-DD') as ISO_Date, 
Date(Date#(Date,'YYYY-MM-DD'),'M/D/YYYY') as US_Date, 
Country, Product, Amount 
Inline
[Date, Country, Product, Amount
2018-02-20, Canada, Washer, 6
2018-07-08, Germany, Anchor bolt, 10
2018-07-14, Germany, Anchor bolt, 3
2018-08-31, France, Nut, 2
2018-09-02, Czech Republic, Bolt, 1
2019-02-11, Czech Republic, Bolt, 3
2019-07-31, Czech Republic, Washer, 6
2020-03-13, France, Anchor bolt, 1
2020-07-12, Canada, Anchor bolt, 8
2021-10-15, France, Washer, 1];	

Para más información sobre el uso de cargas inline, vea Usar cargas inline para cargar datos.

Expresiones de gráfico con expansiones de signo dólar

Cree una tabla en una hoja de Qlik Sense con las siguientes expresiones de gráfico.

Tabla: Modificadores de conjunto con expansiones de signo dólar

País	Sum (Amount)	Sum({<US_Date={'$(vToday)'}>} Amount)	Sum({<ISO_Date={"$(=Date(Min(ISO_Date),'YYYY-MM-DD'))"}>} Amount)	Sum({<US_Date={">=$(=AddYears(Max(US_Date),-1))"}>} Amount)
Totales	41	1	6	1
Canadá	14	0	6	0
República Checa	10	0	0	0
Francia	4	1	0	1
Alemania	13	0	0	0

Explicación

• Dimensiones:

  • Country

• Medidas:

  • Sum(Amount)

    Suma de Amount sin una expresión de conjunto.

  • Sum({<US_Date={'$(vToday)'}>}Amount)

    Sum Amount para todos los registros en los que la US_Date es la misma que en la variable vToday.

  • Sum({<ISO_Date={"$(=Date(Min(ISO_Date),'YYYY-MM-DD'))"}>}Amount)

    Sum Amount para todos los registros en los que la ISO_Date es la misma que la primera ISO_Date posible (más pequeña). La función Date() es necesaria para garantizar que el formato de la fecha coincida con el del campo.

  • Sum({<US_Date={">=$(=AddYears(Max(US_Date),-1))"}>}Amount)

    Sum Amount para todos los registros que tienen una US_Date después o en la misma fecha de un año antes que la última US_Date posible (mayor). La función AddYears() devolverá una fecha en el formato especificado por la variable DateFormat y este debe coincidir con el formato del campo US_Date.

Para obtener más información sobre las expresiones, vea Utilizar expresiones en las visualizaciones.