Crosstable

Vue d'ensemble

Ouvrez l'éditeur de chargement de données et ajoutez le premier script de chargement ci-dessous à un nouvel onglet.

Le premier script de chargement contient un ensemble de données auquel le préfixe de script crosstable sera appliqué ultérieurement, la section appliquant crosstable commenté. Cela signifie que la syntaxe de commentaire a été utilisée pour désactiver cette section dans le script de chargement.

Le deuxième script de chargement est le même que le premier, mais avec l'application de crosstable non commenté (activé via la suppression de la syntaxe de commentaire). Les scripts sont présentés de cette manière pour mettre en évidence la valeur de cette fonction de script dans la transformation des données.

Premier script de chargement (fonction non appliquée)

tmpData:
//Crosstable (MonthText, Sales)
Load * inline [
Product, Jan 2021, Feb 2021, Mar 2021, Apr 2021, May 2021, Jun 2021
A, 100, 98, 103, 63, 108, 82
B, 284, 279, 297, 305, 294, 292
C, 50, 53, 50, 54, 49, 51];
 
//Final:
//Load Product,
//Date(Date#(MonthText,'MMM YYYY'),'MMM YYYY') as Month,
//Sales

//Resident tmpData;

//Drop Table tmpData;

Pour plus d'informations sur l'utilisation des chargements inline, voir Chargements inline.

Résultats

Chargez les données et ouvrez une feuille. Créez une table et ajoutez ces champs comme dimensions :

• Product

• Jan 2021

• Feb 2021

• Mar 2021

• Apr 2021

• May 2021

• Jun 2021

Ce script permet la création d'un tableau croisé (crosstable) avec une colonne pour chaque mois et une ligne par produit. Dans ce format, ces données ne sont pas faciles à analyser. Il serait préférable d'avoir tous les nombres dans un champ et tous les mois dans un autre, à savoir, dans un tableau à trois colonnes. La section suivante explique comment effectuer cette transformation en tableau croisé (crosstable).

Deuxième script de chargement (fonction appliquée)

Décommentez le script en supprimant //. Le script de chargement devrait ressembler au suivant :

tmpData:
Crosstable (MonthText, Sales)
Load * inline [
Product, Jan 2021, Feb 2021, Mar 2021, Apr 2021, May 2021, Jun 2021
A, 100, 98, 103, 63, 108, 82
B, 284, 279, 297, 305, 294, 292
C, 50, 53, 50, 54, 49, 51];
 
Final:
Load Product,
Date(Date#(MonthText,'MMM YYYY'),'MMM YYYY') as Month,
Sales

Resident tmpData;

Drop Table tmpData;

Pour plus d'informations sur l'utilisation des chargements inline, voir Chargements inline.

Résultats

Chargez les données et ouvrez une feuille. Créez une table et ajoutez ces champs comme dimensions :

• Product

• Month

• Sales

Une fois le préfixe de script appliqué, le tableau croisé (crosstable) est transformé en tableau simple avec une colonne pour Month et une autre pour Sales. Cela améliore la lisibilité des données.

Vue d'ensemble

Ouvrez l'éditeur de chargement de données et ajoutez le script de chargement ci-dessous à un nouvel onglet.

Le script de chargement contient :

• Ensemble de données chargé dans une table appelée Targets.

• Préfixe de chargement crosstable, qui transpose les noms sales person pivotés dans un champ qui lui est propre, intitulé Sales Person.

• Données sales target associées, structurées dans un champ nommé Target.

Script de chargement

SalesTargets:
CROSSTABLE([Sales Person],Target,1)
LOAD
*
INLINE [
Area, Lisa, James, Sharon
APAC, 1500, 1750, 1850
EMEA, 1350, 950, 2050
NA, 1800, 1200, 1350
];

Résultats

Chargez les données et ouvrez une feuille. Créez une table et ajoutez ces champs comme dimensions :

• Area

• Sales Person

Ajoutez cette mesure :

=Sum(Target)

Si vous souhaitez répliquer l'affichage des données sous forme de tableau d'entrée pivoté, vous pouvez créer un tableau croisé dynamique équivalent dans une feuille.

Procédez comme suit :

1. Copiez et collez le tableau que vous venez de créer dans la feuille.
2. Faites glisser l'objet graphique Tableau croisé dynamique par-dessus la copie de tableau que vous venez de créer. Sélectionnez Convertir.
3. Cliquez sur Édition terminée.
4. Faites glisser le champ Sales Person de la partie supérieure de la colonne verticale vers la partie supérieure de la colonne horizontale.

Le tableau suivant montre les données sous leur forme de tableau initiale, telles qu'affichées dans Qlik Sense :

Le tableau croisé dynamique équivalent ressemble à ce qui suit, la colonne du nom de chaque vendeur étant contenue dans la ligne plus grande pour Sales Person :

Vue d'ensemble

Ouvrez l'éditeur de chargement de données et ajoutez le script de chargement ci-dessous à un nouvel onglet.

Le script de chargement contient :

• Ensemble de données représentant les données sales et targets, organisées par secteur et mois de l'année. Cet ensemble de données est chargé dans une table appelée SalesAndTargets.

• Préfixe de chargement crosstable. Ceci est utilisé pour annuler le pivotement de la dimension Month Year dans un champ dédié, ainsi que pour transposer la matrice des montants sales et target dans un champ dédié appelé Amount.

• Conversion du champ Month Year du format texte en une date appropriée, à l'aide de la fonction de conversion de texte en date date#. Ce champ Month Year converti en date est de nouveau joint à la table SalesAndTarget via un préfixe de chargement Join.

Script de chargement

SalesAndTargets:
CROSSTABLE(MonthYearAsText,Amount,2)
LOAD
	*
INLINE [
Area	Type	Jan-22	Feb-22	Mar-22	Apr-22	May-22	Jun-22	Jul-22	Aug-22	Sep-22	Oct-22	Nov-22	Dec-22
APAC	Target	425	425	425	425	425	425	425	425	425	425	425	425
APAC	Actual	435	434	397	404	458	447	413	458	385	421	448	397
EMEA	Target	362.5	362.5	362.5	362.5	362.5	362.5	362.5	362.5	362.5	362.5	362.5	362.5
EMEA	Actual	363.5	359.5	337.5	361.5	341.5	337.5	379.5	352.5	327.5	337.5	360.5	334.5
NA	Target	375	375	375	375	375	375	375	375	375	375	375	375
NA	Actual	378	415	363	356	403	343	401	365	393	340	360	405
] (delimiter is '\t');

tmp:
LOAD DISTINCT MonthYearAsText,date#(MonthYearAsText,'MMM-YY') AS [Month Year]
RESIDENT SalesAndTargets;

JOIN (SalesAndTargets)
LOAD * RESIDENT tmp;

DROP TABLE tmp;
DROP FIELD MonthYearAsText;

Résultats

Chargez les données et ouvrez une feuille. Créez une table et ajoutez ces champs comme dimensions :

• Area

• Month Year

Créez la mesure suivante, avec le libellé Actual :

=Sum({<Type={'Actual'}>} Amount)

Créez également la mesure suivante, avec le libellé Target :

=Sum({<Type={'Target'}>} Amount)

Si vous souhaitez répliquer l'affichage des données sous forme de tableau d'entrée pivoté, vous pouvez créer un tableau croisé dynamique équivalent dans une feuille.

Procédez comme suit :

1. Copiez et collez le tableau que vous venez de créer dans la feuille.
2. Faites glisser l'objet graphique Tableau croisé dynamique par-dessus la copie de tableau que vous venez de créer. Sélectionnez Convertir.
3. Cliquez sur Édition terminée.
4. Faites glisser le champ Month Year de la partie supérieure de la colonne verticale vers la partie supérieure de la colonne horizontale.
5. Faites glisser l'élément Values de la partie supérieure de la colonne horizontale vers la partie supérieure de la colonne verticale.

Le tableau suivant montre les données sous leur forme de tableau initiale, telles qu'affichées dans Qlik Sense :

Le tableau croisé dynamique équivalent ressemble à ce qui suit, la colonne de chaque mois de l'année étant contenue dans la ligne plus grande pour Month Year :