Los operadores de conjuntos se utilizan para incluir, excluir o intersectar diferentes conjuntos de elementos. Combinan los diferentes métodos para definir conjuntos de elementos.
Los operadores son los mismos que los utilizados para los identificadores de conjuntos.
| Operador | Descripción |
|---|---|
| + | Unión. Esta operación binaria devuelve un conjunto compuesto por los registros o elementos que pertenecen a cualquiera de los dos operandos de conjunto. |
| - | Exclusión. Esta operación binaria devuelve un conjunto formado por los registros o elementos que pertenecen al primero, pero no al segundo, de los operandos de conjunto. Además, cuando se emplee como operador unario, devuelve el otro conjunto complementario. |
| * | Intersección. Esta operación binaria devuelve un conjunto compuesto por los registros o elementos que pertenecen a los dos operandos de conjunto. |
| / | Diferencia simétrica (XOR). Esta operación binaria devuelve un conjunto formado por los registros o elementos que pertenecen a cualquiera de los dos operandos del conjunto, pero no a ambos. |
Por ejemplo, los dos modificadores siguientes definen el mismo conjunto de valores de campo:
-
<Year = {1997, "20*"}>
-
<Year = {1997} + {"20*"}>
Ambas expresiones seleccionan 1997 y los años que empiezan por 20. En otras palabras, esta es la unión de las dos condiciones.
Los operadores de conjuntos también permiten definiciones más complejas. Por ejemplo:
<Year = {1997, "20*"} - {2000}>
Esta expresión seleccionará los mismos años que los anteriores, pero además excluirá el año 2000.
Para más información, vea Operadores de conjunto.
Ejemplos: Expresiones de gráfico para modificadores de conjuntos con operadores de conjuntos
Script de carga
Cargue los datos siguientes como una carga inline en el editor de carga de datos para crear los ejemplos de expresión del gráfico a continuación.
MyTable:
Load
Year(Date) as Year,
Date#(Date,'YYYY-MM-DD') as ISO_Date,
Date(Date#(Date,'YYYY-MM-DD'),'M/D/YYYY') as US_Date,
Country, Product, Amount
Inline
[Date, Country, Product, Amount
2018-02-20, Canada, Washer, 6
2018-07-08, Germany, Anchor bolt, 10
2018-07-14, Germany, Anchor bolt, 3
2018-08-31, France, Nut, 2
2018-09-02, Czech Republic, Bolt, 1
2019-02-11, Czech Republic, Bolt, 3
2019-07-31, Czech Republic, Washer, 6
2020-03-13, France, Anchor bolt, 1
2020-07-12, Canada, Anchor bolt, 8
2020-09-16, France, Washer, 1]; Para más información sobre el uso de cargas inline, vea Cargas inline .
Expresiones de gráfico
Cree una tabla en una hoja de Qlik Sense con las siguientes expresiones de gráfico.
| País | Sum(Amount) | Sum({<Year={">2018"}-{2020}>} Amount) | Sum({<Country=-{Germany}>} Amount) | Sum({<Country={Germany}+P({<Product={Nut}>}Country)>} Amount) |
|---|---|---|---|---|
| Totales | 41 | 9 | 28 | 17 |
| Canadá | 14 | 0 | 14 | 0 |
| República Checa | 10 | 9 | 10 | 0 |
| Francia | 4 | 0 | 4 | 4 |
| Alemania | 13 | 0 | 0 | 13 |
Explicación
-
Dimensiones:
-
Country
-
-
Medidas:
-
Sum(Amount)
Suma de Amount sin una expresión de conjunto.
-
Sum({<Year={">2018"}-{2020}>}Amount)
Sum Amount para todos los años después de 2018, excepto 2020.
-
Sum({<Country=-{Germany}>}Amount)
Sum Amount para todos los países excepto Germany. Tenga en cuenta el operador de exclusión unario.
-
Sum({<Country={Germany}+P({<Product={Nut}>}Country)>}Amount)
Sum Amount para Germany y todos los países asociados con el producto Nut.
-
Modificadores de conjunto con operadores de conjunto
Para obtener más información sobre las expresiones, vea Utilizar expresiones en las visualizaciones.
| Ejemplos | Resultados |
|---|---|
| sum( {$<Product = Product + {OurProduct1} – {OurProduct2} >} Sales ) | Devuelve las ventas de la selección actual, pero con el producto "OurProduct1" agregado a la lista de productos seleccionados y "OurProduct2" eliminado de la lista de productos seleccionados. |
| sum( {$<Year = Year + ({“20*”,1997} – {2000}) >} Sales ) |
Devuelve las ventas de la selección actual, pero con selecciones adicionales en el campo “Year”: 1997 y todos los que comienzan por "20", excepto el 2000. Observe que si se incluye 2000 en la selección actual, se incluirá todavía tras la modificación. |
| sum( {$<Year = (Year + {“20*”,1997}) – {2000} >} Sales ) |
Devuelve prácticamente lo mismo que el anterior, pero en este caso se excluirá el 2000, incluso si estuviera inicialmente incluido en la selección actual. El ejemplo muestra la importancia de utilizar en ocasiones los paréntesis, que ayudan a definir un orden de prioridad. |
| sum( {$<Year = {“*”} – {2000}, Product = {“*bearing*”} >} Sales ) |
Devuelve las ventas de la selección actual, pero con una nueva selección en "Year": todos los años excepto 2000; y solo para los productos que contienen la cadena "bearing" (rodamiento). |