Dolar işareti genişletmeleri içeren set değiştiricileri

Dolar işareti genişletmeleri, ifade ayrıştırılıp değerlendirilmeden önce hesaplanan kurgulardır. Sonuç, daha sonra $(…) yerine ifadenin içine eklenir. İfade, daha sonra dolar işareti genişletmesinin sonucu kullanılarak hesaplanır.

İfade düzenleyicisi; dolar işareti genişletmesinin değerlendirme sonucunu doğrulayabilmeniz için, bir dolar işareti genişletmesi önizlemesi gösterir.

Dolar işareti genişletmelerini, öğe setinizin içinde bir hesaplama kullanmak istediğinizde kullanın.

Örneğin, yalnızca olabilecek en son yıla bakmak istiyorsanız, aşağıdaki kurguyu kullanabilirsiniz:

<Year = {$(=Max(Year))}>

Önce Max(Year) hesaplanır ve sonuç, $(…) yerine ifadenin içine eklenir.

Dolar işareti genişletmesinden sonra sonuç, aşağıdaki gibi bir ifade olacaktır:

<Year = {2021}>

Dolar işareti genişletmesinin içindeki ifade, mevcut seçim temel alınarak hesaplanır. Bu, başka bir alanda bir seçiminiz varsa, sonucun bundan etkileneceği anlamına gelir.

Hesaplamanın seçimden bağımsız olmasını istiyorsanız, dolar işareti genişletmesinin içinde set analizi kullanın. Örneğin:

<Year = {$(=Max({1} Year))}>

Dizeler

Dolar işareti genişletmesinin bir dize ile sonuçlanmasını istiyorsanız, normal tırnak işareti kuralları geçerlidir. Örneğin:

<Country = {'$(=FirstSortedValue(Country,Date)'}>

Dolar işareti genişletmesinden sonra sonuç, aşağıdaki gibi bir ifade olacaktır:

<Country = {'New Zealand'}>

Tırnak işaretleri kullanmazsanız, bir söz dizimi hatası alırsınız.

Sayılar

Dolar işareti genişletmesinin bir sayı ile sonuçlanmasını istiyorsanız, genişletmenin alan ile aynı biçimde olduğundan emin olun. Bu, ifadeyi bazen bir biçimlendirme fonksiyonu içine almanız gerektiği anlamına gelir.

Örneğin:

<Amount = {$(=Num(Max(Amount), '###0.00'))}>

Dolar işareti genişletmesinden sonra sonuç, aşağıdaki gibi bir ifade olacaktır:

<Amount = {12362.00}>

Genişletmeyi her zaman ondalık basamak kullanmaya ve binler ayracı kullanmamaya zorlamak için bir diyez işareti kullanın. Örneğin:

<Amount = {$(#=Max(Amount))}>

Tarihler

Dolar işareti genişletmesinin bir tarih ile sonuçlanmasını istiyorsanız, genişletmenin doğru biçimde olduğundan emin olun. Bu, ifadeyi bazen bir biçimlendirme fonksiyonu içine almanız gerektiği anlamına gelir.

Örneğin:

<Date = {'$(=Date(Max(Date)))'}>

Dolar işareti genişletmesinden sonra sonuç, aşağıdaki gibi bir ifade olacaktır:

<Date = {'12/31/2015'}>

Dizelerde olduğu gibi doğru tırnak karakterlerini kullanmanız gerekir.

Yaygın kullanım örneği, hesaplamanın son ay (veya yıl) ile sınırlı olmasının istendiği durumdur. Bu durumda AddMonths() fonksiyonu ile birlikte bir sayısal arama kullanabilirsiniz.

Örneğin:

<Date = {">=$(=AddMonths(Today(),-1))"}>

Dolar işareti genişletmesinden sonra sonuç, aşağıdaki gibi bir ifade olacaktır:

<Date = {">=9/31/2021"}>

Bu, geçen ay gerçekleşen tüm etkinlikleri seçer.

Örnek: Set değiştiriciler için grafik ifadeleri içeren dolar işareti genişletmeleri

Örnek - grafik ifadeleri

Yükleme kodu

Aşağıdaki grafik ifadesi örneklerini oluşturmak için aşağıdaki verileri veri yükleme düzenleyicisinde satır içi yükleme olarak yükleyin.

Let vToday = Today();
MyTable:
Load 
Year(Date) as Year,
Date#(Date,'YYYY-MM-DD') as ISO_Date, 
Date(Date#(Date,'YYYY-MM-DD'),'M/D/YYYY') as US_Date, 
Country, Product, Amount 
Inline
[Date, Country, Product, Amount
2018-02-20, Canada, Washer, 6
2018-07-08, Germany, Anchor bolt, 10
2018-07-14, Germany, Anchor bolt, 3
2018-08-31, France, Nut, 2
2018-09-02, Czech Republic, Bolt, 1
2019-02-11, Czech Republic, Bolt, 3
2019-07-31, Czech Republic, Washer, 6
2020-03-13, France, Anchor bolt, 1
2020-07-12, Canada, Anchor bolt, 8
2021-10-15, France, Washer, 1];	

Satır içi yüklemeleri kullanma hakkında daha fazla bilgi için bkz. Satır içi yüklemeler.

Grafik ifadeleri içeren dolar işareti genişletmeleri

Aşağıdaki grafik ifadeleriyle Qlik Sense sayfasında bir tablo oluşturun.

Tablo - Dolar işareti genişletmeleri içeren set değiştiriciler

Ülke	Sum (Tutar)	Sum({<US_Date={'$(vToday)'}>} Tutar)	Sum({<ISO_Date={"$(=Date(Min(ISO_Date),'YYYY-MM-DD'))"}>} Tutar)	Sum({<US_Date={">=$(=AddYears(Max(US_Date),-1))"}>} Tutar)
Toplamlar	41	1	6	1
Kanada	14	0	6	0
Çek Cumhuriyeti	10	0	0	0
Fransa	4	1	0	1
Almanya	13	0	0	0

Açıklama

• Boyutlar:

  • Country

• Measures:

  • Sum(Amount)

    ToplamSet ifadesi olmayan Amount değeri.

  • Sum({<US_Date={'$(vToday)'}>}Amount)

    US_Date değerinin vToday değişkenindeki gibi olduğu tüm kayıtlar için Amount değerini topla.

  • Sum({<ISO_Date={"$(=Date(Min(ISO_Date),'YYYY-MM-DD'))"}>}Amount)

    ISO_Date değerinin olabilecek ilk (en küçük) ISO_Date ile aynı olduğu tüm kayıtlar için Amount değerini topla. Date() fonksiyonu, tarih biçiminin alanınkiyle eşleşmesini sağlamak için gereklidir.

  • Sum({<US_Date={">=$(=AddYears(Max(US_Date),-1))"}>}Amount)

    Olabilecek en son (en büyük) US_Date tarihinden bir yıl önceki tarihte veya daha sonra bir US_Date içeren tüm kayıtlar için Amount değerini topla. AddYears() fonksiyonu, DateFormat değişkeni ile belirtilen biçimde bir tarih döndürür ve bunun US_Date alanı ile eşleşmesi gerekir.

İfadeler hakkında daha fazla bilgi için bkz. Görselleştirmelerde ifadeleri kullanma.