Crosstable

概述

打开数据加载编辑器，并将下面的第一加载脚本添加到新选项卡。

第一个加载脚本包含一个数据集，crosstable 脚本前缀稍后将应用于该数据集，其中应用 crosstable 的部分已注释掉。这意味着注释语法用于在加载脚本中禁用此部分。

第二个加载脚本与第一个加载脚本相同，但应用了未注释 crosstable（通过删除注释语法启用）。脚本以这种方式显示，以突出显示该脚本函数在转换数据中的价值。

第二加载脚本（应用的函数）

tmpData:
//Crosstable (MonthText, Sales)
Load * inline [
Product, Jan 2021, Feb 2021, Mar 2021, Apr 2021, May 2021, Jun 2021
A, 100, 98, 103, 63, 108, 82
B, 284, 279, 297, 305, 294, 292
C, 50, 53, 50, 54, 49, 51];
 
//Final:
//Load Product,
//Date(Date#(MonthText,'MMM YYYY'),'MMM YYYY') as Month,
//Sales

//Resident tmpData;

//Drop Table tmpData;

有关使用内联加载的详细信息，请参见使用内联加载来加载数据。

结果

加载数据并打开工作表。创建新表并将这些字段添加为维度：

• Product

• Jan 2021

• Feb 2021

• Mar 2021

• Apr 2021

• May 2021

• Jun 2021

该脚本允许创建一个交叉表，每个月一列，每个产品一行。按照目前的格式，该数据不容易分析。最好将所有数字放在一个字段中，将所有月份放在另一个字段中，放在一个三列表格中。下一节将解释如何对交叉表进行这种转换。

第二加载脚本（应用的函数）

通过删除 // 来取消对脚本的注释。加载的脚本应如下所示：

tmpData:
Crosstable (MonthText, Sales)
Load * inline [
Product, Jan 2021, Feb 2021, Mar 2021, Apr 2021, May 2021, Jun 2021
A, 100, 98, 103, 63, 108, 82
B, 284, 279, 297, 305, 294, 292
C, 50, 53, 50, 54, 49, 51];
 
Final:
Load Product,
Date(Date#(MonthText,'MMM YYYY'),'MMM YYYY') as Month,
Sales

Resident tmpData;

Drop Table tmpData;

有关使用内联加载的详细信息，请参见使用内联加载来加载数据。

结果

加载数据并打开工作表。创建新表并将这些字段添加为维度：

• Product

• Month

• Sales

应用脚本前缀后，交叉表将转换为一个垂直表，其中一列用于 Month，另一列用于 Sales。这提高了数据的可读性。

概述

打开数据加载编辑器，并将下面的加载脚本添加到新选项卡。

加载脚本包含：

• 加载到名为目标的表中的数据集。

• crosstable 加载前缀，将数据透视的销售人员姓名转换为其自己的字段，标记为 Sales Person。

• 关联的销售目标数据，该数据被结构化为一个名为 Target 的字段。

加载脚本

SalesTargets:
CROSSTABLE([Sales Person],Target,1)
LOAD
*
INLINE [
Area, Lisa, James, Sharon
APAC, 1500, 1750, 1850
EMEA, 1350, 950, 2050
NA, 1800, 1200, 1350
];

结果

加载数据并打开工作表。创建新表并将这些字段添加为维度：

• Area

• Sales Person

添加该度量：

=Sum(Target)

如果要将数据的显示复制为数据透视输入表，可以在工作表中创建等效的数据透视表。

执行以下操作：

1. 将刚刚创建的表复制并粘贴到工作表中。
2. 将透视表图表对象拖动到新创建的表副本的顶部。选择转换。
3. 单击 完成编辑。
4. 将 Sales Person 字段从垂直列架拖动到水平列架。

下表显示了初始表格形式的数据，如 Qlik Sense 中所示：

等效数据透视表类似如下，每个销售人员姓名的列包含在较大的 Sales Person 行中：

概述

打开数据加载编辑器，并将下面的加载脚本添加到新选项卡。

加载脚本包含：

• 表示销售和目标数据的数据集，按地区和月份组织。这将加载到名为 SalesAndTargets 的表中。

• crosstable 加载前缀。这用于将 Month Year 维度取消透视到专用字段中，以及将销售和目标金额矩阵转换到名为 Amount 的专用字段中。

• 使用文本到日期转换特性 date# 将 Month Year 字段从文本转换为适当的日期。此日期转换 Month Year 字段通过 Join 加载前缀连接回 SalesAndTarget 表中。

加载脚本

SalesAndTargets:
CROSSTABLE(MonthYearAsText,Amount,2)
LOAD
	*
INLINE [
Area	Type	Jan-22	Feb-22	Mar-22	Apr-22	May-22	Jun-22	Jul-22	Aug-22	Sep-22	Oct-22	Nov-22	Dec-22
APAC	Target	425	425	425	425	425	425	425	425	425	425	425	425
APAC	Actual	435	434	397	404	458	447	413	458	385	421	448	397
EMEA	Target	362.5	362.5	362.5	362.5	362.5	362.5	362.5	362.5	362.5	362.5	362.5	362.5
EMEA	Actual	363.5	359.5	337.5	361.5	341.5	337.5	379.5	352.5	327.5	337.5	360.5	334.5
NA	Target	375	375	375	375	375	375	375	375	375	375	375	375
NA	Actual	378	415	363	356	403	343	401	365	393	340	360	405
] (delimiter is '\t');

tmp:
LOAD DISTINCT MonthYearAsText,date#(MonthYearAsText,'MMM-YY') AS [Month Year]
RESIDENT SalesAndTargets;

JOIN (SalesAndTargets)
LOAD * RESIDENT tmp;

DROP TABLE tmp;
DROP FIELD MonthYearAsText;

结果

加载数据并打开工作表。创建新表并将这些字段添加为维度：

• Area

• Month Year

使用标签 Actual 创建以下度量值：

=Sum({<Type={'Actual'}>} Amount)

同时创建此度量，具有标签 Target：

=Sum({<Type={'Target'}>} Amount)

如果要将数据的显示复制为数据透视输入表，可以在工作表中创建等效的数据透视表。

执行以下操作：

1. 将刚刚创建的表复制并粘贴到工作表中。
2. 将透视表图表对象拖动到新创建的表副本的顶部。选择转换。
3. 单击 完成编辑。
4. 将 Month Year 字段从垂直列架拖动到水平列架。
5. 将 Values 项目从水平列架拖动到垂直列架。

下表显示了初始表格形式的数据，如 Qlik Sense 中所示：

等效数据透视表类似如下，每个单独年度月份的列包含在较大的 Month Year 行中：