if - función de script y de gráfico

La función if devuelve un valor dependiendo de si la condición proporcionada con la función se evalúa como True o False.

Sintaxis:

if(condition , then [, else])

Algunos de los ejemplos de este tema utilizan cargas inline. Para más información, vea Cargas inline .

Argumentos
Argumento	Descripción
condition	La expresión que se interpreta de una manera lógica.
then	La expresión que puede ser de cualquier tipo. Si la condition es True, entonces la función if devuelve el valor de la expresión then.
else	La expresión que puede ser de cualquier tipo. Si la condition es False, entonces la función if devuelve el valor de la expresión else. Este parámetro es opcional. Si la condition es False, devuelve NULL si no ha especificado else.

Ejemplo
Ejemplo	Resultado
if( Amount>= 0, 'OK', 'Alarm' )	Esta expresión comprueba si la cantidad es un número positivo (0 o mayor) y devuelve 'OK' si lo es. Si la cantidad es inferior a 0, devuelve 'Alarm'.

Ejemplo: cargar script usando if

Script de carga

If se puede utilizar en el script de carga con otros métodos y objetos, incluidas las variables. Por ejemplo, si define una variable umbral threshold y desea incluir un campo en el modelo de datos basado en ese umbral, puede hacer lo siguiente:

Cree una nueva pestaña en el editor de carga de datos y luego cargue los siguientes datos como una carga inline. Cree la tabla siguiente en Qlik Sense para ver los resultados.

Transactions:
Load * Inline [
transaction_id, transaction_date, transaction_amount, transaction_quantity, customer_id, size, color_code
3750, 20180830, 23.56, 2, 2038593, L, Red
3751, 20180907, 556.31, 6, 203521, m, orange
3752, 20180916, 5.75, 1, 5646471, S, blue
3753, 20180922, 125.00, 7, 3036491, l, Black
3754, 20180922, 484.21, 13, 049681, xs, Red
3756, 20180922, 59.18, 2, 2038593, M, Blue
3757, 20180923, 177.42, 21, 203521, XL, Black
];
 
set threshold = 100;
					
/* Create new table called Transaction_Buckets 
Compare transaction_amount field from Transaction table to threshold of 100.
Output results into a new field called Compared to Threshold							
 */					
 
Transaction_Buckets:
Load
   transaction_id,
   If(transaction_amount > $(threshold),'Greater than $(threshold)','Less than $(threshold)') as [Compared to Threshold]
Resident Transactions;

Resultados

Tabla de Qlik Sense que muestra el resultado de usar la función if en el script de carga.
id_transacción	Comparado con umbral
3750	Menor que 100
3751	Mayor que 100
3752	Menor que 100
3753	Mayor que 100
3754	Mayor que 100
3756	Menor que 100
3757	Mayor que 100

Ejemplos: expresiones de gráfico usando if

Expresión de gráfico 1

Script de carga

Cree una nueva pestaña en el editor de carga de datos y luego cargue los siguientes datos como una carga inline. Después de cargar los datos, cree los ejemplos de la expresión de gráfico a continuación en una tabla de Qlik Sense.

MyTable:
LOAD * inline [Date, Location, Incidents
1/3/2016, Beijing, 0
1/3/2016, Boston, 12
1/3/2016, Stockholm, 3
1/3/2016, Toronto, 0
1/4/2016, Beijing, 0
1/4/2016, Boston, 8];

Tabla de Qlik Sense con ejemplos de la función if en una expresión de gráfico.
Fecha	Localización	Incidentes	if(Incidentes>=10, 'Critical', 'Ok' )	if(Incidentes>=10, 'Critical', If( Incidentes>=1 and Incidentes<10, 'Advertencia', 'Ok'))
1/3/2016	Pekín	0	Ok	Ok
1/3/2016	Boston	12	Critical	Critical
1/3/2016	Estocolmo	3	Ok	Advertencia
1/3/2016	Toronto	0	Ok	Ok
1/4/2016	Pekín	0	Ok	Ok
1/4/2016	Boston	8	Ok	Advertencia

Expresión de gráfico 2

En una nueva app, agregue el siguiente script en una nueva pestaña en el editor de carga de datos y luego cargue los datos. Después, puede crear la tabla con las expresiones de gráfico a continuación.

SET FirstWeekDay=0;
Load 
Date(MakeDate(2022)+RecNo()-1) as Date
Autogenerate 14;

Tabla Qlik Sense que muestra un ejemplo de la función if en una expresión de gráfico.
Fecha	WeekDay(Date)	If(WeekDay(Date)>=5,'WeekEnd','Normal Day')
1/1/2022	Sáb	WeekEnd
1/2/2022	Dom	WeekEnd
1/3/2022	Lun	Normal Day
1/4/2022	Mar	Normal Day
1/5/2022	Mié	Normal Day
1/6/2022	Jue	Normal Day
1/7/2022	Vie	Normal Day
1/8/2022	Sáb	WeekEnd
1/9/2022	Dom	WeekEnd
1/10/2022	Lun	Normal Day
1/11/2022	Mar	Normal Day
1/12/2022	Mié	Normal Day
1/13/2022	Jue	Normal Day
1/14/2022	Vie	Normal Day

¿Esta página le ha sido útil?

No dude en indicarnos en qué podemos mejorar si encuentra algún problema en esta página o su contenido, como, por ejemplo, errores tipográficos, pasos que falta o errores técnicos.

Deje aquí sus comentarios