maketime - función de script y de gráfico

Vista general

Abra el editor de carga de datos y agregue el script de carga a continuación a una nueva pestaña.

El script de carga contiene:

• Un conjunto de datos que contiene un conjunto de transacciones, que se carga en una tabla llamada Transactions.

• Horas de las transacciones, proporcionado en tres campos: hours, minutes y seconds.

• La creación de un campo, transaction_time, que devuelve la hora en el formato de la variable del sistema TimeFormat.

Script de carga

SET TimeFormat='h:mm:ss TT';

Transactions:
    Load
        *,
        maketime(transaction_hour, transaction_minute, transaction_second) as transaction_time
        ; 
Load * Inline [
transaction_id, transaction_hour, transaction_minute, transaction_second, transaction_amount, transaction_quantity, customer_id
3750, 18, 43, 30, 12423.56, 23, 2038593
3751, 6, 32, 07, 5356.31, 6, 203521
3752, 12, 09, 16, 15.75, 1, 5646471
3753, 21, 43, 41, 7, 3036491
3754, 17, 55, 22, 21484.21, 1356, 049681
3756, 2, 52, 22, -59.18, 2, 2038593
3757, 9, 25, 23, 3177.4, 21, 203521
];

Resultados

Cargue los datos y abra una hoja. Cree una nueva tabla y agregue estos campos como dimensiones:

• transaction_hour

• transaction_minute

• transaction_second

• transaction_time

El campo transaction_time se crea en la instrucción load anterior utilizando la función maketime() e indicando los campos de hora, minuto y segundo como argumentos de la función.

A continuación la función combina y convierte estos valores en un campo de hora, devolviendo los resultados en el formato de la variable del sistema TimeFormat.

Vista general

Abra el editor de carga de datos y agregue el script de carga a continuación a una nueva pestaña.

El script de carga contiene:

• Se utilizan el mismo conjunto de datos y escenario que en el primer ejemplo.

• La creación de un campo, transaction_time, que nos permitirá mostrar los resultados en el formato horario de 24 horas, sin modificar la variable del sistema TimeFormat.

Script de carga

SET TimeFormat='h:mm:ss TT';

Transactions:
    Load
        *,
        time(maketime(transaction_hour, transaction_minute, transaction_second),'h:mm:ss') as transaction_time
        ; 
Load * Inline [
transaction_id, transaction_hour, transaction_minute, transaction_second, transaction_amount, transaction_quantity, customer_id
3750, 18, 43, 30, 12423.56, 23, 2038593
3751, 6, 32, 07, 5356.31, 6, 203521
3752, 12, 09, 16, 15.75, 1, 5646471
3753, 21, 43, 41, 7, 3036491
3754, 17, 55, 22, 21484.21, 1356, 049681
3756, 2, 52, 22, -59.18, 2, 2038593
3757, 9, 25, 23, 3177.4, 21, 203521
];

Resultados

Cargue los datos y abra una hoja. Cree una nueva tabla y agregue estos campos como dimensiones:

• transaction_hour

• transaction_minute

• transaction_second

• transaction_time

En este caso, la función maketime() está anidada dentro de la función time(). El segundo argumento de la función time() establece el formato de los resultados de la función maketime() como el DD/MM/AAAA requerido h:mm:ss.

Vista general

Abra el editor de carga de datos y agregue el script de carga a continuación a una nueva pestaña.

El script de carga contiene:

• Un conjunto de datos que contiene un conjunto de transacciones, que se carga en una tabla llamada Transactions.

• Horas de las transacciones, proporcionado en dos campos: hours y minutes.

• La creación de un campo, transaction_time, que devuelve la hora en el formato de la variable del sistema TimeFormat.

Cree una medida de objeto gráfico, transaction_time, que devuelva una fecha en el formato h:mm:ss TT.

Script de carga

SET TimeFormat='h:mm:ss TT';

Transactions:
Load * Inline [
transaction_id, transaction_hour, transaction_minute, transaction_amount, transaction_quantity, customer_id
3750, 18, 43, 12423.56, 23, 2038593
3751, 6, 32, 5356.31, 6, 203521
3752, 12, 09, 15.75, 1, 5646471
3753, 21, 43, 7, 3036491
3754, 17, 55, 21484.21, 1356, 049681
3756, 2, 52, -59.18, 2, 2038593
3757, 9, 25, 3177.4, 21, 203521
];

Resultados

Cargue los datos y abra una hoja. Cree una nueva tabla y agregue estos campos como dimensiones:

• transaction_hour

• transaction_minute

Para calcular transaction_time, cree esta medida:

=maketime(transaction_hour,transaction_minute)

La medida transaction_time se crea en el objeto gráfico utilizando la función maketime() e insertando los campos de hora y minuto como argumentos de la función.

Luego, la función combina estos valores y se supone que los segundos son 00. Estos valores se convierten luego en un campo de hora, devolviendo los resultados en el formato de la variable del sistema TimeFormat.

Vista general

Cree un conjunto de datos de calendario para el mes de enero de 2022, desglosado en incrementos de ocho horas.

Script de carga

SET TimestampFormat='M/D/YYYY h:mm:ss[.fff] TT';

tmpCalendar:
	load 
		*
    where year(date)=2022;
load
	date(recno()+makedate(2021,12,31)) as date
AutoGenerate 31;

Left join(tmpCalendar)
load
	maketime((recno()-1)*8,00,00) as time
autogenerate 3;

Calendar:
load
	timestamp(date + time) as timestamp
resident tmpCalendar;

drop table tmpCalendar;

Resultados

La función autogenerate inicial crea un calendario que contiene todas las fechas de enero en una tabla llamada tmpCalendar.

Se crea una segunda tabla, que contiene tres registros. Para cada registro, se toma recno() – 1 (valores 0, 1, 2) y el resultado se multiplica por 8. Como resultado, esto genera los valores 0, 8 16. Estos valores se utilizan como parámetro de hora en una función maketime(), con valores de minutos y segundos de 0. Como resultado, la tabla contiene tres campos de hora: 12:00:00 a. m., 8:00:00 a. m. y 4:00: 00 p. m.

Esta tabla se une a la tabla tmpCalendar. Dado que no hay campos coincidentes entre las dos tablas para la combinación, las filas de hora se agregan a cada fila de fecha. Como resultado, cada fila de fecha ahora se repite tres veces con cada valor de tiempo.

Por último, la tabla Calendar se crea a partir de una carga residente de la tabla tmpCalendar. Los campos de fecha y hora se concatenan e indican en la función timestamp() para crear el campo de marca de tiempo.

Después, se elimina la tabla tmpCalendar.