Modificatori di gruppo con espansioni con simbolo del dollaro

Le espansioni con simbolo del dollaro sono costrutti calcolati prima che l'espressione sia analizzata e valutata. Il risultato viene quindi inserito nell'espressione al posto di $(…). Il calcolo dell'espressione viene quindi effettuato usando il risultato dell'espansione con simbolo del dollaro.

L'editor delle espressioni mostra un'anteprima dell'espansione con simbolo del dollaro, in modo che sia possibile verificare per cosa valuta la propria espressione con simbolo del dollaro.

Utilizzare le espansioni con simbolo del dollaro quando si desidera utilizzare un calcolo all'interno del proprio set di elementi.

Ad esempio, se si desidera ricercare solo l'ultimo anno possibile, è possibile utilizzare la seguente costruzione:

<Year = {$(=Max(Year))}>

Max(Year) viene calcolato per primo e il risultato verrà inserito nell'espressione al posto di $(…).

Il risultato dopo l'espansione con dollaro sarà un'espressione simile alla seguente:

<Year = {2021}>

L'espressione all'interno dell'espansione con simbolo del dollaro viene calcolata in base alla selezione corrente. Ciò significa che se si effettua una selezione in un altro campo, il risultato dell'espressione ne viene influenzato.

Se si desidera che il calcolo sia indipendente dalla selezione, utilizzare l'analisi di gruppo all'interno dell'espansione con il simbolo del dollaro. Ad esempio:

<Year = {$(=Max({1} Year))}>

Stringhe

Quando si desidera che l'espansione con simbolo del dollaro risulti in una stringa, si applicano le normali regole associate alle citazioni. Ad esempio:

<Country = {'$(=FirstSortedValue(Country,Date)'}>

Il risultato dopo l'espansione con dollaro sarà un'espressione simile alla seguente:

<Country = {'New Zealand'}>

Si otterrà un errore di sintassi se non si utilizzano le virgolette.

Numeri

Quando si desidera che l'espansione con simbolo del dollaro risulti in un numero, assicurarsi che l'espansione abbia la stessa formattazione del campo. Questo significa che a volte è necessario disporre l'espressione in una funzione di formattazione.

Ad esempio:

<Amount = {$(=Num(Max(Amount), '###0.00'))}>

Il risultato dopo l'espansione con dollaro sarà un'espressione simile alla seguente:

<Amount = {12362.00}>

Usare un hash per forzare l'espansione a usare sempre il punto decimale e nessun separatore delle migliaia. Ad esempio:

<Amount = {$(#=Max(Amount))}>

Date

Quando si desidera che l'espansione con simbolo del dollaro risulti in una data, assicurarsi che l'espansione abbia la formattazione corretta. Questo significa che a volte è necessario disporre l'espressione in una funzione di formattazione.

Ad esempio:

<Date = {'$(=Date(Max(Date)))'}>

Il risultato dopo l'espansione con dollaro sarà un'espressione simile alla seguente:

<Date = {'12/31/2015'}>

Proprio come con le stringhe, è necessario utilizzare le virgolette corrette.

Un caso d'uso comune è quello di volere che il proprio calcolo sia limitato all'ultimo mese (o anno). Quindi è possibile utilizzare una ricerca numerica in combinazione con la funzione AddMonths().

Ad esempio:

<Date = {">=$(=AddMonths(Today(),-1))"}>

Il risultato dopo l'espansione con dollaro sarà un'espressione simile alla seguente:

<Date = {">=9/31/2021"}>

Questa operazione sceglierà tutti gli eventi che si sono verificati nell'ultimo mese.

Esempio: Espressioni del grafico per i modificatori set con espansioni con simbolo del dollaro

Esempio: espressioni del grafico

Script di caricamento

Caricare i dati seguenti come un caricamento inline nell'editor caricamento dati per creare gli esempi di espressione del grafico in basso.

Let vToday = Today();
MyTable:
Load 
Year(Date) as Year,
Date#(Date,'YYYY-MM-DD') as ISO_Date, 
Date(Date#(Date,'YYYY-MM-DD'),'M/D/YYYY') as US_Date, 
Country, Product, Amount 
Inline
[Date, Country, Product, Amount
2018-02-20, Canada, Washer, 6
2018-07-08, Germany, Anchor bolt, 10
2018-07-14, Germany, Anchor bolt, 3
2018-08-31, France, Nut, 2
2018-09-02, Czech Republic, Bolt, 1
2019-02-11, Czech Republic, Bolt, 3
2019-07-31, Czech Republic, Washer, 6
2020-03-13, France, Anchor bolt, 1
2020-07-12, Canada, Anchor bolt, 8
2021-10-15, France, Washer, 1];	

Per ulteriori informazioni sull'utilizzo di caricamenti inline, vedere Caricamento inline.

Espressioni del grafico con espansioni con simbolo del dollaro

Generare una tabella in un foglio Qlik Sense con le seguenti espressioni del grafico.

Tabella - Modificatori set con espansioni con simbolo del dollaro

Paese	Sum (Amount)	Sum({<US_Date={'$(vToday)'}>} Amount)	Sum({<ISO_Date={"$(=Date(Min(ISO_Date),'YYYY-MM-DD'))"}>} Amount)	Sum({<US_Date={">=$(=AddYears(Max(US_Date),-1))"}>} Amount)
Totali	41	1	6	1
Canada	14	0	6	0
Repubblica Ceca	10	0	0	0
France	4	1	0	1
Germany	13	0	0	0

Spiegazione

• Dimensioni:

  • Country

• Misure:

  • Sum(Amount)

    Sum Amount senza espressione set.

  • Sum({<US_Date={'$(vToday)'}>}Amount)

    Sum Amount per tutti i record in cui US_Date è lo stesso della variabile vToday.

  • Sum({<ISO_Date={"$(=Date(Min(ISO_Date),'YYYY-MM-DD'))"}>}Amount)

    Sum Amount per tutti i record in cui ISO_Date è lo stesso del primo (più piccolo) ISO_Date possibile. La funzione Date() è necessaria per assicurare che il formato della data corrisponda a quello del campo.

  • Sum({<US_Date={">=$(=AddYears(Max(US_Date),-1))"}>}Amount)

    Sum Amount per tutti i record che presentano un US_Date dopo o nella data un anno prima del più recente (più grande) US_Date possibile. La funzione AddYears() restituirà una data nel formato specificato dalla variabile DateFormat, e questo deve corrispondere al formato del campo US_Date.

Per ulteriori informazioni sulle espressioni, vedere Utilizzo di espressioni nelle visualizzazioni.