Manchmal müssen Sie eine Reihe von Feldwerten mit einer verschachtelten Auswahlfunktion definieren. Beispiel: Sie möchten alle Kunden auswählen, die ein spezifisches Produkt gekauft haben, ohne das Produkt auszuwählen.
In solchen Fällen verwenden Sie die Elementsatzfunktionen P() und E(). Diese geben die Elementsätze möglicher Werte bzw. ausgeschlossener Werte eines Feldes zurück. Innerhalb der Klammern können Sie das betreffende Feld und eine Auswahlformel, die den Umfang definiert, angeben. Hier ein Beispiel:
P({1<Year = {2021}>} Customer)
Damit wird der Satz Kunden zurückgegeben, die im Jahr 2021 Transaktionen hatten. Dies können Sie dann in einem Modifikator für Auswahlformeln verwenden. Hier ein Beispiel:
Sum({<Customer = P({1<Year = {2021}>} Customer)>} Amount)
Mit dieser Auswahlformel werden diese Kunden ausgewählt, aber die Auswahl wird nicht auf 2021 beschränkt.
In anderen Ausdrücken können diese Funktionen nicht eingesetzt werden:
Zudem können nur natürliche Sätze innerhalb der Elementsatzfunktionen verwendet werden. Ein natürlicher Satz bezeichnet einen Datensatz, der durch einen einfachen Auswahlvorgang definiert werden kann.
Ein durch {1-$} angegebener Satz kann beispielsweise nicht immer durch eine Auswahl definiert werden und ist somit kein natürlicher Satz. In nicht natürlichen Sätzen geben diese Funktionen unerwartete Ergebnisse zurück.
Beispiele: Diagrammformeln für Modifikatoren für Auswahlformeln mit Funktionen für Auswahlformeln
Ladeskript
Laden Sie die folgenden Daten als Inline-Ladevorgang in den Dateneditor, um die folgenden Diagrammformelbeispiele zu erstellen.
MyTable:
Load
Year(Date) as Year,
Date#(Date,'YYYY-MM-DD') as ISO_Date,
Date(Date#(Date,'YYYY-MM-DD'),'M/D/YYYY') as US_Date,
Country, Product, Amount
Inline
[Date, Country, Product, Amount
2018-02-20, Canada, Washer, 6
2018-07-08, Germany, Anchor bolt, 10
2018-07-14, Germany, Anchor bolt, 3
2018-08-31, France, Nut, 2
2018-09-02, Czech Republic, Bolt, 1
2019-02-11, Czech Republic, Bolt, 3
2019-07-31, Czech Republic, Washer, 6
2020-03-13, France, Anchor bolt, 1
2020-07-12, Canada, Anchor bolt, 8
2020-09-16, France, Washer, 1]; Weitere Informationen über Inline-Ladevorgänge finden Sie unter Inline-Ladevorgänge.
Diagrammformeln
Erstellen Sie eine Tabelle in einem Qlik Sense Arbeitsblatt mit den folgenden Diagrammformeln.
| Land | Sum(Amount) | Sum({<Country=P({<Year={2019}>}Country)>} Amount) | Sum({<Product=P({<Year={2019}>}Product)>} Amount) | Sum({<Country=E({<Product={Washer}>}Country)>} Amount) |
|---|---|---|---|---|
| Summen | 41 | 10 | 17 | 13 |
| Kanada | 14 | 0 | 6 | 0 |
| Tschechische Republik | 10 | 10 | 10 | 0 |
| Frankreich | 4 | 0 | 1 | 0 |
| Deutschland | 13 | 0 | 0 | 13 |
Erläuterung
-
Dimension:
-
Country
-
-
Kennzahl:
-
Sum(Amount)
Amount ohne Auswahlformel summieren.
-
Sum({<Country=P({<Year={2019}>} Country)>} Amount)
Amount für alle Länder summieren, die mit dem Jahr 2019 verknüpft sind. Damit wird aber die Berechnung nicht auf 2019 beschränkt.
-
Sum({<Product=P({<Year={2019}>} Product)>} Amount)
Amount für die Produkte summieren, die mit dem Jahr 2019 verknüpft sind. Damit wird aber die Berechnung nicht auf 2019 beschränkt.
-
Sum({<Country=E({<Product={Washer}>} Country)>} Amount)
Amount für alle Länder summieren, die nicht mit dem Produkt Washer verknüpft sind.
-
Modifikatoren für Auswahlformeln mit Funktionen für Auswahlformeln
Weitere Informationen zu Formeln finden Sie unter Arbeiten mit Formeln in Visualisierungen.
| Beispiele | Results |
|---|---|
| sum( {$<Customer = P({1<Product={'Shoe'}>} Customer)>} Sales ) |
Liefert den Umsatz für die aktuelle Auswahl, jedoch nur für die Kunden, die das Produkt 'Shoe' bereits gekauft haben. Die Statusfunktion P() liefert die wählbaren Werte des Felds "Kunde". Diese sind bestimmt durch die Auswahl des Werts 'Shoe' im Feld Product. |
| sum( {$<Customer = P({1<Product={'Shoe'}>})>} Sales ) |
Wie oben. Enthält das Argument der Statusfunktion keinen Feldnamen, liefert die Funktion alle wählbaren Werte der in der Auswahlformel angegebenen Felder. |
| sum( {$<Customer = P({1<Product={'Shoe'}>} Supplier)>} Sales ) |
Liefert den Umsatz für die aktuelle Auswahl, jedoch nur für die Kunden, die das Produkt 'Shoe' bereits geliefert haben. In diesem Fall ist der Kunde also auch ein Lieferant. Die Statusfunktion P() liefert die wählbaren Werte des Felds "Lieferant". Diese sind bestimmt durch die Auswahl des Werts 'Shoe' im Feld Product. Diese Lieferanten werden im Feld Customer ausgewählt. |
| sum( {$<Customer = E({1<Product={'Shoe'}>})>} Sales ) |
Liefert den Umsatz für die aktuelle Auswahl, jedoch nur für die Kunden, die das Produkt 'Shoe' noch nie gekauft haben. Die Statusfunktion E() liefert die ausgeschlossenen Werte des Felds "Kunde". Diese sind bestimmt durch die Auswahl des Werts 'Shoe' im Feld Product. |