검색을 사용하는 집합 수정자

로드 스크립트

데이터 로드 편집기에서 다음 데이터를 인라인 로드로 로드하여 아래 차트 표현식 예를 만듭니다.

MyTable:
Load 
Year(Date) as Year,
Date#(Date,'YYYY-MM-DD') as ISO_Date, 
Date(Date#(Date,'YYYY-MM-DD'),'M/D/YYYY') as US_Date, 
Country, Product, Amount 
Inline
[Date, Country, Product, Amount
2018-02-20, Canada, Washer, 6
2018-07-08, Germany, Anchor bolt, 10
2018-07-14, Germany, Anchor bolt, 3
2018-08-31, France, Nut, 2
2018-09-02, Czech Republic, Bolt, 1
2019-02-11, Czech Republic, Bolt, 3
2019-07-31, Czech Republic, Washer, 6
2020-03-13, France, Anchor bolt, 1
2020-07-12, Canada, Anchor bolt, 8
2020-09-16, France, Washer, 1];	

인라인 로드 사용에 대한 자세한 내용은 인라인 로드를 사용하여 데이터 로드를 참조하십시오.

예 1: 텍스트 검색이 포함된 차트 표현식

다음 차트 표현식을 사용하여 Qlik Sense 시트에 테이블을 만듭니다.

설명

• 차원:

  • Country

• 측정값:

  • Sum(Amount)

    집합 표현식 없는 합계 Amount입니다.

  • Sum({<Country={"C*"}>}Amount)

    C로 시작하는 모든 국가(예: Canada 및 Czech Republic)의 합계 Amount입니다.

  • Sum({<Country={"*^R*"}>}Amount)

    R로 시작하는 단어가 있는 모든 국가(예: Czech Republic)의 합계 Amount입니다.

  • Sum({<Product={"*bolt*"}>}Amount)

    bolt 문자열을 포함하는 모든 제품(예: Bolt 및 Anchor bolt)의 합계 Amount입니다.

집합 표현식에 대한 자세한 내용은 시각화에서 표현식 사용을 참조하십시오.

예 2: 숫자 검색이 포함된 차트 표현식

다음 차트 표현식을 사용하여 Qlik Sense 시트에 테이블을 만듭니다.

설명

• 차원:

  • Country

• 측정값:

  • Sum(Amount)

    집합 표현식 없는 합계 Amount입니다.

  • Sum({<Year={">2019"}>}Amount)

    2019 이후의 모든 연도에 대한 합계 Amount입니다.

  • Sum({<ISO_Date={">=2019-07-01"}>}Amount)

    2019-07-01 또는 그 이후의 모든 날짜에 대한 합계 Amount입니다. 검색의 날짜 형식은 필드 형식과 일치해야 합니다.

  • Sum({<US_Date={">=4/1/2018<=12/31/2018"}>}Amount)

    시작 날짜와 종료 날짜를 포함하여 4/1/2018부터 12/31/2018까지의 모든 날짜에 대한 합계 Amount입니다. 검색의 날짜 형식은 필드 형식과 일치해야 합니다.

예 3: 표현식 검색이 포함된 차트 표현식

다음 차트 표현식을 사용하여 Qlik Sense 시트에 테이블을 만듭니다.

설명

• 차원:

  • Country

• 측정값:

  • Sum(Amount)

    집합 표현식 없는 합계 Amount입니다.

  • Sum({<Country={"=Sum(Amount)>10"}>}Amount)

    집계된 Amount 합계가 10보다 큰 모든 국가의 합계 Amount입니다.

  • Sum({<Country={"=Count(distinct Product)=1"}>}Amount)

    정확히 하나의 고유한 제품과 연관된 모든 국가의 합계 Amount입니다.

  • Sum({<Product={"=Count(Amount)>3"}>}Amount)

    데이터에 4개 이상의 거래가 있는 모든 국가의 합계 Amount입니다.