Crosstable

概覽

開啟資料載入編輯器並將下面的第一個載入指令碼新增至新的索引標籤。

第一個載入指令碼包含之後將套用 crosstable 指令碼前置詞的資料集，其中套用 crosstable 的區段標記為註解。這表示註解語法已在載入指令碼中用來停用此區段。

第二個載入指令碼與第一個相同，但 crosstable 的應用程式未標記為註解 (透過移除註解語法來啟用)。指令碼以此方式顯示，以在轉換資料中醒目提示此指令碼函數的值。

第一個載入指令碼 (未套用函數)

tmpData:
//Crosstable (MonthText, Sales)
Load * inline [
Product, Jan 2021, Feb 2021, Mar 2021, Apr 2021, May 2021, Jun 2021
A, 100, 98, 103, 63, 108, 82
B, 284, 279, 297, 305, 294, 292
C, 50, 53, 50, 54, 49, 51];
 
//Final:
//Load Product,
//Date(Date#(MonthText,'MMM YYYY'),'MMM YYYY') as Month,
//Sales

//Resident tmpData;

//Drop Table tmpData;

如需更多關於使用內嵌載入的資訊，請參閱 使用內嵌載入以載入資料。

結果

載入資料並開啟工作表。建立新的表格並將這些欄位新增為維度：

• Product

• Jan 2021

• Feb 2021

• Mar 2021

• Apr 2021

• May 2021

• Jun 2021

此指令碼允許建立跨維度資料表，其中每個月份都有一欄，而每個產品都有一列。在目前格式中，此資料不容易分析。比較好的做法會是某個欄位中具備所有數字以及另一個欄位 (即三欄表格) 中具備所有月份。下一區段說明如何對跨維度資料表進行此轉換。

第二個載入指令碼 (已套用函數)

移除 // 以為指令碼取消註解。載入指令碼應如下所示：

tmpData:
Crosstable (MonthText, Sales)
Load * inline [
Product, Jan 2021, Feb 2021, Mar 2021, Apr 2021, May 2021, Jun 2021
A, 100, 98, 103, 63, 108, 82
B, 284, 279, 297, 305, 294, 292
C, 50, 53, 50, 54, 49, 51];
 
Final:
Load Product,
Date(Date#(MonthText,'MMM YYYY'),'MMM YYYY') as Month,
Sales

Resident tmpData;

Drop Table tmpData;

如需更多關於使用內嵌載入的資訊，請參閱 使用內嵌載入以載入資料。

結果

載入資料並開啟工作表。建立新的表格並將這些欄位新增為維度：

• Product

• Month

• Sales

套用指令碼前置詞後，跨維度資料表已轉換為直式表格，其中 Month 為一欄，Sales 為另一欄。這可改善資料可讀性。

概覽

開啟資料載入編輯器並將下面的載入指令碼新增至新的索引標籤。

載入指令碼包含：

• 載入到稱為 Targets 之表格的資料集。

• 將樞紐銷售人員名稱轉置為自己欄位的 crosstable 載入前置詞具有 Sales Person 標籤。

• 關聯銷售目標資料，這結構化為稱為 Target 的欄位。

載入指令碼

SalesTargets:
CROSSTABLE([Sales Person],Target,1)
LOAD
*
INLINE [
Area, Lisa, James, Sharon
APAC, 1500, 1750, 1850
EMEA, 1350, 950, 2050
NA, 1800, 1200, 1350
];

結果

載入資料並開啟工作表。建立新的表格並將這些欄位新增為維度：

• Area

• Sales Person

新增此量值：

=Sum(Target)

若您想要複寫資料顯示作為樞紐輸入表格，可以在工作表中建立對等的樞紐分析表。

請執行下列動作：

1. 複製並貼上您剛在工作表中建立的表格。
2. 將樞紐分析表圖表物件拖曳到新建立的表格副本頂端。選取轉換。
3. 按一下 完成編輯。
4. 將 Sales Person 欄位從垂直欄架拖曳到水平欄架。

下表以初始表格形式顯示資料，如 Qlik Sense 中顯示：

對等的樞紐分析表看起來與下列內容類似，在 Sales Person 的較大列內包含每個銷售人員名稱的欄：

概覽

開啟資料載入編輯器並將下面的載入指令碼新增至新的索引標籤。

載入指令碼包含：

• 呈現銷售和目標資料的資料集，按區域和一年中的月份組織。 這載入到稱為 SalesAndTargets 的表格。

• crosstable 載入前置詞。這用來在專用欄位內取消 Month Year 維度樞紐，以及將銷售和目標金額的矩陣轉置為稱為 Amount 的專用欄位。

• Month Year 欄位使用文字至日期轉換函數 date# 從文字轉換為正確日期。此日期轉換的 Month Year 欄位透過 Join 載入前置詞聯結回到 SalesAndTarget 表格。

載入指令碼

SalesAndTargets:
CROSSTABLE(MonthYearAsText,Amount,2)
LOAD
	*
INLINE [
Area	Type	Jan-22	Feb-22	Mar-22	Apr-22	May-22	Jun-22	Jul-22	Aug-22	Sep-22	Oct-22	Nov-22	Dec-22
APAC	Target	425	425	425	425	425	425	425	425	425	425	425	425
APAC	Actual	435	434	397	404	458	447	413	458	385	421	448	397
EMEA	Target	362.5	362.5	362.5	362.5	362.5	362.5	362.5	362.5	362.5	362.5	362.5	362.5
EMEA	Actual	363.5	359.5	337.5	361.5	341.5	337.5	379.5	352.5	327.5	337.5	360.5	334.5
NA	Target	375	375	375	375	375	375	375	375	375	375	375	375
NA	Actual	378	415	363	356	403	343	401	365	393	340	360	405
] (delimiter is '\t');

tmp:
LOAD DISTINCT MonthYearAsText,date#(MonthYearAsText,'MMM-YY') AS [Month Year]
RESIDENT SalesAndTargets;

JOIN (SalesAndTargets)
LOAD * RESIDENT tmp;

DROP TABLE tmp;
DROP FIELD MonthYearAsText;

結果

載入資料並開啟工作表。建立新的表格並將這些欄位新增為維度：

• Area

• Month Year

透過標籤 Actual 建立下列量值：

=Sum({<Type={'Actual'}>} Amount)

也透過標籤 Target 建立此量值：

=Sum({<Type={'Target'}>} Amount)

若您想要複寫資料顯示作為樞紐輸入表格，可以在工作表中建立對等的樞紐分析表。

請執行下列動作：

1. 複製並貼上您剛在工作表中建立的表格。
2. 將樞紐分析表圖表物件拖曳到新建立的表格副本頂端。選取轉換。
3. 按一下 完成編輯。
4. 將 Month Year 欄位從垂直欄架拖曳到水平欄架。
5. 將 Values 項目從水平欄架拖曳到垂直欄架。

下表以初始表格形式顯示資料，如 Qlik Sense 中顯示：

對等的樞紐分析表看起來與下列內容類似，在 Month Year 的較大列內包含該年每個個別月份的欄：