Crosstable

Vista general

Abra el Editor de carga de datos y agregue el primer script de carga a continuación, en una nueva pestaña.

El primer script de carga contiene un conjunto de datos al que se aplicará el prefijo de script crosstable más adelante, con la sección de aplicación crosstable descomentada. Esto significa que se utilizó la sintaxis de comentarios para deshabilitar esta sección en el script de carga.

El segundo script de carga es el mismo que el primero, pero con la aplicación de crosstable no comentado (habilitado al eliminar la sintaxis de comentarios). Los scripts se muestran de esta manera para resaltar el valor de esta función de script en la transformación de datos.

Primer script de carga (función no aplicada)

tmpData:
//Crosstable (MonthText, Sales)
Load * inline [
Product, Jan 2021, Feb 2021, Mar 2021, Apr 2021, May 2021, Jun 2021
A, 100, 98, 103, 63, 108, 82
B, 284, 279, 297, 305, 294, 292
C, 50, 53, 50, 54, 49, 51];
 
//Final:
//Load Product,
//Date(Date#(MonthText,'MMM YYYY'),'MMM YYYY') as Month,
//Sales

//Resident tmpData;

//Drop Table tmpData;

Para más información sobre el uso de cargas inline, vea Usar cargas inline para cargar datos.

Resultados

Cargue los datos y abra una hoja. Cree una nueva tabla y agregue estos campos como dimensiones:

• Product

• Jan 2021

• Feb 2021

• Mar 2021

• Apr 2021

• May 2021

• Jun 2021

Este script permite la creación de una tabla cruzada con una columna para cada mes y una fila por producto. En su formato actual, estos datos no son fáciles de analizar. Sería mucho mejor tener todos los números en un campo y todos los meses en otro, en una tabla de tres columnas. La siguiente sección explica cómo hacer esta transformación en la tabla cruzada.

Segundo script de carga (función aplicada)

Descomente el script eliminando el //. El script de carga deberá presentar el siguiente aspecto:

tmpData:
Crosstable (MonthText, Sales)
Load * inline [
Product, Jan 2021, Feb 2021, Mar 2021, Apr 2021, May 2021, Jun 2021
A, 100, 98, 103, 63, 108, 82
B, 284, 279, 297, 305, 294, 292
C, 50, 53, 50, 54, 49, 51];
 
Final:
Load Product,
Date(Date#(MonthText,'MMM YYYY'),'MMM YYYY') as Month,
Sales

Resident tmpData;

Drop Table tmpData;

Para más información sobre el uso de cargas inline, vea Usar cargas inline para cargar datos.

Resultados

Cargue los datos y abra una hoja. Cree una nueva tabla y agregue estos campos como dimensiones:

• Product

• Month

• Sales

Una vez que se ha aplicado el prefijo de script, la tabla cruzada se transforma en una tabla simple con una columna para Month y otra para Sales. Esto mejora la legibilidad de los datos.

Vista general

Abra el editor de carga de datos y agregue el script de carga a continuación a una nueva pestaña.

El script de carga contiene:

• Un conjunto de datos que se carga en una tabla denominada Targets (Objetivos).

• El prefijo de carga crosstable, que transpone los nombres de las personas de ventas dinámicas en un campo propio, etiquetado Sales Person.

• Los datos de objetivos de ventas asociados, que se estructuran en un campo llamado Target.

Script de carga

SalesTargets:
CROSSTABLE([Sales Person],Target,1)
LOAD
*
INLINE [
Area, Lisa, James, Sharon
APAC, 1500, 1750, 1850
EMEA, 1350, 950, 2050
NA, 1800, 1200, 1350
];

Resultados

Cargue los datos y abra una hoja. Cree una nueva tabla y agregue estos campos como dimensiones:

• Area

• Sales Person

Añada esta medida:

=Sum(Target)

Si desea replicar la visualización de datos como la tabla de entrada dinámica, puede crear una tabla pivotante equivalente en una hoja.

Haga lo siguiente:

1. Copie y pegue la tabla que acaba de crear en la hoja.
2. Arrastre el objeto gráfico de la Tabla pivotante a la parte superior de la copia de la tabla recién creada. Seleccione Convertir.
3. Haga clic en Edición finalizada.
4. Arrastre el campo Sales Person desde el estante de la columna vertical al estante de la columna horizontal.

La tabla siguiente muestra los datos en su forma de tabla inicial, como se indica en Qlik Sense:

La tabla pivotante equivalente es similar a la siguiente, con la columna para el nombre de cada vendedor contenida dentro de la fila más grande para Sales Person:

Vista general

Abra el editor de carga de datos y agregue el script de carga a continuación a una nueva pestaña.

El script de carga contiene:

• Un conjunto de datos que representa datos de ventas y objetivos, organizados por área y mes del año. Esto se carga en una tabla llamada SalesAndTargets.

• El prefijo de carga crosstable. Esto se usa para despivotar la dimensión Month Year en un campo específico, así como para transponer la matriz de ventas y las cantidades objetivo en un campo específico llamado Amount.

• Una conversión del campo de texto Month Year a una fecha adecuada, usando la función de conversión de texto a fecha date#. Este campo Month Year convertido a fecha se vuelve a unir a la tabla SalesAndTarget a través de un prefijo de carga Join.

Script de carga

SalesAndTargets:
CROSSTABLE(MonthYearAsText,Amount,2)
LOAD
	*
INLINE [
Area	Type	Jan-22	Feb-22	Mar-22	Apr-22	May-22	Jun-22	Jul-22	Aug-22	Sep-22	Oct-22	Nov-22	Dec-22
APAC	Target	425	425	425	425	425	425	425	425	425	425	425	425
APAC	Actual	435	434	397	404	458	447	413	458	385	421	448	397
EMEA	Target	362.5	362.5	362.5	362.5	362.5	362.5	362.5	362.5	362.5	362.5	362.5	362.5
EMEA	Actual	363.5	359.5	337.5	361.5	341.5	337.5	379.5	352.5	327.5	337.5	360.5	334.5
NA	Target	375	375	375	375	375	375	375	375	375	375	375	375
NA	Actual	378	415	363	356	403	343	401	365	393	340	360	405
] (delimiter is '\t');

tmp:
LOAD DISTINCT MonthYearAsText,date#(MonthYearAsText,'MMM-YY') AS [Month Year]
RESIDENT SalesAndTargets;

JOIN (SalesAndTargets)
LOAD * RESIDENT tmp;

DROP TABLE tmp;
DROP FIELD MonthYearAsText;

Resultados

Cargue los datos y abra una hoja. Cree una nueva tabla y agregue estos campos como dimensiones:

• Area

• Month Year

Cree la siguiente medida, con la etiqueta Actual:

=Sum({<Type={'Actual'}>} Amount)

Cree también la siguiente medida, con la etiqueta Target:

=Sum({<Type={'Target'}>} Amount)

Si desea replicar la visualización de datos como la tabla de entrada dinámica, puede crear una tabla pivotante equivalente en una hoja.

Haga lo siguiente:

1. Copie y pegue la tabla que acaba de crear en la hoja.
2. Arrastre el objeto gráfico de la Tabla pivotante a la parte superior de la copia de la tabla recién creada. Seleccione Convertir.
3. Haga clic en Edición finalizada.
4. Arrastre el campo Month Year desde el estante de la columna vertical al estante de la columna horizontal.
5. Arrastre el elemento Values desde el estante de la columna horizontal al estante de la columna vertical.

La tabla siguiente muestra los datos en su forma de tabla inicial, como se indica en Qlik Sense:

La tabla pivotante equivalente es similar a la siguiente, con la columna para el nombre de cada mes del año individual contenida dentro de la fila más grande de Month Year: