Crosstable

Panoramica

Aprire l'editor caricamento dati e aggiungere il primo script di caricamento di seguito in una nuova scheda.

Il primo script di caricamento contiene un set di dati a cui verrà successivamente applicato il prefisso dello script crosstable, con la sezione che applica crosstable con commenti. Ciò significa che la sintassi dei commenti è stata utilizzata per disabilitare questa sezione nello script di caricamento.

Il secondo script di caricamento è uguale al primo, ma con l'applicazione di crosstable senza commenti (abilitato rimuovendo la sintassi del commento). Gli script vengono mostrati in questo modo per evidenziare il valore di questa funzione di script nella trasformazione dei dati.

Primo script di caricamento (funzione non applicata)

tmpData:
//Crosstable (MonthText, Sales)
Load * inline [
Product, Jan 2021, Feb 2021, Mar 2021, Apr 2021, May 2021, Jun 2021
A, 100, 98, 103, 63, 108, 82
B, 284, 279, 297, 305, 294, 292
C, 50, 53, 50, 54, 49, 51];
 
//Final:
//Load Product,
//Date(Date#(MonthText,'MMM YYYY'),'MMM YYYY') as Month,
//Sales

//Resident tmpData;

//Drop Table tmpData;

Per ulteriori informazioni sull'utilizzo di caricamenti inline, vedere Caricamento inline.

Risultati

Caricare i dati e aprire un foglio. Creare una nuova tabella e aggiungere tali campi come dimensioni:

• Product

• Jan 2021

• Feb 2021

• Mar 2021

• Apr 2021

• May 2021

• Jun 2021

Questo script consente la creazione di una tabella incrociata con una colonna per ogni mese e una riga per prodotto. Nel suo formato attuale, questi dati non sono facili da analizzare. Sarebbe preferibile disporre di tutti i numeri in un campo e tutti i mesi in un altro, in una tabella a tre colonne. La sezione successiva spiega come eseguire questa trasformazione nella tabella incrociata.

Secondo script di caricamento (funzione non applicata)

Cancellare i commenti nello script rimuovendo //. Lo script di caricamento dovrebbe avere l'aspetto seguente:

tmpData:
Crosstable (MonthText, Sales)
Load * inline [
Product, Jan 2021, Feb 2021, Mar 2021, Apr 2021, May 2021, Jun 2021
A, 100, 98, 103, 63, 108, 82
B, 284, 279, 297, 305, 294, 292
C, 50, 53, 50, 54, 49, 51];
 
Final:
Load Product,
Date(Date#(MonthText,'MMM YYYY'),'MMM YYYY') as Month,
Sales

Resident tmpData;

Drop Table tmpData;

Per ulteriori informazioni sull'utilizzo di caricamenti inline, vedere Caricamento inline.

Risultati

Caricare i dati e aprire un foglio. Creare una nuova tabella e aggiungere tali campi come dimensioni:

• Product

• Month

• Sales

Una volta applicato il prefisso dello script, la tabella incrociata viene trasformata in una tabella lineare con una colonna per il valore Month e un'altra per Sales. Ciò migliora la leggibilità dei dati.

Panoramica

Aprire l'editor caricamento dati e aggiungere lo script di caricamento sotto in una nuova scheda.

Lo script di caricamento contiene:

• Un set di dati che viene caricato in una tabella denominata Target.

• Il prefisso di caricamento crosstable, che traspone i nomi degli agenti dedicati alle vendite pivot in un campo a sé stante con l'etichetta Sales Person.

• I dati degli obiettivi di vendita associati, sono strutturati in un campo denominato Target.

Script di caricamento

SalesTargets:
CROSSTABLE([Sales Person],Target,1)
LOAD
*
INLINE [
Area, Lisa, James, Sharon
APAC, 1500, 1750, 1850
EMEA, 1350, 950, 2050
NA, 1800, 1200, 1350
];

Risultati

Caricare i dati e aprire un foglio. Creare una nuova tabella e aggiungere tali campi come dimensioni:

• Area

• Sales Person

Aggiungere questa misura:

=Sum(Target)

Se si desidera replicare la visualizzazione dei dati come tabella pivot di input, è possibile creare una tabella pivot equivalente in un foglio.

Procedere come indicato di seguito:

1. Copiare e incollare la tabella appena creata nel foglio.
2. Trascinare l'oggetto grafico Tabella pivot sopra la copia della tabella appena creata. Selezionare Converti.
3. Fare clic su Termina modifica.
4. Trascinare il campo Sales Person dalla casella della colonna verticale alla casella della colonna orizzontale.

La tabella seguente mostra i dati nella forma della tabella iniziale, come è visualizzato in Qlik Sense:

La tabella pivot equivalente è simile a quella seguente, con la colonna per il nome di ogni dipendente addetto alle vendite contenuta all'interno della riga più grande per Sales Person:

Panoramica

Aprire l'editor caricamento dati e aggiungere lo script di caricamento sotto in una nuova scheda.

Lo script di caricamento contiene:

• Un set di dati che rappresenta i dati sulle vendite e sugli obiettivi, organizzati per area e mese dell'anno. Questo viene caricato in una tabella denominata SalesAndTargets.

• Il prefisso di caricamento crosstable. Questo viene utilizzato per annullare il pivot della dimensione Month Year in un campo dedicato, nonché per trasporre la matrice delle vendite e degli importi target in un campo dedicato chiamato Amount.

• Conversione del campo Month Year da testo in una data corretta, utilizzando la funzione di conversione text-to-date date#. Il campo Month Year convertito in data viene unito nuovamente alla tabella SalesAndTarget tramite un prefisso di caricamento Join.

Script di caricamento

SalesAndTargets:
CROSSTABLE(MonthYearAsText,Amount,2)
LOAD
	*
INLINE [
Area	Type	Jan-22	Feb-22	Mar-22	Apr-22	May-22	Jun-22	Jul-22	Aug-22	Sep-22	Oct-22	Nov-22	Dec-22
APAC	Target	425	425	425	425	425	425	425	425	425	425	425	425
APAC	Actual	435	434	397	404	458	447	413	458	385	421	448	397
EMEA	Target	362.5	362.5	362.5	362.5	362.5	362.5	362.5	362.5	362.5	362.5	362.5	362.5
EMEA	Actual	363.5	359.5	337.5	361.5	341.5	337.5	379.5	352.5	327.5	337.5	360.5	334.5
NA	Target	375	375	375	375	375	375	375	375	375	375	375	375
NA	Actual	378	415	363	356	403	343	401	365	393	340	360	405
] (delimiter is '\t');

tmp:
LOAD DISTINCT MonthYearAsText,date#(MonthYearAsText,'MMM-YY') AS [Month Year]
RESIDENT SalesAndTargets;

JOIN (SalesAndTargets)
LOAD * RESIDENT tmp;

DROP TABLE tmp;
DROP FIELD MonthYearAsText;

Risultati

Caricare i dati e aprire un foglio. Creare una nuova tabella e aggiungere tali campi come dimensioni:

• Area

• Month Year

Creare le seguenti misure, con l'etichetta Actual:

=Sum({<Type={'Actual'}>} Amount)

Inoltre, creare questa misura, con l'etichetta Target:

=Sum({<Type={'Target'}>} Amount)

Se si desidera replicare la visualizzazione dei dati come tabella pivot di input, è possibile creare una tabella pivot equivalente in un foglio.

Procedere come indicato di seguito:

1. Copiare e incollare la tabella appena creata nel foglio.
2. Trascinare l'oggetto grafico Tabella pivot sopra la copia della tabella appena creata. Selezionare Converti.
3. Fare clic su Termina modifica.
4. Trascinare il campo Month Year dalla casella della colonna verticale alla casella della colonna orizzontale.
5. Trascinare l'elemento Values dalla casella della colonna verticale alla casella della colonna orizzontale.

La tabella seguente mostra i dati nella forma della tabella iniziale, come è visualizzato in Qlik Sense:

La tabella pivot equivalente è simile a quella seguente, con la colonna per ogni mese dell'anno contenuta all'interno della riga più grande per Month Year: