Değişken kullanarak dolar işareti genişletmesi

Yükleme kodu

Aşağıdaki verileri satır içi yükleme olarak veri yükleme düzenleyicisine yükleyin:

Set x = 'red';  	// Assign the value "red" to variable x
Set y = 'blue'; 	 // Assign the value "blue" to variable y
Set z = '$(x) $(y)';    // Expands x and y, returns "red blue" in variable z

// Expand x and y, return "red green blue" in variable MyString

Let MyString='$(x)'&' green '&'$(y)';

// Create table MyTable, load variable values for x, y, z into fields X, Y, Z
// Concatenate with variable MyString into field NewString

MyTable:
Load '$(x)' as X, '$(y)' as Y, '$(z)' as Z, '$(MyString)' as NewString autogenerate 1;

Satır içi yüklemeleri kullanma hakkında daha fazla bilgi için bkz. Satır içi yüklemeler.

Açıklama

Bu örnekte şunlar gösterilmektedir:

• Değişken atamalarında değişkenlerin genişletilmesi.

• Değişkenlerin metin işlemleriyle birleştirilerek genişletilmesi.

Bu, bir değişkenin içeriğini statik dizelerle birleştiren dinamik etiketler ve genel metin dizeleri oluşturmak için yararlı bir ayarlamadır.

Çıktı

Qlik Sense içinde aşağıdaki tabloyu oluşturun:

Yükleme kodu

Aşağıdaki verileri satır içi yükleme olarak veri yükleme düzenleyicisine yükleyin:

Set vFunction = 'upper';  // Assign the string “upper” to variable vFunction
Set vField = 'String';    // Assign the string "String" to variable vField
Let vEvaluate = '$(vFunction)'&'('&'$(vField)'&')';

// The variable vEvaluate returns the value "upper(string)"

MyTable: // Create table called MyTable
Load *, $(vEvaluate) as Upper;          // vEvaluate expanded as a dynamic expression
Load *, '$(vEvaluate)' as Expression;   // vEvaluate expanded as string
Load * inline [
ID, String
1, abc
2, def
3, ghi
4, jkl ];

Açıklama

Set ve Let deyimleri, yükleme kodundaki değişkenlere değerler atamak için kullanılır. İkisi arasındaki fark, Setdeyiminin değişkene bir dize ataması, buna karşın Letdeyiminin dizenin içeriğini değerlendirdikten sonra ortaya çıkan değeri değişkene atamasıdır. Bu örnekteki yükleme satır içi tablosu, vEvaluate değişkeninin gerek metin dizesi gerekse karşılık gelen ifade olarak farklı değerlendirmelerini görselleştirmek için kullanılan iki öncelikli yükleme deyimi ile desteklenmektedir.

Çıktı

Qlik Sense içinde aşağıdaki tabloyu oluşturun:

Yükleme kodu

Aşağıdaki verileri satır içi yükleme olarak veri yükleme düzenleyicisine yükleyin:

// Create table SalesByCountry
SalesByCountry:
Load * Inline [
Country, Year, Sales
Argentina, 2014, 66295.03
Argentina, 2015, 140037.89
Austria, 2014, 54166.09
Austria, 2015, 182739.87
Belgium, 2014, 182766.87
Belgium, 2015, 178042.33
Brazil, 2014, 174492.67
Brazil, 2015, 2104.22
Canada, 2014, 101801.33
Canada, 2015, 40288.25
Denmark, 2014, 45273.25
Denmark, 2015, 106938.41
Finland, 2014, 107565.55
Finland, 2015, 30583.44
France, 2014, 115644.26
France, 2015, 30696.98
Germany, 2014, 8775.18
Germany, 2015, 77185.68
];

Değişkenler

Düzenleme modundaki bir sayfada, Varlıklar panelinden Değişkenler iletişim kutusunu açın.

Aşağıdaki değişkenleri oluşturun:

Genişletmeleri görmek için KPI grafikleri oluşturun.

Yükleme kodu

Aşağıdaki verileri satır içi yükleme olarak veri yükleme düzenleyicisine yükleyin:

Set DecimalSep = ',';  // Set decimal comma as separator for this example.
Let X = 7/2;           // Assign the expression 7/2 to variable X.

MyTable:   // Create an inline table labeled “MyTable”
Load 1 as ID, * inline [  
DecimalComma	DecimalPoint
$(X)	$(#X) ] 
(delimiter is '\t'); 

Açıklama

#vVariable genişletmesi her zaman, değişkenin sayısal değerinin geçerli bir ondalık gösterimini verir. Bu, ondalık ayırıcı olarak nokta yerine virgül kullanıldığında yararlıdır ve virgülle ayrılmış listeler ile çakışma riski yoktur.

Bir yükleme satır içi tablosundaki bu değişkenleri genişletmenin ana nedeni, $(X) değerinin ayrıca tırnak içine alınmasının gerekmemesidir.

Çıktı

Qlik Sense içinde aşağıdaki tabloyu oluşturun:

Yükleme kodu

Aşağıdaki verileri satır içi yükleme olarak veri yükleme düzenleyicisine yükleyin:

// The three Set statements below are required to mimic and initialize
// Format specifiers that are relevant to this particular example

Set ThousandSep=' '; 		// Set example thousand separator
Set DecimalSep=','; 		// Set example decimal separator
Set TimestampFormat='YYYY-MM-DD hh:mm:ss';	 // Set example date format
Let vRaw = today()-1/1440;  		 // Timestamp minus one minute
Let vFormat = timestamp($(#vRaw));	 // Formatted as timestamp

// Create MyTable as an inline table to expand variables as field values
						
MyTable:
Load * inline [
DecimalComma	DecimalPoint	FormattedNumber
$(vRaw)	$(#vRaw)	$(vFormat) ] (delimiter is '\t');

Açıklama

#vVariable genişletmesi her zaman, değişkenin sayısal değerinin geçerli bir ondalık gösterimini verir. Bu, ondalık ayırıcısı olarak nokta yerine virgül kullanıldığında yararlıdır ve virgülle ayrılmış listeler ile çakışma riski yoktur. Ayrıca, değişkenler doğru ondalık ayırıcı kullanılmadan genişletildiğinde ondalık kısmın kesilmesinden sayısal kesinliğin de etkileneceğinin akılda tutulması önemlidir.

Bir yükleme satır içi tablosundaki bu değişkenleri genişletmenin ana nedeni, $(X) değerinin ayrıca tırnak içine alınmasının gerekmemesidir.

Çıktı

Qlik Sense içinde aşağıdaki tabloyu oluşturun:

Yükleme kodu

Aşağıdaki verileri satır içi yükleme olarak veri yükleme düzenleyicisine yükleyin:

// The three Set statements below are required to mimic and initialize
// format specifiers that are relevant to this particular example

Set ThousandSep=' '; 		// Set example thousand separator
Set DecimalSep=','; 		// Set example decimal separator
Set TimestampFormat='YYYY-MM-DD hh:mm:ss';	// Set example date format

// Assign a numerical value and a valid format specifier to vStart

Let vStart = timestamp#('2021-03-23 12:34:56','$(TimestampFormat)');

// Calculate timestamp (vStart + 3 hours) with valid decimal separator: "."

Let vStop = timestamp($(#vStart)+1/8,'YYYY-MM-DD hh:mm:ss');

// Create MyTable as an inline table to expand variables as field values

MyTable:
Load * inline [
StartTime	StopTime
$(vStart)	$(vStop) ] (delimiter is '\t');

// This is a tab delimited inline table
// Tab delimited tables are useful for avoiding conflicting list separators

Açıklama

#vVariable genişletmesi her zaman, değişkenin sayısal değerinin geçerli bir ondalık gösterimini verir. Bu, ondalık ayırıcısı olarak nokta yerine virgül kullanıldığında yararlıdır ve virgülle ayrılmış listeler ile çakışma riski yoktur. Ayrıca, değişkenler doğru ondalık ayırıcı kullanılmadan genişletildiğinde ondalık kısmın kesilmesinden sayısal kesinliğin de etkileneceğinin akılda tutulması önemlidir.

Bir yükleme satır içi tablosundaki bu değişkenleri genişletmenin ana nedeni, $(X) değerinin ayrıca tırnak içine alınmasının gerekmemesidir.

Çıktı

Qlik Sense içinde aşağıdaki tabloyu oluşturun: