if – função de script e gráfico

A função if retorna um valor dependendo se a condição fornecida com a função avaliar como True ou False.

Sintaxe:

if(condition , then [, else])

Alguns dos exemplos neste tópico usam carregamentos inline. Para obter mais informações, consulte Carregamentos inline.

Argumentos
Argumento	Descrição
condition	Expressão que é interpretada de forma lógica.
then	Expressão que pode ser de qualquer tipo. Se condition forTrue, então a função if retornará o valor da expressão then.
else	Expressão que pode ser de qualquer tipo. Se condition forFalse, então a função if retornará o valor da expressão else. Este parâmetro é opcional. Se condition for False, NULL será retornado se você não tiver especificado else.

Exemplo
Exemplo	Resultado
if( Amount>= 0, 'OK', 'Alarm' )	Essa expressão testa se o valor é um número positivo (0 ou maior) e retorna 'OK' se for. Se a quantidade for menor que 0, 'Alarm' é exibido.

Exemplo - Script de carregamento usando if

Script de carregamento

É possível usar If em um script de carregamento com outros métodos e objetos, incluindo variáveis. Por exemplo, se você definir uma variável threshold e quiser incluir um campo no modelo de dados com base nesse limite, poderá fazer o seguinte.

Crie uma nova guia no editor de carregamento de dados e carregue os dados a seguir como um carregamento inline. Crie a tabela abaixo no Qlik Sense para ver os resultados.

Transactions:
Load * Inline [
transaction_id, transaction_date, transaction_amount, transaction_quantity, customer_id, size, color_code
3750, 20180830, 23.56, 2, 2038593, L, Red
3751, 20180907, 556.31, 6, 203521, m, orange
3752, 20180916, 5.75, 1, 5646471, S, blue
3753, 20180922, 125.00, 7, 3036491, l, Black
3754, 20180922, 484.21, 13, 049681, xs, Red
3756, 20180922, 59.18, 2, 2038593, M, Blue
3757, 20180923, 177.42, 21, 203521, XL, Black
];
 
set threshold = 100;
					
/* Create new table called Transaction_Buckets 
Compare transaction_amount field from Transaction table to threshold of 100.
Output results into a new field called Compared to Threshold							
 */					
 
Transaction_Buckets:
Load
   transaction_id,
   If(transaction_amount > $(threshold),'Greater than $(threshold)','Less than $(threshold)') as [Compared to Threshold]
Resident Transactions;

Resultados

Tabela do Qlik Sense mostrando a saída do uso da função if no script de carregamento.
transaction_id	Comparado a Limite
3750	Menor que 100
3751	Maior que 100
3752	Menor que 100
3753	Maior que 100
3754	Maior que 100
3756	Menor que 100
3757	Maior que 100

Exemplos - Expressões de gráfico usando if

Expressão de gráfico 1

Script de carregamento

Crie uma nova guia no editor de carregamento de dados e carregue os dados a seguir como um carregamento inline. Depois de carregar os dados, crie os exemplos de expressão de gráfico abaixo em uma tabela do Qlik Sense.

MyTable:
LOAD * inline [Date, Location, Incidents
1/3/2016, Beijing, 0
1/3/2016, Boston, 12
1/3/2016, Stockholm, 3
1/3/2016, Toronto, 0
1/4/2016, Beijing, 0
1/4/2016, Boston, 8];

Tabela do Qlik Sense mostrando exemplos da função if função em uma expressão de gráfico.
Date	Localização	Incidentes	if(Incidentes>=10, 'Crítico', 'OK' )	if(Incidentes>=10, 'Crítico', If( Incidentes>=1 and Incidentes<10, 'Aviso', 'OK'))
1/3/2016	Pequim	0	OK	OK
1/3/2016	Boston	12	Crítico	Crítico
1/3/2016	Estocolmo	3	OK	Aviso
1/3/2016	Toronto	0	OK	OK
1/4/2016	Pequim	0	OK	OK
1/4/2016	Boston	8	OK	Aviso

Expressão de gráfico 2

Em um novo aplicativo, adicione o script a seguir em uma nova guia no editor de carregamento de dados e carregue os dados. Você pode então criar a tabela com as expressões de gráfico abaixo.

SET FirstWeekDay=0;
Load 
Date(MakeDate(2022)+RecNo()-1) as Date
Autogenerate 14;

Tabela do Qlik Sense mostrando um exemplo da função if em uma expressão de gráfico.
Date	WeekDay(Date)	If(WeekDay(Date)>=5,'WeekEnd','Normal Day')
1/1/2022	Sáb	Fim de semana
1/2/2022	Dom	Fim de semana
1/3/2022	Seg	Dia normal
1/4/2022	Ter	Dia normal
1/5/2022	Qua	Dia normal
1/6/2022	Qui	Dia normal
1/7/2022	Sex	Dia normal
1/8/2022	Sáb	Fim de semana
1/9/2022	Dom	Fim de semana
1/10/2022	Seg	Dia normal
1/11/2022	Ter	Dia normal
1/12/2022	Qua	Dia normal
1/13/2022	Qui	Dia normal
1/14/2022	Sex	Dia normal

Esta página ajudou?

Se você encontrar algum problema com esta página ou seu conteúdo - um erro de digitação, uma etapa ausente ou um erro técnico - informe-nos como podemos melhorar!

Deixe seu feedback aqui