Tutorial – Erstellen einer Auswahlformel

Sie können Auswahlformeln in Qlik Sense so zusammenstellen, dass Datenanalyse unterstützt wird. In diesem Kontext wird die Analyse oft als Aggregierung mit Auswahlformeln bezeichnet. Die Aggregierung mit Auswahlformeln bietet eine Möglichkeit, einen Umfang zu definieren, der sich vom durch die aktuellen Auswahlen in einer App definierten Satz an Datensätzen unterscheidet.

Lerninhalte

In diesem Tutorial werden die Daten und Diagrammformeln gezeigt, mit denen Modifikatoren, Identifikatoren und Operatoren für Auswahlformeln erstellt werden.

Für wen wird dieses Tutorial empfohlen

Dieses Tutorial richtet sich an App-Entwickler, die mit dem Skript-Editor und mit Diagrammformeln vertraut sind.

Vorbereitungen vor dem Beginn

Sie benötigen die Zuteilung eines Qlik Sense Enterprise Professional-Zugriffs, um Daten laden und Apps erstellen zu können.

Weitere Informationsquellen und Ressourcen

• Die Themen Aggregierung mit Auswahlformeln in der Hilfe bieten einen Überblick über die Aggregierung mit Auswahlformeln, eine eingehende Beschreibung der Elemente von Auswahlformeln und Beispiele.

• Qlik bietet eine Vielzahl von Ressourcen, wenn Sie noch mehr erfahren möchten.
• Schulungen, einschließlich kostenloser Online-Kurse, stehen im Qlik Continuous Classroom zur Verfügung.
• Diskussionsforen, Blogs und mehr finden Sie in der Qlik Community.

Videos

Die folgenden Videos ergänzen dieses Tutorial.

Das erste Video zeigt grundlegende Auswahlformeln ähnlich denen, die in diesem Tutorial beschrieben werden. Das zweite Video zeigt komplexere Auswahlformeln.

• Aggregierung mit Auswahlformeln Teil 1: Einführung für Anfänger

• Aggregierung mit Auswahlformeln Teil 2

Elemente in einer Auswahlformel

Auswahlformeln sind in eine Aggregierungsfunktion eingeschlossen, wie Sum(), Max(), Min(), Avg() oder Count(). Auswahlformeln sind aus Blöcken aufgebaut, die als Elemente bezeichnet werden. Diese Elemente sind Modifikatoren, Identifikatoren und Operatoren für Auswahlformeln.

Die obige Auswahlformel wird beispielsweise anhand der Aggregierung Sum(Sales) erstellt. Die Auswahlformel ist in die äußeren geschweiften Klammern eingeschlossen: { }

Der erste Operand in der Formel ist: $<Year={2021}>

Dieser Operand gibt den Umsatz für das Jahr 2021 für die aktuelle Auswahl zurück. Der Modifikator <Year={2021}> enthält die Auswahl des Jahres 2021. Der Identifikator für Auswahlformeln $ gibt an, dass die Auswahlformel auf der aktuellen Auswahl basiert.

Der zweite Operand in der Formel ist: 1<Country={'Sweden'}>

Dieser Operand gibt Sales für Sweden zurück. Der Modifikator <Country={'Sweden'}> enthält die Auswahl des Landes Sweden. Der Identifikator für Auswahlformeln 1 gibt an, dass die in der App getroffenen Auswahlen ignoriert werden.

Schließlich gibt der Operator für Auswahlformeln + an, dass die Formel einen Satz bestehend aus den Datensätzen zurückgibt, die zu einem beliebigen der beiden Operanden gehören.

Weitere Informationen finden Sie unter:

• Modifikatoren für Auswahlformeln

• Identifikatoren für Auswahlformeln

• Operatoren für Auswahlformeln

Erstellen einer Auswahlformel – Tutorial

Befolgen Sie das folgende Verfahren, um die in diesem Tutorial gezeigten Auswahlformeln zu erstellen.

Eine neue App erstellen und Daten laden

Gehen Sie folgendermaßen vor:

1. Erstellen Sie eine neue App.
2. Klicken Sie auf Skript-Editor. Klicken Sie alternativ auf Vorbereiten > Dateneditor in der Navigationsleiste.
3. Erstellen Sie einen neuen Abschnitt im Dateneditor.
4. Kopieren Sie die folgenden Daten und fügen Sie sie in den neuen Abschnitt ein: Tutorial-Daten für Auswahlformeln

5. Klicken Sie auf Daten laden. Die Daten werden als Inline-Ladevorgang geladen.

Weitere Informationen über Inline-Ladevorgänge finden Sie unter: Inline-Ladevorgänge

Erstellen von Auswahlformeln mit Modifikatoren

Der Modifikator für Auswahlformeln besteht aus mindestens einem Feldnamen, jeweils gefolgt von einer Auswahl von Feldwerten. Der Modifikator ist in spitze Klammern eingeschlossen. Beispielsweise gilt in dieser Auswahlformel:

Sum ( {<Year = {2015}>} Sales )

Der Modifikator ist:

<Year = {2015}>

Dieser Modifikator gibt an, dass Daten aus dem Jahr 2015 ausgewählt werden. Die geschweiften Klammern, in die der Modifikator eingeschlossen ist, geben eine Auswahlformel an.

Gehen Sie folgendermaßen vor:

1. Öffnen Sie in einem Arbeitsblatt über die Navigationsleiste das Extras-Fenster und klicken Sie dann auf Diagramme.

   

2. Ziehen Sie einen KPI auf das Arbeitsblatt und klicken Sie dann auf Kennzahl hinzufügen.

   

3. Klicken Sie auf Sales und wählen Sie Sum(Sales) für die Aggregierung aus.

   

   Der KPI zeigt die Summe der Umsätze für alle Jahre.

   

4. Kopieren Sie den KPI und fügen Sie ihn ein, um einen neuen KPI zu erstellen.

5. Klicken Sie auf den neuen KPI, klicken Sie unter Kennzahlen auf Sales und klicken Sie dann auf Formel-Editor öffnen.

   

   Der Formel-Editor wird mit der Aggregierung Sum(Sales) geöffnet.

   

6. Erstellen Sie im Formel-Editor eine Formel, um nur Sales für 2015 zu summieren: 

   1. Fügen Sie geschweifte Klammern hinzu, um eine Auswahlformel anzugeben: Sum({}Sales)

   2. Fügen Sie spitze Klammern hinzu, um einen Modifikator für Auswahlformeln anzugeben: Sum({<>}Sales)

   3. Fügen Sie in den spitzen Klammern das auszuwählende Feld hinzu, in diesem Fall Year, gefolgt von einem Gleichheitszeichen. Schließen Sie dann 2015 in einen weiteren Satz geschweifte Klammern ein. Daraus ergibt sich der Modifikator für Auswahlformeln: {<Year={2015}>}.

      Die ganze Formel lautet:

      Sum({<Year={2015}>}Sales)

      

   4. Klicken Sie auf Anwenden, um die Formel zu speichern und den Formel-Editor zu schließen. Die Summe von Sales für 2015 wird im KPI gezeigt.

      

7. Erstellen Sie zwei weitere KPIs mit den folgenden Formeln:

   Sum({<Year={2015,2016}>}Sales)

   Der Modifikator in der obigen Formel ist <Year={2015,2016}>. Die Formel gibt die Summe für Sales für 2015 und 2016 zurück.

   Sum({<Year={2015},Country={'Germany'}>} Sales)

   Der Modifikator in der obigen Formel ist <Year={2015}, Country={'Germany'}>. Die Formel gibt die Summe für Sales für 2015 zurück, wobei sich 2015 mit Germany schneidet.

   

Hinzufügen von Identifikatoren für Auswahlformeln

In den obigen Auswahlformeln werden die aktuellen Auswahlen als Basis verwendet, weil kein Identifikator verwendet wurde. Fügen Sie dann Identifikatoren hinzu, um das Verhalten bei Treffen von Auswahlen anzugeben.

Gehen Sie folgendermaßen vor:

Erstellen oder kopieren Sie in Ihrem Arbeitsblatt die folgenden Auswahlformeln:

Sum({$<Year={"2015"}>}Sales)

Der Identifikator $ basiert die Auswahlformel auf den aktuellen Auswahlen, die in den Daten getroffen wurden. Dies ist auch das Standardverhalten, wenn kein Identifikator verwendet wird.

Sum({1<Year={"2015"}>}Sales)

Der Identifikator 1 sorgt dafür, dass die Aggregierung von Sum(Sales) für 2015 die aktuelle Auswahl ignoriert. Der Wert der Aggregierung ändert sich nicht, wenn der Benutzer andere Auswahlen trifft. Wenn beispielsweise unten Germany ausgewählt wird, ändert sich der Wert der aggregierten Summe von 2015 nicht.

Hinzufügen von Operatoren

Operatoren für Auswahlformeln werden zum Einschließen, Ausschließen und Überschneiden von Datensätzen verwendet. Sie benutzen Auswahlformeln als Operanden und liefern wiederum eine Auswahlformel.

Sie können Operatoren für Auswahlformeln in verschiedenen Situationen einsetzen:

• Zum Durchführen eines Vorgangs für Identifikatoren für Auswahlformeln, der Sätze von Datensätzen in Daten darstellt.

• Zum Durchführen eines Vorgangs für die Elementsätze, die Feldwerte oder innerhalb eines Modifikators für Auswahlformeln.

Gehen Sie folgendermaßen vor:

Erstellen oder kopieren Sie in Ihrem Arbeitsblatt die folgende Auswahlformel:

Sum({$<Year={2015}>+1<Country={'Germany'}>}Sales)

Hier sorgt das Pluszeichen ((+)) für eine Verbindung der Datensätze für 2015 und Germany. Wie für Identifikatoren für Auswahlformeln oben erläutert, bedeutet der Dollarzeichen-Identifikator (($)), dass die aktuellen Auswahlen für den ersten Operanden (<Year={2015}>) respektiert werden. Der Identifikator 1 bedeutet, dass die Auswahl für den zweiten Operanden (<Country={'Germany'}>) ignoriert wird.

Alternativ können Sie ein Minuszeichen ((-)) verwenden, um einen Datenbestand zurückzugeben, der aus den Datensätzen besteht, die zu 2015, aber nicht zu Germany gehören. Oder verwenden Sie einen Asterisk ((*)), um einen Satz aus den Datensätzen zurückzugeben, die zu beiden Sätzen gehören.

Sum({$<Year={2015}>-1<Country={'Germany'}>}Sales)

Sum({$<Year={2015}>*1<Country={'Germany'}>}Sales)

Tutorial-Daten für Auswahlformeln

//Create table SalesByCountry
SalesByCountry:
Load * Inline [
Country, Year, Sales
Argentina, 2016, 66295.03
Argentina, 2015, 140037.89
Austria, 2016, 54166.09
Austria, 2015, 182739.87
Belgium, 2016, 182766.87
Belgium, 2015, 178042.33
Brazil, 2016, 174492.67
Brazil, 2015, 2104.22
Canada, 2016, 101801.33
Canada, 2015, 40288.25
Denmark, 2016, 45273.25
Denmark, 2015, 106938.41
Finland, 2016, 107565.55
Finland, 2015, 30583.44
France, 2016, 115644.26
France, 2015, 30696.98
Germany, 2016, 8775.18
Germany, 2015, 77185.68
];