Expansion $ comprenant une variable

Script de chargement

Chargez les données suivantes sous forme de chargement inline dans l'éditeur de chargement de données :

Set x = 'red';  	// Assign the value "red" to variable x
Set y = 'blue'; 	 // Assign the value "blue" to variable y
Set z = '$(x) $(y)';    // Expands x and y, returns "red blue" in variable z

// Expand x and y, return "red green blue" in variable MyString

Let MyString='$(x)'&' green '&'$(y)';

// Create table MyTable, load variable values for x, y, z into fields X, Y, Z
// Concatenate with variable MyString into field NewString

MyTable:
Load '$(x)' as X, '$(y)' as Y, '$(z)' as Z, '$(MyString)' as NewString autogenerate 1;

Pour plus d'informations sur l'utilisation des chargements inline, voir Chargements inline.

Explication

Cet exemple démontre :

• Comment développer une variable dans des affectations de variables.

• Comment développer des variables combinées avec des opérations textuelles.

Il s'agit d'une configuration utile pour créer des étiquettes dynamiques et des chaînes de texte générales qui combinent le contenu d'une variable avec des chaînes statiques.

Sortie

Créez le tableau suivant dans Qlik Sense :

Script de chargement

Chargez les données suivantes sous forme de chargement inline dans l'éditeur de chargement de données :

Set vFunction = 'upper';  // Assign the string “upper” to variable vFunction
Set vField = 'String';    // Assign the string "String" to variable vField
Let vEvaluate = '$(vFunction)'&'('&'$(vField)'&')';

// The variable vEvaluate returns the value "upper(string)"

MyTable: // Create table called MyTable
Load *, $(vEvaluate) as Upper;          // vEvaluate expanded as a dynamic expression
Load *, '$(vEvaluate)' as Expression;   // vEvaluate expanded as string
Load * inline [
ID, String
1, abc
2, def
3, ghi
4, jkl ];

Explication

Les instructions Set et Let sont utilisées pour affecter des valeurs aux variables du script de chargement. La différence entre les deux réside dans le fait que l'instruction Set affecte une chaîne à la variable, tandis que l'instruction Let évalue le contenu de la chaîne avant d'affecter la valeur obtenue à la variable. Dans cet exemple, le tableau de chargement inline est complété de deux instructions preceding load qui sont utilisées pour visualiser différentes évaluations de la variable vEvaluate sous forme de chaîne de texte et d'expression correspondante.

Sortie

Créez le tableau suivant dans Qlik Sense :

Script de chargement

Chargez les données suivantes sous forme de chargement inline dans l'éditeur de chargement de données :

// Create table SalesByCountry
SalesByCountry:
Load * Inline [
Country, Year, Sales
Argentina, 2014, 66295.03
Argentina, 2015, 140037.89
Austria, 2014, 54166.09
Austria, 2015, 182739.87
Belgium, 2014, 182766.87
Belgium, 2015, 178042.33
Brazil, 2014, 174492.67
Brazil, 2015, 2104.22
Canada, 2014, 101801.33
Canada, 2015, 40288.25
Denmark, 2014, 45273.25
Denmark, 2015, 106938.41
Finland, 2014, 107565.55
Finland, 2015, 30583.44
France, 2014, 115644.26
France, 2015, 30696.98
Germany, 2014, 8775.18
Germany, 2015, 77185.68
];

Variables

Dans une feuille en mode d'édition, ouvrez la boîte de dialogue Variables depuis le panneau des ressources.

Créez les variables suivantes :

Créez des graphiques d'indicateurs KPI pour afficher les expansions.

Script de chargement

Chargez les données suivantes sous forme de chargement inline dans l'éditeur de chargement de données :

Set DecimalSep = ',';  // Set decimal comma as separator for this example.
Let X = 7/2;           // Assign the expression 7/2 to variable X.

MyTable:   // Create an inline table labeled “MyTable”
Load 1 as ID, * inline [  
DecimalComma	DecimalPoint
$(X)	$(#X) ] 
(delimiter is '\t'); 

Explication

L'expansion #vVariable produit toujours une représentation en point décimal valide de la valeur numérique de la variable. Cela s'avère utile lorsqu'une virgule est utilisée au lieu d'un point comme séparateur décimal et qu'il existe un risque de conflit avec des listes séparées par des virgules.

La raison principale de l'expansion de ces variables dans un tableau de chargement inline réside dans le fait qu'aucun guillemet supplémentaire ne doit être ajouté à $(X).

Sortie

Créez le tableau suivant dans Qlik Sense :

Script de chargement

Chargez les données suivantes sous forme de chargement inline dans l'éditeur de chargement de données :

// The three Set statements below are required to mimic and initialize
// Format specifiers that are relevant to this particular example

Set ThousandSep=' '; 		// Set example thousand separator
Set DecimalSep=','; 		// Set example decimal separator
Set TimestampFormat='YYYY-MM-DD hh:mm:ss';	 // Set example date format
Let vRaw = today()-1/1440;  		 // Timestamp minus one minute
Let vFormat = timestamp($(#vRaw));	 // Formatted as timestamp

// Create MyTable as an inline table to expand variables as field values
						
MyTable:
Load * inline [
DecimalComma	DecimalPoint	FormattedNumber
$(vRaw)	$(#vRaw)	$(vFormat) ] (delimiter is '\t');

Explication

L'expansion #vVariable produit toujours une représentation en point décimal valide de la valeur numérique de la variable. Cela s'avère utile lorsqu'une virgule est utilisée au lieu d'un point comme séparateur décimal et qu'il existe un risque de conflit avec des listes séparées par des virgules. Il est également important de noter que la précision numérique sera affectée, car la partie décimale sera tronquée lors de l'expansion des variables sans séparateur décimal correct.

La raison principale de l'expansion de ces variables dans une table de chargement inline réside dans le fait qu'aucun guillemet supplémentaire ne doit être ajouté à $(X).

Sortie

Créez le tableau suivant dans Qlik Sense :

Script de chargement

Chargez les données suivantes sous forme de chargement inline dans l'éditeur de chargement de données :

// The three Set statements below are required to mimic and initialize
// format specifiers that are relevant to this particular example

Set ThousandSep=' '; 		// Set example thousand separator
Set DecimalSep=','; 		// Set example decimal separator
Set TimestampFormat='YYYY-MM-DD hh:mm:ss';	// Set example date format

// Assign a numerical value and a valid format specifier to vStart

Let vStart = timestamp#('2021-03-23 12:34:56','$(TimestampFormat)');

// Calculate timestamp (vStart + 3 hours) with valid decimal separator: "."

Let vStop = timestamp($(#vStart)+1/8,'YYYY-MM-DD hh:mm:ss');

// Create MyTable as an inline table to expand variables as field values

MyTable:
Load * inline [
StartTime	StopTime
$(vStart)	$(vStop) ] (delimiter is '\t');

// This is a tab delimited inline table
// Tab delimited tables are useful for avoiding conflicting list separators

Explication

L'expansion #vVariable produit toujours une représentation en point décimal valide de la valeur numérique de la variable. Cela s'avère utile lorsqu'une virgule est utilisée au lieu d'un point comme séparateur décimal et qu'il existe un risque de conflit avec des listes séparées par des virgules. Il est également important de noter que la précision numérique sera affectée, car la partie décimale sera tronquée lors de l'expansion des variables sans séparateur décimal correct.

La raison principale de l'expansion de ces variables dans une table de chargement inline réside dans le fait qu'aucun guillemet supplémentaire ne doit être ajouté à $(X).

Sortie

Créez le tableau suivant dans Qlik Sense :